এই কৌশলটি ব্যবহারকারীর দ্বারা সংজ্ঞায়িত সেশনের সময় স্বল্পমেয়াদী ব্রেকআউটের জন্য মাল্টি-টাইমফ্রেম ডনচিয়ানকে একত্রিত করে। এটি স্বল্পমেয়াদী স্কালপিং কৌশলগুলির অন্তর্গত।
সময়সীমা জুড়ে ব্রেকআউট জোন গঠনের জন্য দিন এবং স্বল্পমেয়াদী মাঝারি পয়েন্ট গণনা করুন।
শুধুমাত্র একটি কাস্টমাইজযোগ্য ট্রেডিং সেশনের সময় ট্রেড করুন। সেশনের শুরুতে প্রবেশ করুন, সেশনের শেষে প্রস্থান করুন।
রিয়েল-টাইম EMA ব্যবহার করুন।
পলাতক এলাকার বাইরে থামো, পলাতক ব্যর্থ হলে থামো।
যখন মূল্য মধ্যপন্থী পয়েন্টের কাছাকাছি ফিরে আসে তখন পজিশন বন্ধ করুন, ব্যর্থ ব্রেকআউট নিশ্চিত করে।
মাল্টি-টাইমফ্রেম সংমিশ্রণ কার্যকরভাবে মিথ্যা breakouts ফিল্টার করতে.
নির্দিষ্ট সেশনের মাধ্যমে বড় বড় সংবাদ ইভেন্টের ঝুঁকি এড়ানো যায়।
ইএমএ ট্র্যাকিং গতির সাথে সামঞ্জস্য রেখে সময়মতো এন্ট্রি করার অনুমতি দেয়।
স্টপগুলি ঝুঁকি নিয়ন্ত্রণে সহায়তা করে।
সেশনের জোরপূর্বক প্রস্থান রাতারাতি ঝুঁকি এড়ায়।
স্বল্পমেয়াদী ব্রেকআউটগুলি হুইপস এবং স্টপ আউটগুলির মুখোমুখি হতে পারে।
সেশন শেষ হওয়ার আগে কিছু ব্রেকআউট পুরোপুরি লাভবান হতে পারে না।
দুর্বল সেশনের সংজ্ঞা সুযোগ হারাতে পারে।
প্রতিটি ব্রেকআউট প্রত্যাশিত মুনাফা অর্জন করবে বলে কোন নিশ্চয়তা নেই।
অপ্টিমাইজেশান প্যারামিটারগুলিকে অতিরিক্ত ফিট করার ঝুঁকি।
সর্বোত্তম সমন্বয় খুঁজে বের করার জন্য পরীক্ষামূলক প্যারামিটার।
প্রবেশের সঠিকতা উন্নত করার জন্য অতিরিক্ত সূচকগুলি মূল্যায়ন করুন।
লাভের তুলনায় ঝুঁকির ভারসাম্যের জন্য ট্রেডিং সেশনের অপ্টিমাইজ করুন।
গবেষণার সমন্বয় লাভের কৌশল গ্রহণ করে।
বিভিন্ন প্রতীকের মধ্যে পরীক্ষার পরামিতি পার্থক্য।
গতিশীল প্যারামিটার অপ্টিমাইজেশনের জন্য মেশিন লার্নিং ব্যবহার করুন।
এই কৌশলটি সীমিত সেশনের ব্রেকআউটের উপর স্বল্পমেয়াদী স্কাল্পিংয়ের চেষ্টা করে। মিথ্যা ব্রেকআউট এবং ঝুঁকি নিয়ন্ত্রণের চারপাশে অপ্টিমাইজেশানগুলির সাথে এটি একটি বাস্তববাদী এবং দক্ষ স্বল্পমেয়াদী সিস্টেমে পরিমার্জন করা যেতে পারে।
/*backtest
start: 2023-08-20 00:00:00
end: 2023-09-19 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=3
strategy("Breakout Scalper", overlay=true)
// -------------------------------------------------------------------------------------------------
// INPUTS
// -------------------------------------------------------------------------------------------------
// Period of the "fast" donchian channel
fast_window = input(title="Fast Window", defval=13, minval=1)
// Used for the volatility (atr) period
slow_window = input(title="Slow Window", defval=52, minval=1)
// Period of EMA used as the current price
instant_period = input(title="Instant Period", defval=3, minval=1)
// Minimum ratio of cloud width to ATR in order for trade to be active
cloud_min_percent = input(title="Minimum Cloud ATR Multiplier", type=float, defval=1.0, minval=0)
// Session where we allow trades to be active
trading_sesh = input(title="Trading Session", defval='1000-1500')
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// SESSION TIMING
// -------------------------------------------------------------------------------------------------
is_newbar(t) =>
na(t[1]) and not na(t) or t[1] < t
day_time = time("D")
sess_time = time(timeframe.period, trading_sesh)
day_open_bar = is_newbar(day_time)
sess_open_bar = is_newbar(sess_time)
sess_close_bar = na(sess_time) and not na(sess_time[1])
sess_is_open = false
sess_is_open := sess_open_bar ? true : (sess_close_bar ? false : sess_is_open[1])
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// DONCHIANS
// -------------------------------------------------------------------------------------------------
slow_high = na
slow_high := day_open_bar ? high : (high > slow_high[1] ? high : slow_high[1])
slow_low = na
slow_low := day_open_bar ? low : (low < slow_low[1] ? low : slow_low[1])
slow_mid = (slow_high + slow_low) / 2
fast_low = max(slow_low, lowest(fast_window))
fast_high = min(slow_high, highest(fast_window))
fast_mid = (fast_low + fast_high) / 2
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// TREND CLOUD
// -------------------------------------------------------------------------------------------------
cloud_width = fast_mid - slow_mid
slow_atr = atr(slow_window)
cloud_percent = cloud_width / slow_atr
cloud_color = cloud_percent > cloud_min_percent ? green : (cloud_percent < -cloud_min_percent ? red : gray)
fp = plot(fast_mid, title="Fast MidR", color=green)
sp = plot(slow_mid, title="Slow MidR", color=red)
fill(fp, sp, color=cloud_color)
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// INSTANT PRICE
// -------------------------------------------------------------------------------------------------
instant_price = ema(close, instant_period)
plot(instant_price, title="Instant Price", color=black, transp=50)
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// ENTRY SIGNALS & STOPS
// -------------------------------------------------------------------------------------------------
buy_entry_signal = sess_is_open and (instant_price > fast_mid) and (cloud_percent > cloud_min_percent)
sell_entry_signal = sess_is_open and (instant_price < fast_mid) and (cloud_percent < -cloud_min_percent)
buy_close_signal = sess_close_bar or (cloud_percent < 0)
sell_close_signal = sess_close_bar or (cloud_percent > 0)
entry_buy_stop = slow_high
entry_sell_stop = slow_low
exit_buy_stop = max(slow_low, fast_low)
exit_sell_stop = min(slow_high, fast_high)
entry_buy_stop_color = (strategy.position_size == 0) ? (buy_entry_signal ? green : na) : na
plotshape(entry_buy_stop, location=location.absolute, color=entry_buy_stop_color, style=shape.circle)
entry_sell_stop_color = (strategy.position_size == 0) ? (sell_entry_signal ? red : na) : na
plotshape(entry_sell_stop, location=location.absolute, color=entry_sell_stop_color, style=shape.circle)
exit_buy_stop_color = (strategy.position_size > 0) ? red : na
plotshape(exit_buy_stop, location=location.absolute, color=exit_buy_stop_color, style=shape.xcross)
exit_sell_stop_color = (strategy.position_size < 0) ? green : na
plotshape(exit_sell_stop, location=location.absolute, color=exit_sell_stop_color, style=shape.xcross)
// -------------------------------------------------------------------------------------------------
// -------------------------------------------------------------------------------------------------
// STRATEGY EXECUTION
// -------------------------------------------------------------------------------------------------
strategy.entry("long", strategy.long, stop=entry_buy_stop, when=buy_entry_signal)
strategy.cancel("long", when=not buy_entry_signal)
strategy.exit("stop", "long", stop=exit_buy_stop)
strategy.entry("short", strategy.short, stop=entry_sell_stop, when=sell_entry_signal)
strategy.cancel("short", when=not sell_entry_signal)
strategy.exit("stop", "short", stop=exit_sell_stop)
strategy.close("long", when=buy_close_signal)
strategy.close("short", when=sell_close_signal)
// -------------------------------------------------------------------------------------------------