Engbereichsschwingung und interne Durchbruchsstrategie
ChaoZhang
Strategieübersicht
Die Breakout-Strategie ist eine Strategie zur Identifizierung von Breakouts in den Schmalen Schwankungen und in den inneren Schließungen. Sie beurteilt die Richtung der Mittellinie, wenn die Doppelbedingungen für die Schmalen Schwankungen und die inneren Schließungen erfüllt sind, und erzeugt mehrere Signale, um die Preisentwicklung nach dem Breakout zu erfassen.
Strategieprinzip
Der Tag mit dem geringsten Kursbewegungen in den letzten 7 Tagen wird mit NR7 ermittelt.
Die Vortagshöhe ist niedriger als die Vortagshöhe und die Vortagshöhe ist höher als die Vortagshöhe
Wenn die NR7 und die innere Schließung gleichzeitig auftreten und der Schließungspreis höher ist als der Öffnungspreis, tritt man in die Überschuldung ein
Die Plateau-Bedingung ist, dass der Schlusskurs am nächsten Tag höher ist als der Eröffnungskurs.
Die Strategie nutzt die beiden Hauptsignale der Schrumpfung der Preisschwankungen und des internen Abschlusses, um zu beurteilen, ob der Markt in eine Phase der kumulierten Erschütterung eingetreten ist. Wenn die Durchschnittslinie nach oben geht, ist es wahrscheinlich, dass der Preis einen Durchbruch verursacht. Diese Mehrfach-Bedingungsfilterung kann die Genauigkeit des tatsächlichen Handels verbessern.
Außerdem ist die Strategie so konzipiert, dass man nicht in den Schwankungsbereichen feststeckt und unnötige Transaktionen reduziert.
Strategische Vorteile
Die beiden größten Signale für die Schwingungsschwächung und die innere Abschließung
Die Richtung der mittleren Linie bestimmt die Existenz einer großen Tendenz.
Mehrfach-Konditions-Filterung zur Verbesserung der Signalgenauigkeit
Nur mehr tun, um Schokken zu vermeiden
Optimierbare Rückmeldparameter und flexible Strategien
Gefahrenwarnung
Die Parameter der Durchschnittslinie müssen entsprechend angepasst werden, um die Handelssignale zu optimieren.
Es gibt eine Reihe von Faktoren, die einen Rückgang des Kaufpreises verursachen können.
Nur mehr zu tun, bringt keinen Gewinn.
Die Ausbreitung der Erschütterung ist noch zu verhindern.
Zusammenfassen
Die Breakout-Strategie der engen Schwingung innerhalb der Schwingung beurteilt die Marktstruktur in hohem Maße und erzeugt Handelssignale bei hoher Wahrscheinlichkeit. Sie hat eine starke Anpassungsfähigkeit und kann durch Anpassung der Parameter optimiert werden. Die Strategie verdient eine Rücktestprüfung und eine virtuelle Anpassung und kann zu einem wichtigen Modul in einem quantitativen Handelssystem werden.
/*backtest
start: 2023-09-11 00:00:00
end: 2023-09-14 00:00:00
period: 10m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=2
strategy("NR7ID: Narrow Range + Inside Day, Long Only Strategy (by ChartArt)", shorttitle="CA_-_NR7ID_Strat", overlay=true) // max_bars_back=5000
// ChartArt's Narrow Range + Inside Day Strategy (Long Only)
//
// Version 1.0
// Idea by ChartArt on Oktober 16, 2016.
//
// This long only strategy determines when there is both
// a NR7 (narrow range 7, a trading day in which the range
// is narrower than any of the previous six days), plus a
// inside day (high of the current day is lower than the high
// of the previous day and the low of the current day is higher
// than the low of the previous day) both on the same trading day
// and enters a long trade when the close is larger than the
// open and the slope of the simple moving average is upwards, too.
//
// The strategy exits the long trade next time the close is
// larger than the open in any of the next trading days.
//
// In addition the NR7ID can be colored (if close large open
// colored in green, else in red) and the SMA can be drawn
// with a color based on the direction of the SMA slope.
//
// List of my work:
// https://www.tradingview.com/u/ChartArt/
//
// __ __ ___ __ ___
// / ` |__| /\ |__) | /\ |__) |
// \__, | | /~~\ | \ | /~~\ | \ |
//
//
// NR7 Identifier
show_NR7=input(true, type=bool,title="Show Narrow Range 7 (NR7) ?")
range=(high-low)
nr7=(range < range[1]) and (range < range[2]) and (range < range[3]) and (range < range[4]) and (range < range[5]) and (range < range[6])
plotchar(show_NR7?nr7:na, char="7", location=location.abovebar, color=blue)
// Inside Day Identifier
show_insidebar = input(true, type=bool,title="Show Inside Day (I) ?")
insidebar = (high < high[1] and low > low[1])
plotchar(show_insidebar?insidebar:na, char="i", location=location.abovebar, color=blue)
// NR7 + Inside Day Identifier
show_NR7ID = input(true, type=bool,title="Show NR7ID (NR7 + Inside Day) colors ?")
NR7ID = nr7 and insidebar
NR7ID_color = NR7ID and open < close ? green : NR7ID and open > close ? red : gray
barcolor(show_NR7ID?NR7ID_color:na)
// Simple Moving Average
show_ma = input(true, type=bool,title="Show SMA ?")
ma_length = input(14,title="SMA Length")
ma = sma(close,ma_length)
ma_change = change(ma) > 0
ma_change_color = change(ma) > 0 ? green : change(ma) < 0 ? red : blue
plot(show_ma?ma:na,color=ma_change_color,linewidth=3)
// (not enabled) Short Strategy: NR7 + Inside Day + close is smaller than open + change of SMA is downwards
//strategy.entry("sell", strategy.short, when = NR7ID and open > close and ma_change == false, comment="Short")
//strategy.close("sell", when = open > close )
// Long Strategy: NR7 + Inside Day + close is larger than open + change of SMA is upwards
strategy.entry("long", strategy.long, when = NR7ID and open < close and ma_change == true, comment="Long")
strategy.close("long", when = open < close )