[TOC]

• Basic Description

  • Contract

    Commodity futures contract, cryptocurrency contract

    Commodity futures/cryptocurrency contract

    this_week   OKEX futures contract for current week
    next_week   OKEX futures contract for next week
    quarter     OKEX futures contract for quarter
    
    XBTUSD      BITMEX Perpetual Contract
    
    rb888       Rebar main contract
    MA000       Methanol Index Contract
    rb1901      Rebar contract
    …and so on.
    

    

    When setting the contract, you can choose rb1901/rb1905 The market data is rb1901, the order trading contract is rb1905

  • Variables

    A variable is a space opened in the computer memory to store data. Simply put, it is used to save data.

    Declare the first variable

    // Assign 1 to the variable a
    a:=1;
    

    In “M Language”, a simple distinction is made from the “data volume”:

    1. Single-valued data: only one value, such as 0, 1, 'abc’
    2. Sequence data: A sequence of data consisting of a single set of single-valued data, such as Close (close price), where Close contains the closing price of n cycles [ 10.1 , 10.2 , 10.3 , 10.4 , 10. 5… ]

    Distinguish from “variable type”

    1. String type: must use ‘’ parcel, string type is not allowed to be used directly, you need to match the function output to the view

    INFO(CLSOE>OPEN,'OK!');
    

    2. Value type: including integers, floating point numbers (decimal)

    // integer
    int:=2;
    
    // decimal
    float:=3.1;
    

    3. Boolean type, using 1 (for true) or 0 (for false): 1, 0, true or false, for example: A:=1>0; after the execution of this code, the value of A is 1

    // The current period closing price is greater than -999, you will find that the return value of each cycle is 1, representing true, because the closing price is almost impossible to be negative
    Is_true:=Close>-999;
    

    4. Global variable

    VARIABLE:VALUE1:10;     // Declare a global variable with a value of 10 and execute only once.
    

    • Naming rules

      In most systems, variable naming does not allow the use of system “reserved words” (built-in variable names, function names), such as the well-known Close, C. In addition, pure numbers are not allowed, or numbers begin with, and cannot be too long, different systems, and different length limits are different. In fact, you don’t have to entangle the efficiency of the mainstream system for English analysis. I believe that “M Language” is very friendly to English speakers. I recommend you use the following naming convention:

      English + underline

      // output
      Move_avg_5:=MA(C,5);
      

      If you prefer English, please let people understand the meaning of your variables as much as possible. Do not use naming methods such as: A1, AAA, BBB… Believe me, after a few days, when you review your indicator code again, you will be very painful due to the lack of memory. Similarly, when you export code to others, the reader’s mindset must have collapsed.

      Then, from now on, embrace the “M Language” as much as you can! I hope it will be a powerful tool for your analysis and decision making.

  • Type of data

    The data type is a basic concept. In programming, when we assign an explicit data to a variable, the variable becomes the type of the data itself.

    • 1. Value type:

      1、2、3、1.1234、2.23456 ……
      

    • 2. String type (str):

      '1' 、'2' 、'3' ，string type must be wrapped with ''
      

    • 3. Sequence data:

      a collection of data consisting of a series of single-valued data
      

    • 4. Boolean type (boolean):

      Use 1 for true and 0 for false

      Example

      // Declare a variable of a numeric type
      var_int := 1;
      // Declare a variable of sequence data
      var_arr := Close;
      // String type can not be declared separately, you need to combine functions
      INFO(C>O, 'rising line');
      

  • Operator

    The operation and calculation used to execute the indicator code, which is the symbol of the participation operation.

    • Assignment operator

      Used to assign a value to a variable

      • 1. :

        a colon, representing the assignment and outputting to the diagram (deputy diagram)

        Close1:Close;      // Assign Close to the variable Close1 and output it to the diagram
        

      • 2. :=

        The “colon equal”, representing the assignment, but is not output to the diagram (main diagram, subgraph…) and is not displayed in the status bar table.

        Close2:=Close;     // Assign Close to the variable Close2
        

      • 3. ^^

        ^^ ,two ^ symbols represent assignments, assign values to variables and output them to the diagram (main diagram).

        lastPrice^^C;
        

      • 4. ..

        … ,two dot, The symbol represents the assignment, assigns a value to the variable and displays it in the status bar table, but does not output it to the diagram (main diagram, sub- diagram…).

        openPrice..O
        

    • Relational operator

      Relational operators are binocular operators that are used in conditional expressions. Used to determine the relationship between two data

      Return value: Boolean type, not true (1), must be false (0)

      • 1. Greater than >

        // Assign the result of 2 > 1 to the rv1 variable, at this time rv1=1
        Rv1:=2>1;
        

      • 2. Less than <

        // returns false, which is 0, because 2 is greater than 1. :-)
        rv3:=2<1;
        

      • 3. Greater than or equal to >=

        x:=Close;
        // Assign the result of the operation with a closing price greater than or equal to ¥ 10 to the variable rv2
        // Note that since “close” is a sequence of data, when the close>=10 operation is performed, the essence is that each cycle is performed, so each cycle will have a return value of 1, 0.
        rv2:=Close>=10;
        

      • 4. Less than or equal to <=

        Omitted here
        

      • 5. Equal to =

        A:=O=C;     // Determine if the opening price is equal to the closing price.
        

      • 6. Not equal to <>

        1<>2       // Judgment weather 1 is equal to 2 or not, the return value is 1 (true)
        

    • Logical Operators

      Return value: Boolean type, not true (1), must be false (0)
      

      1. Logic and &&, can use “and” instead, and the left and right sides of the connection must be true at the same time.

      // determine whether cond_a, cond_b, cond_c is true at the same time,
      cond_a:=2>1;
      cond_b:=4>3;
      cond_c:=6>5;
      cond_a && cond_b and cond_c;    // return value 1, true
      

      2. Logic or ||, can use “or” instead, “or” link the left and right sides, as long as the one side is true, the whole is true (return true)

      cond_a:=1>2;
      cond_b:=4>3;
      cond_c:=5>6;
      cond_a || cond_b or cond_c;    // return value 1, true
      

    • Arithmetic operator

      Return value: numeric type
      

      It is the completion of the basic arithmetic operators symbol, which is the symbol used to process the four arithmetic operations.

      • Plus +

        A:=1+1;      // return 2
        

      • Subtract -

        A:=2-1;      // return 1
        

      • Multiply *

        A:=2*2;      // return 4
        

      • Divide by /

        A:=4/2;      // return 2
        

  • Function

    • Function

      In the world of programming, a “function” is actually a piece of code that implements a certain function and can be called by other code. The general form is as follows

      function(param1,param2,……)
      

      • Composition：

        The function name (parameter 1, parameter 2, …), there may be no parameters, there may be multiple parameters, such as MA(x, n); represents a simple moving average of the inner x returning n cycles, where MA() is a The function, x and n are the parameters of the function.

        When using a function, we need to understand the basic definition of the function, that is, what data can be obtained by calling the function. In general, functions have parameters. When we pass in parameters, we need to ensure that the data type passed in is compliant. At current stage, the code hinting function of most IDEs is very imperfect. They are not showing the certain data types for the parameters given, which gives us some troubles. The interpretation of MA(x,n) is:

        Return a simple moving average
        usage：
        AVG:=MA(X,N): N's simple moving average of X, algorithm (X1+X2+X3+...+Xn)/N,N supports variables
        

        This is very unfriendly explanation for beginners. Next, we thoroughly analyze the function and try to find a way to quickly learn and use the function.

    • Return value

      In order to learn the function quickly, we first need to understand a concept called “return value”. Return, as the name implies, is “return”, the value represents “concrete value”, the data that can be obtained.

      // Because it will be used in the following code, use the variable return_value to receive and save the return value of function()
      // retrun_value := function(param1,param2);
      // for example：
      AVG:=MA(C,10); // AVG is retrun_value , “function” function is: MA function, param1 parameter: C is the closing price sequence data, param2 parameter: 10.
      

    • Parameter

      Second, the second important concept of the function is the parameter, passing in different parameters, you can get different return values.

      // variable ma5 receives 5 day closing price moving average
      ma5:=MA(C,5);
      // variable ma10 receives 10 day closing price moving average
      ma10:=MA(C,10);
      

      The first parameter X of the above variables ma5, ma10 is C (closing price), in fact C is also a function (returning the closing price sequence since the opening), but it has no parameters. The second parameter 5, 10，This is used to tell the MA () function, we want to get the moving average of the closing price for how many days, through the parameters, the function becomes more flexible.

    • How to learn

      • 1. First, you need to understand the function of the “function”, which is what data this function can give us.
      • 2. Understanding the type of the return value, after all, we use the function in order to get the return value.
      • 3. We need to understand the data type of the parameter, MA (x, n), if you do not know the data type of the parameters x, n, you can not get the return value correctly.

      In the following function introduction, use, follow the above three principles.

  • Language enhancement

    • Mixed programming between M language and JavaScript language

      %%
      // here you can call any API function of FMZ Quant.
      scope.TEST = function(obj) {
          return obj.val * 100;
      }
      %% 
      

    Closing price: C; The closing price is magnified 100 times: TEST©; The previous closing price is magnified 100 times: TEST(REF(C, 1)); // The mouse moves to the backtest K line and the variable value is displayed.

    
    - scope object
    
      scope object, you can add attributes and assign anonymous functions to attributes. An anonymous function referenced by this attributes can be called in the M language code section.
    
    - scope.getRefs(obj) function
    
      In the JavaScript code block, call the scope.getRefs(obj) function, which returns the data of the incoming obj object.
    
     The following %%%% of the symbolic package's JavaScript code will get the incoming C closing price when the TEST(C) function is called in the M language code.
      The scope.getRefs function returns all closing prices for this K-line data. Since the throw "stop" interrupt routine is used, the variable “arr” contains only the closing price of the first Bar of k-line. You can try to delete throw "stop" and it will execute the last return of the JavaScript code, returning all the closing price data.
      ```
      %%
      scope.TEST = function(obj){
          var arr = scope.getRefs(obj)
          Log("arr:", arr)
          throw "stop"
          return
      }
      %%
      TEST(C);
      ```
    
    - scope.bars
    
      In the JavaScript code block, access all K line bars.
    
      The TEST function returns a value, 1 is the falling k-line and 0 is the rising line.
      
      ```
      %%
      scope.TEST = function(){
          var bars = scope.bars
          return bars[bars.length - 1].Open > bars[bars.length - 1].Close ? 1 : 0    // can only return values
      }
      %%
      arr:TEST;                                                                      
      ```
    
      ```
      # Note:
      # TEST Received anonymous function, the return value must be a numeric value
      # If the anonymous function has no parameters, write VAR:=TEST directly when calling TEST; write VAR:=TEST(); will report an error.
      # TEST in #scope.TEST must be uppercase.
      ```
    
    - scope.bar
    
      In the JavaScript code block, access the current bar.
    
      Calculate the average of “opening high but closing low” of k-line’s prices.
    
      ```
      %%
      scope.TEST = function(){
          var bar = scope.bar
          var ret = (bar.Open + bar.Close + bar.High + bar.Low) / 4
          return ret
      }
      %%
      avg^^TEST;
      ```
    
    - scope.depth
    
      Access the market depth data (order book)
    
      ```
      %%
      scope.TEST = function(){
          Log(scope.depth)
          throw "stop"             // Throw an exception after printing the depth data, pause.
      }
      %%
      TEST;
      ```
    
    - scope.symbol
    
      Get the current trading pair name string
    
      ```
      %%
      scope.TEST = function(){
          Log(scope.symbol)
          throw "stop"
      }
      %%
      TEST;
      ```
    
    - scope.barPos
    
      Get the K line Bar location.
    
      ```
      %%
      scope.TEST = function(){
          Log(scope.barPos)
          throw "stop"
      }
      %%
      TEST;
      ```
    
    - scope.get\_locals('name')
    
      This function is used to get the variables in the M language code part
    
      ```
      V:10;
      %%
      scope.TEST = function(obj){
          return scope.get_locals('V')
      }
      %%
      GET_V:TEST(C);
      ```
    
      ```
      # Note:
      # If a variable does not calculate data when the period is insufficient, this time the scope.get_locals function is called in the JavaScript code.
      # When get this variable, it will give an error: line:XX - undefined locals a variable name undefined
      ```
    
    

  • Multi-cycle reference

    • Use: #EXPORT Formula Name … #END to create a formula. If you only want to get data for different periods, you can also write an empty formula without formula calculation.

      The empty formula is:

      #EXPORT TEST 
      NOP;
      #END           // End
      

    • Use: #IMPORT [MIN, period, formula name] AS variable value, reference formula, get the data of the set period (closing price, opening price, etc., obtained by variable value).

      Code example:

      // this code demonstrates how to reference formulas of different cycles in the same code
      // #EXPORT extends the syntax, ending with #END as a formula, you can declare multiple
      #EXPORT TEST 
      Mean 1:EMA(C, 20);
      Mean 2:EMA(C, 10);
      #END // End
      
      #IMPORT [MIN,15,TEST] AS VAR15 // Reference formula, K line cycle is 15 minutes
      #IMPORT [MIN,30,TEST] AS VAR30 // Reference formula, K line cycle is 30 minutes
      CROSSUP(VAR15.Mean1, VAR30.Mean1),BPK;
      CROSSDOWN(VAR15.Mean2, VAR30.Mean2),SPK;
      The highest price of 15 mins:VAR15.HIGH;
      The highest price of 30 mins:VAR30.HIGH;
      AUTOFILTER;
      

  • Mode Description

    • 1、One opening position and one closing position signal filtering model

      In the model, by writing the AUTOFILTER function to control and realize the signal filtering of one opening and one closing. When multiple opening position signals satisfy the condition, the first signal is taken as the effective signal, and the same signal on the subsequent k line will be filtered out.

      Filtering model supported commands: BK, BP, BPK, SK, SP, SPK, CLOSEOUT, does not support BK (5) and other instructions with lots

      E.g：

      MA1:MA(CLOSE,5);
      MA2:MA(CLOSE,10);
      CROSSUP(C,MA1),BK;
      CROSSUP(MA1,MA2),BK;
      C>BKPRICE+10||C<BKPRICE-5,SP;
      AUTOFILTER;
      

    • 2、adding or subtracting position model

      The AUTOFILTER function is not written in the model, allowing continuous opening position signal or continuous closing position signal, which can be used to increase or decrease the position.

      Supported commands: BK(N), BP(N), SK(N), SP(N), CLOSEOUT, BPK(N), SPK(N), do not support open and close position without lot. （1）Support instruction grouping。 （2）When multiple instruction conditions are satisfied at the same time, the signals are executed in the order in which the conditional statements are written. E.g：

      MA1:MA(CLOSE,5);
      MA2:MA(CLOSE,10);
      CROSSUP(C,MA1),BK(1);
      CROSSUP(MA1,MA2),BK(1);
      C>BKPRICE+10||C<BKPRICE-5,SP(BKVOL);
      

    • 3、one K-line with one signal model

      One K-line with one signal model can be subdivided into a closing price model and an instruction price model.

      1）Closing price model

      The K line goes through the calculation signal to place an order (the calculation is also performed during the formation of a K line. At this time, the signal will uncertain, and the signal that appears when the k line is not finished will be ignored, and no order will be placed)

      The signal direction is consistent with the direction of the holding position, and there is no signal disappearing condition.

      E.g：
      MA1:MA(CLOSE,5);
      MA2:MA(CLOSE,10);
      CROSSUP(MA1,MA2),BPK;//5 cycle moving average line up cross 10 cycle moving average line to buy long.
      CROSSDOWN(MA1,MA2),SPK;//5 cycle moving average line down cross 10 cycle moving average line to sell short.
      AUTOFILTER;
      

      2）Instruction price model

      Regardless of whether the k-line is finished or not, the signal is calculated and the order is placed in real time, that is, the order is placed before the K-line is completed;

      When the K line ends, it will be checked. If the direction of the position does not match the direction of the signal at the end of the k line, the position will be automatically synchronized.

      E.g：

      MA1:MA(CLOSE,5);
      MA2:MA(CLOSE,10);
      CROSSUP(MA1,MA2),BPK;//5 cycle moving average line up cross 10 cycle moving average line to buy long.
      CROSSDOWN(MA1,MA2),SPK;//5 cycle moving average line down cross 10 cycle moving average line to sell short.
      AUTOFILTER;
      

    • 4、One K-line with multiple signal model

      The model uses a multsig or multsig_min to control and implement multiple signals from a single K-line.

      Regardless of whether the k line is finished, calculate the signal and place a real-time order.

      The signal will not be reviewed, there is no signal disappearing condition, and the signal direction is consistent with the direction of the position.

      Repeated multiple executions in a K line if multiple signal conditions are met

      E.g:
      MA1:MA(CLOSE,5);
      MA2:MA(CLOSE,10);
      CROSSUP(MA1,MA2),BK;
      C>BKPRICE+10||C<BKPRICE-5,SP;
      AUTOFILTER;
      MULTSIG(0,0,2,0);
      

      supplement: 1、Adding and subtracting position model, two methods of one k-line signal: the closing price placing order and the instructing price placing order are all supported.

      2、Adding and subtracting position model，also supports a single k-line signal to place orders.

      Adding and subtracting position model，write the multsig or multsig_min function, realize multiple times of Adding and subtracting position on one k line, or reduce the position multiple times.

  • Chart Display

    • Main diagram additional indicator

      Use the operator “^^” to set the indicator to be displayed on the main image while assigning values to the variable.

      MA60^^MA(C, 60);  // Calculate the moving average indicator with a parameter of 60
      

      

    • Sub-diagram additional indicator

      Use the operator “:” to set the indicator to be displayed on the secondary diagram while assigning values to the variable.

      ATR:MA(MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW)),26);    // Assign a value to the ATR variable, The ":" symbol is followed by the formula for calculating the ATR
      

      If you don’t want to display on the main or sub-diagram Use the “…” operator

      MA60..MA(C, 60);  // Calculate the moving average indicator with a parameter of 60
      

      You can use DOT and COLORRED to set the line type, color, etc. in line with the habits of users who are familiar with the M language.

  • Common Problem

    Introduce the “problems” commonly encountered in the preparation of indicators, usually the points that need attention when writing the indicators. (To be continue)

    • Pay attention to the end of “;”.

    • Note that system keywords cannot be declared as variables.

    • Note that the string uses single quotes, for example: ‘opening’ only one quote.

    • Comment

      Annotation

      • // The content of the comment (the input method can be typed in both English and Chinese), which means that the code is not compiled during the execution process, that is, it does not execute // the content behind it. Usually we use the meaning of the code to facilitate the code review. Understanding, recall

      • { Comment content } Block comment.

        A:=MA(C,10);
        {The previous line of code is the calculation of the moving average.}
        

      • (* Comment content *) Block comment.

        A:=MA(C,10);
        (*The previous line of code is the calculation of the moving average.*)
        

    • Input method

      When writing code, it often causes a symbol error because the input method switches between Chinese and English. Common types are as follows: colon:, terminator; comma, parenthesis (), etc., these different characters in Chinese and English need to pay attention.

    • Error-prone logic

      1. At least || Not less than || Not less than: Corresponding relational operator >=
      2. At most || Most || No more: Corresponding relational operator <=

• K Line Data Reference

  • OPEN

    Get the opening price of the K-line chart

    Opening Price

    Function：OPEN，shorthand as O

    Parameters: None

    Explanation: Return the opening price of the cycle

    Sequence data

    OPEN obtained the opening price of the K-line chart.
    
    Note:
    1、can be shorthand as O.
    
    example 1：
    OO:=O;           //Define OO as the opening price; pay attention to the difference between O and 0.
    example 2：
    NN:=BARSLAST(DATE<>REF(DATE,1));
    OO:=REF(O,NN);   //Get the opening price of the day
    example 3：
    MA5:=MA(O,5);    //Define the 5-period moving average of the opening price (O is OPEN shorthand).
    

  • HIGH

    Get the highest price of the K-line chart

    Highest price

    Function：HIGH，shorthand as H

    Parameters: None

    Explanation: return the highest price of the cycle

    Sequence data

    HIGH Get the highest price of the K-line chart.
    
    Note：
    1、can be shorthand as H.
    
    example 1：
    HH:=H;         //Define HH as the highest price.
    example 2：
    HH:=HHV(H,5);  //Take the maximum value of the highest price within 5 cycles.
    example 3：
    REF(H,1);      //Take the highest price of the previous K line
    

  • LOW

    Get the lowest price of the K-line chart

    Lowest Price

    Function：LOW，shorthand as L

    Parameters: None

    Explanation: Return the lowest price of the cycle.

    Sequence data

    LOW gets the lowest price of the K-line chart.
    
    Note：
    1、can be shorthand as L.
    
    example 1：
    LL:=L;            //Define LL as the lowest price.
    example 2：
    LL:=LLV(L,5);     //Get the minimum value of the lowest price in 5 cycles.
    example 3：
    REF(L,1);         //Get the lowest price of the previous K line
    

  • CLOSE

    Get the closing price of the K-line chart

    Closing Price

    Function：CLOSE，shorthand as C

    Parameters: None

    Explanation: Return the closing price of the cycle

    Sequence data

    CLOSE Get the closing price of the K-line chart.
    
    Note：
    1、When the k-line in the market is not finished, get the latest price.
    2、Can be shorthand as C.
    
    example 1：
    A:=CLOSE;          //Define the variable A as the closing price (A is the latest price when the k line is not finished).
    example 2：
    MA5:=MA(C,5);      //Define the 5-period moving average of the closing price (C is short for CLOSE).
    example 3：
    A:=REF(C,1);       //Get the closing price of the previous k line.
    

  • VOL

    Get the volume of the K-line chart

    Trading Volume

    Function：VOL，shorthand as V

    Parameters: None

    Explanation: Return the volume of this cycle.

    Sequence data

    VOL gets the volume of the K-line chart.
    
    Note：
    Can be shorthand as V.
    The return value of this function on the root TICK is the cumulative value of all TICK transactions for the day.
    
    example 1：
    VV:=V;       //Define VV as volume
    example 2：
    REF(V,1);    //indicates the volume of the previous cycle
    example 3：
    V>=REF(V,1); //The volume is greater than the volume of the previous cycle, indicating that the volume increases (V is short for VOL).
    

  • REF

    Forward Reference

    Reference the value of X before N cycles.
    
    Note：
    1、When N is a valid value, but the current number of k lines is less than N, a null value is returned;
    2、When N is 0, the current X value is returned;
    3、When N is null, it returns a null value.
    4、N can be a variable
    
    example 1:
    REF(CLOSE,5); indicates the closing price of the 5th cycle before the current cycle
    example 2：
    AA:=IFELSE(BARSBK>=1,REF(C,BARSBK),C);//Take the closing price of the K line of latest buying long of the open position signal
    //1) When the k-line BARSBK of the BK signal returns a null value, the k-line REF(C, BARSBK) of the BK signal is returned.
    Null value；
    //2）When the BK signal is sent, the k-line BARSBK returns a null value, and if the BARSBK>=1 is not satisfied, then send the closing price of the k-line.
    //3）The k-line BARSBK after the BK signal is sent returns the number of cycles of the K-line of the open position from the current K-line, REF(C, BARSBK)
    Returns the closing price of the opening k line.
    //4）Example: 1, 2, 3 three k lines, 1 K line is the opening position signal K line, then return the closing price of this k line, 2, 3
    K line returns the closing price of the 1 K line.
    

  • UNIT

    Take the transaction unit of the data contract

    Take the trading unit of the data contract.
    usage：
    UNIT takes the trading unit of the data loading contract.
    

    Commodity Future

    UNIT value is related to the contract

    rb contract - 1 hand, 10 (tons)
    

    Cryptocurrency Spot

    UNIT value is 1

    Cryptocurrency futures UNIT value is related to contract currency

    OKEX Futures: 1 BTC contract represents $100, and 1 contract in other currencies represents $10
    

  • MINPRICE

    Minimum price change for data contracts

    Take the minimum price change of the data contract.
    usage:
    MINPRICE; Take the minimum price change for loading data contracts.
    

  • MINPRICE1

    Minimum change in trading contract

    Take the minimum price change of the trading contract.
    usage：
    MINPRICE1; Take the minimum price change of the trading contract.
    

• Time Function

  • BARPOS

    Take the position of the K line
    
    BARPOS，returns the number of cycles from the first K line to the current cycle.
    
    Note：
    1、BARPOS returns the number of existing K lines in the local area, starting from the data existing on the local machine.
    2、The return value of the first K line already on the local machine is 1.
    
    example 1：LLV(L,BARPOS);//Find the minimum value of the local existing data.
    
    example 2：IFELSE(BARPOS=1,H,0);//The current K line is the highest value of the first K line already in the local machine, otherwise it is 0.
    

  • PERIOD

    The period value is the number of minutes.

    1, 3, 5, 15, 30, 60, 1440
    

  • DATE

    DATE

    Function：DATE

    Parameters: None

    Explanation : Obtain the date of the cycle from 1900

    Sequence data

  • TIME

    Take the time of the K line

    TIME，take the K line time.
    
    Note：
    1、The function returns in real time on the real-market, and returns the start time of the K line after the K line is finished.
    2、The function returns the exchange data reception time, which is the exchange time.
    3、The TIME function returns a six-digit form when used in the second period, ie: HHMMSS, which is displayed in four-digit form on other periods, namely: HHMM.
    4、The TIME function can only be loaded in the period below the daily period. The return value of the function is always 1500 in the period above the daily period (Included the daily period).
    5、use the TIME function to close the position of the tail operation needs attention
    （1） The time set by the end of the closing position is recommended to be set to the actual time that can be taken in the K line return value (eg, the RB index is 5 minutes, the last K line return time is 1455, and the tail closing position is set to TIME> =1458, CLOSEOUT; the signal that the tail is closed can not appear in the effect test)
    （2）	Using the TIME function as the condition for closing the position at the end of the market, it is recommended to open position condition also to make the corresponding time limit (such as setting the closing condition of the tail to TIME>=1458, CLOSEOUT; then the corresponding opening conditions are required Add condition TIME<1458; avoid opening the position again after closing the position)
    
    example 1:
    C>O&&TIME<1450,BK;
    C<O&&TIME<1450,SK;
    TIME>=1450,SP;
    TIME>=1450,BP;
    AUTOFILTER;
    //Close the position after 14:50.
    example 2：
    ISLASTSK=0&&C>O&&TIME>=0915,SK;
    

  • YEAR

    Years

    YEAR，the year is obtained.
    
    Note：
    YEAR ranges from 1970—2033。
    
    example 1：
    N:=BARSLAST(YEAR<>REF(YEAR,1))+1;
    HH:=REF(HHV(H,N),N);
    LL:=REF(LLV(L,N),N);
    OO:=REF(VALUEWHEN(N=1,O),N);
    CC:=REF(C,N);//take the highest price, the lowest price, the opening price, and the closing price of the previous year.
    example 2：
    NN:=IFELSE(YEAR>=2000 AND MONTH>=1,0,1);
    

  • MONTH

    Returns the month of a cycle

    MONTH, returns the month of a cycle.
    
    Note：
    MONTH has a value range of 1-12.
    
    example 1：
    VALUEWHEN(MONTH=3&&DAY=1,C);//The closing price is taken when the K-line date is March 1.
    example 2：
    C>=VALUEWHEN(MONTH<REF(MONTH,1),O),SP;
    

  • DAY

    Get the number of days in a cycle

    DAY, returns the number of days in a cycle.
    
    Note：
    The DAY value ranges from 1-31.
    
    example 1：
    DAY=3&&TIME=0915，BK;//From the date of 3 days, the time is 9:15, buy long.
    example 2：
    N:=BARSLAST(DATE<>REF(DATE,1))+1;
    CC:=IFELSE(DAY=1,VALUEWHEN(N=1,O),0);//When the date is 1, the opening price is taken, otherwise the value is 0.
    

  • HOUR

    HOUR

    HOUR，Returns the number of hours in a cycle.
    
    Note：
    HOUR ranges from 0 to 23
    
    example 1：
    NX:=BARSLAST(CROSS(HOUR=9,0.5));
    DRAWLINE3(CROSSDOWN(HOUR=14,0.5),REF(H,NX),NX,CROSSDOWN(HOUR=14,0.5),REF(H,1),1,0),COLORGREEN;
    //Connect 9:00 to the latest k-line high point before the market close.
    example 2：
    HOUR=10;//The return value is 1 on the K line at 10:00, and the return value on the remaining K lines is 0.
    

  • MINUTE

    MINUTE

    MINUTE, Returns the number of minutes in a cycle.
    
    Note：
    1：MINUTE has a value range of 0-59
    2：This function can only be loaded on the minute period, returning the number of minutes since the current K line.
    example 1：
    MINUTE=0；//The return value on the minute K line at the beginning of an hour is 1, and the remaining K lines return a value of 0.
    example 2：
    TIME>1400&&MINUTE=50,SP;//close position at 14:50.
    

  • WEEKDAY

    Get the number of weeks

    WEEKDAY, get the number of weeks.
    
    Note：
    1：WEEKDAY has a value range of 0-6.
    2：The value displayed by the function on the weekly cycle is always 5, and the number of weeks on the day of the end of the K line is returned on the monthly cycle.
    
    example 1：
    N:=BARSLAST(MONTH<>REF(MONTH,1))+1;
    COUNT(WEEKDAY=5,N)=3&&TIME>=1450,BP;
    COUNT(WEEKDAY=5,N)=3&&TIME>=1450,SP;
    AUTOFILTER;//each month delivery date is automatically closed all position at the end of that day.
    example 2：
    C>VALUEWHEN(WEEKDAY<REF(WEEKDAY,1),O)+10,BK;
    AUTOFILTER;
    

• Logical Judgment Function

  • BARSTATUS

    Returns the position status of the current cycle

    BARSTATUS returns the position status of the current cycle.
    
    Note：
    The function returns 1 to indicate that the current cycle is the first cycle, return 2 to indicate the last cycle, and return 0 to indicate that the current cycle is in the middle position.
    
    example:
    A:=IFELSE(BARSTATUS=1,H,0); //If the current K line is the first cycle, the variable A returns the highest value of the K line, otherwise it takes 0.
    

  • BETWEEN

    Between

    BETWEEN(X,Y,Z) indicates whether X is between Y and Z, and returns 1 (Yes), otherwise returns 0 (No).
    
    Note：
    1、If X=Y, X=Z, or X=Y and Y=Z, the function returns a value of 1 (Yse).
    
    example 1：
    BETWEEN(CLOSE,MA5,MA10); //indicates that the closing price is between the 5-day moving average and the 10-day moving average.
    

  • CROSS

    Cross Function

    CROSS(A,B) means that A passes B from the bottom to up, and returns 1 (Yes), otherwise it returns 0 (No).
    
    Note：
    1、The conditions for crossing must satisfy A<=B of pervious k line, and it is confirmed as crossing when the current k-line satisfies A>B.
    
    example 1：
    CROSS(CLOSE,MA(CLOSE,5)); //means the crossing line from below through the 5-period moving average
    

  • CROSSDOWN

    Crossing down

    CROSSDOWN(A,B)：indicates that when A down crossing B from above, it returns 1 (Yes), otherwise it returns 0 (No).
    
    Note：
    1、CROSSDOWN (A, B) is equivalent to CROSS (B, A), CROSSDOWN (A, B) is written to better understand
    
    example 1：
    MA5:=MA(C,5);
    MA10:=MA(C,10);
    CROSSDOWN(MA5,MA10),SK; //MA5 down cross MA10, sell short
    //CROSSDOWN(MA5,MA10),SK; and CROSSDOWN(MA5,MA10)=1, SK; express the same meaning
    

  • CROSSUP

    Crossing up

    CROSSUP(A,B) When A passes up from bottom to B, it returns 1 (Yes), otherwise it returns 0 (No)
    
    Note：
    1、CROSSUP (A, B) is equivalent to CROSS (A, B), CROSSUP (A, B) is written to better understand.
    
    example 1：
    MA5:=MA(C,5);
    MA10:=MA(C,10);
    CROSSUP(MA5,MA10),BK;//MA5 cross up MA10, buy long.
    //CROSSUP(MA5,MA10),BK; and CROSSUP(MA5,MA10)=1, BK; express the same meaning
    

  • EVERY

    Determine whether it continues to meet the requirement

    EVERY(COND,N)，judge whether the COND condition is always satisfied in the N period. If it is, the function returns a value of 1; if it is not, the function returns a value of 0;
    
    Note：
    1、N contains the current k line.
    2、If N is a valid value, but there are not many K lines in front of it, or N is a null value, the condition is not satisfied, and the function returns 0.
    3、N can be a variable
    
    example 1：
    EVERY(CLOSE>OPEN,5);//indicates that it has been a positive line for 5 cycles.
    example 2：
    MA5:=MA(C,5);//Define a 5-cycle moving average
    MA10:=MA(C,10);//Define the 10-cycle moving average
    EVERY(MA5>MA10,4),BK;//MA5 is greater than MA10 in 4 cycles, then buy long.
    //EVERY(MA5>MA10,4),BK; and EVERY(MA5>MA10,4)=1, BK; express the same meaning
    

  • EXIST

    Determine if there is satisfaction

    EXIST(COND,N) determines whether there are conditions for satisfying COND in N cycles
    
    Note:
    1、N contains the current k line.
    2、N can be a variable.
    3、If N is a valid value, but there are not many K lines in front of it, calculate according to the actual number of cycles.
    
    example 1：
    EXIST(CLOSE>REF(HIGH,1),10);indicates whether there is a maximum price in the 10 cycles that is greater than the previous period, if it exist, return 1, and if it does not exist, returns 0.
    example 2：
    N:=BARSLAST(DATE<>REF(DATE,1))+1;
    EXIST(C>MA(C,5),N);//Indicates whether there is a k line that meets the closing price greater than the 5-period moving average. If it exist, return 1, and if it does not exist, return 0.
    

  • IF

    Conditional Function

    IF(COND,A,B) Returns A if the COND condition is true, otherwise returns B
    
    Note：
    1、COND is a judgment condition; A and B can be conditions or numerical values.
    2、the function supports the variable loop to reference the previous period of its own variable, that is, support the following writing method Y: IF (CON, X, REF (Y, 1));
    example 1：
    IF(ISUP,H,L);// k line is the rising line, take the highest price, otherwise take the lowest price
    example 2：
    A:=IF(MA5>MA10,CROSS(DIFF,DEA),IF(CROSS(D,K),2,0));//When MA5>MA10, take whether DIFF is cross up the DEA, otherwise (MA5 Not greater than MA10), when K, D is down crossing, let A be assigned a value of 2. If the above conditions are not met, A is assigned a value of 0.
    A=1,BPK;//When MA5>MA10, use DIFF cross up DEA as the buying long condition
    A=2,SPK;//When MA5 is not greater than MA10, K D down crossing are used as selling short conditions
    

  • IFELSE

    Conditional Function

    IFELSE(COND,A,B) Returns A if the COND condition is true, otherwise returns B
    
    Note：
    1、COND is a judgment condition; A and B can be conditions or numerical values.
    2、the function supports the variable loop to refer to the previous period of its own variable, that is, supports the following writing method Y: IFELSE (CON, X, REF (Y, 1));
    example 1：
    IFELSE(ISUP,H,L);//k line is the rising line, take the highest price, otherwise take the lowest price
    example 2：
    A:=IFELSE(MA5>MA10,CROSS(DIFF,DEA),IFELSE(CROSS(D,K),2,0)); //When MA5>MA10, whether DIFF up cross DEA, otherwise (MA5 Not greater than MA10), when K, D down cross, let A be assigned a value of 2. If the above conditions are not met, A is assigned a value of 0.
    A=1,BPK;//When MA5>MA10, use DIFF up cross DEA as the buying long condition
    A=2,SPK;//When MA5 is not greater than MA10, K, D down cross are used as selling short conditions
    

  • ISCONTRACT

    weather the currently contract a designated contract

    weather ISCONTRACT(CODE) is currently the specified contract.
    
    Usage：ISCONTRACT(CODE); is the current contract returns 1, not the current contract returns 0.
    
    Note：
    1、When judging whether it is a specified contract, CODE can be the transaction code of the contract.
    
    example:
    ISCONTRACT('MA888');
    ISCONTRACT('rb1901');
    ISCONTRACT('this_week');    // cryptocurrency OKEX Futures Contract
    ISCONTRACT('XBTUSD');       // cryptocurrency BITMEX Futures Contract
    

    Support for regular expressions

    Determine contract

    ISCONTRACT('this_week');                     // Determine if the current contract is OKEX futures this_week (week) contract
    

    Judging the name of the exchange

    ISCONTRACT('@Futures_(CTP|BitMEX)');         // Determine whether the current exchange object is a commodity futures or a cryptocurrency BITMEX futures exchange
    ISCONTRACT('@(OKEX|Bitfinex|Futures_CTP)');  // To determine the exchange, you need to add @ character at the beginning
    

  • ISDOWN

    Falling K line

    ISDOWN determines whether the cycle is falling
    
    Note：
    1、ISDOWN is equivalent to C<O
    
    example：
    ISDOWN=1&&C<REF(C,1),SK;//When the current k line is finished and the closing price is lower than the closing price of the previous period, then selling short
    //ISDOWN=1&&C<REF(C,1),SK; is equivalent to ISDOWN&&C<REF(C,1),SK;
    

  • ISEQUAL

    The opening price equal to closing price

    ISEQUAL determines if the cycle is "The opening price equal to closing price"
    
    Note：
    1、ISEQUAL is equivalent to C=O
    
    example 1：
    EVERY(ISEQUAL=1,2),CLOSEOUT; //continue for 2 k lines are “The opening price equal to closing price
    

“, then close all position.

```

• ISLASTBAR

  Determine if the cycle is the last K line

  ISLASTBAR determines if the cycle is the last k line
  
  example 1：
  VALUEWHEN(ISLASTBAR=1,REF(H,1));//The current k-line is the last k-line, taking the highest price of the previous cycle.
  

• ISNULL

  Determine null

  ISNULL determine whether it is null or not
  
  Usage：ISNULL(N);if N is null, the function returns 1; if N is non-null, the function returns 0.
  
  Example: MA5:=IFELSE(ISNULL(MA(C,5))=1, C,MA(C,5));//Define a five-period moving average. When the number of K-lines is less than five, return the current K-line closing price.
  

• ISUP

  Rising line

  ISUP determines whether the cycle is rising
  
  Note：
  1、ISUP is equivalent to C>O
  
  example：
  ISUP=1&&C>REF(C,1),BK;   //If the current k line is a rising k line and the closing price is greater than the closing price of the previous period, then buying long.
                           //ISUP=1&&C>REF(C,1),BK; and ISUP&&C>REF(C,1),BK;
                           //Express the same meaning
  

• LAST

  Determine Function

  LAST(COND,N1,N2) Determines whether the COND condition has been met for the past N1 to N2 cycles.
  
  Note：
  1、If N1 and N2 differ by only one cycle (eg, N1=3, N2=2), the function judges whether the condition is satisfied on the cycle closest to the current K line (ie, whether the K line in the past N2 cycles is meeting the conditions)
  2、When N1/N2 is a valid value, but the current k-line number is less than N1/N2, or N1/N2 null, means is not true, and the function returns 0.
  3、N1 and N2 cannot be variables.
  
  example 1：
  LAST(CLOSE>OPEN,10,5); // indicates that it has been a rising line from the 10th cycle to the 5th cycle in the past.
  example 2：
  MA5:=MA(C,5);
  LAST(C>MA5,4,3);//determine whether the K line from the current k-line 3 cycles satisfies “C greater than MA5”.
  

• LONGCROSS

  Maintain Cross Function

  LONGCROSS(A,B,N) indicates that A is less than B in N cycles, and this cycle A up cross B from bottom to top.
  
  Note：
  1、When N is a valid value, but the current k-line number is less than N, the LONGCROSS function returns a null value.
  2、N does not support variables.
  
  example 1：
  LONGCROSS(CLOSE,MA(CLOSE,10),20); //indicates that the closing price continues below the 10-day moving average for 20 cycles and then up cross the 10-day moving average from bottom to top.
  

• NOT

  non-

  NOT(X)：Take a non. Returns 1 when X=0, otherwise returns 0.
  example 1：
  NOT(ISLASTBK); If the previous signal is not a BK signal, the NOT (ISLASTBK) returns a value of 1; the previous signal is a BK signal, and the NOT (ISLASTBK) returns a value of 0.
  example 2：
  NOT(BARSBK>=1)=1;//The BK signal is sent to the current K line to satisfy the condition.
  //NOT(BARSBK>=1)=1 is equivalent to NOT (BARSBK>=1).
  

• NULL

  Return null

  Return null
  usage：
  MA5:=MA(C,5);
  MA10:=MA(C,10);
  A:=IFELSE(MA5>MA10,MA5,NULL),COLORRED;//When MA5>MA10, draw the five-day moving average MA5, when MA5>MA10 is not satisfied, return null value, no drawing line.
  

• VALUEWHEN

  Value

  VALUEWHEN(COND,X) Takes the current value of X when the COND condition is true. If the COND condition is not true, take the value of X when the COND condition is established last time.
  
  Note：
  X can be either a numerical value or a condition.
  
  example 1
  VALUEWHEN(HIGH>REF(HHV(HIGH,5),1),HIGH);indicates that the current highest price is greater than the maximum value of the highest price of the first five cycles and returns the current highest price.
  example 2：
  VALUEWHEN(DATE<>REF(DATE,1),O);indicates the opening price of the first k-line of the day
  example 3：
  VALUEWHEN(DATE<>REF(DATE,1),L>REF(H,1));//indicates whether the current lowest price on the first k line of the day is greater than the highest price of the last K line yesterday. Returns 1, indicating that there is a price gap on that day. Returns 0, indicating that there are no price gap on that day.
  

• Loop Execution Function

  • LOOP2

    Loop condition function

    LOOP2(COND,A,B); loop condition function Returns A if the COND condition is true, otherwise returns B
    
    Note：
    1、COND is a judgment condition; A and B can be conditions or numerical values.
    2、the function supports variable loop reference to the previous period of its own variable, that is, support the following writing method Y: = LOOP2 (CON, X, REF (Y, 1));
    
    example 1：
    X:=LOOP2(ISUP,H,REF(X,1));//k line is the rising line, take the highest price of the current K line, otherwise take the highest price of the pervious K line that is a rising k line; if it has not appeared before, X returns null
    
    example 2:
    BB:=LOOP2(BARSBK=1,LOOP2(L>LV(L,4),L,LV(L,4)),LOOP2(L>REF(BB,1),L,REF(BB,1)));//When holding long position, the lowest price in the first 4 cycles of opening position k line is the starting stop loss point BB, if the lowest price of the subsequent K line is higher than the previous lowest price, taking the current lowest price as stop loss point, otherwise take the previous lowest point to be the stop loss point.
    SS:=LOOP2(BARSSK=1,LOOP2(H<HV(H,4),H,HV(H,4)),LOOP2(H<REF(SS,1),H,REF(SS,1)));// When holding short position, the highest price in the first 4 cycles of opening position k line is the starting stop loss point SS, if the highest price is lower than the previous highest price, taking the current highest price as stop loss point, Otherwise take the previous high point as stop lose points
    H>HV(H,20),BK;
    L<LV(L,20),SK;
    C<BB,SP;
    C>SS,BP;
    AUTOFILTER;
    
    

• Financial Statistics Function

  • BARSCOUNT

    The number of cycles that the first valid period to the current one

    BARSCOUNT(COND) The number of cycles that the first valid period to the current one
    
    Note：
    1、The return value is the number of cycles from which the COND is calculated from the first valid period and up to now.
    2、The return value of BARSCOUNT(COND) on the current k line on the condition that the condition is first established is 0.
    
    example：
    BARSCOUNT(MA(C,4));//The calculation MA(C,4) has the first return value to the current number of cycles.
    

  • BARSLAST

    Last condition established true

    BARSLAST(COND)：The last condition COND was established to the current number of cycles
    
    Note：
    1、The return value of BARSLAST(COND) on the current k line is 0.
    
    example 1：
    BARSLAST(OPEN>CLOSE); //The number of cycles from the previous falling k line to the present
    Example 2：
    N:=BARSLAST(DATE<>REF(DATE,1))+1;//minute period, the number of k line on the current day.
    //Because the condition is established, the return value of BARSLAST(COND) on the current k line is 0, so "+1" is the k-line number of current day.
    

  • BARSSINCE

    The first condition is established to the current number of cycles

    BARSSINCE(COND) The first condition is established to the current number of cycles.
    
    Note：
    1、the return value is the first time the COND is established to the current number of cycles
    2、The return value of BARSSINCE (COND) on the current k-line of the condition established for the first time is 0.
    
    example ：
    BARSSINCE(CLOSE>OPEN);
    //Statistics of the number of cycles from the K line that satisfies the condition of the first line to the present.
    

  • BARSSINCEN

    Statistics The first condition in the N period is establ