Pivotbasierte RSI-Divergenzstrategie

Schriftsteller:ChaoZhang, Datum: 2023-11-28 13:43:05
Tags:

Übersicht

Diese Strategie wird Pivot-basierte RSI Divergenzstrategie genannt. Sie verwendet die Divergenz zwischen RSI-Indikatoren in verschiedenen Zyklen, um Ein- und Ausstiegspunkte zu bestimmen, und fügt langfristige RSI als Filterbedingung hinzu, um die Stabilität der Strategie zu verbessern.

Strategie Logik

Die Strategie beurteilt hauptsächlich die Möglichkeit zu kaufen, wenn es eine versteckte bullische Divergenz oder regelmäßige bullische Divergenz zwischen dem kurzfristigen RSI (z. B. 5-Tage-RSI) und dem Preis gibt; und zu verkaufen, wenn es eine versteckte bärische Divergenz oder regelmäßige bärische Divergenz gibt.

Eine regelmäßige bullische Divergenz bedeutet, dass der Preis ein neues Tief erreicht, während der RSI kein neues Tief erreicht; eine versteckte bullische Divergenz ist das Gegenteil, der Preis erreicht kein neues Tief, während der RSI ein neues Tief erreicht.

Darüber hinaus führt die Strategie auch langfristigen RSI (wie 50-Tage-RSI) als Filterbedingungen ein. Sie berücksichtigt nur Kaufsignale, wenn der lange RSI größer als 50 ist; und betrachtet Stop-Loss oder Take-Profit-Exit, wenn der lange RSI kleiner als 30 ist.

Vorteile

Der größte Vorteil dieser Strategie besteht darin, dass sie sowohl die RSI-Divergenzsignale auf kurze Sicht als auch den Filter des langfristigen RSI nutzt, der verhindern kann, dass sie gefangen werden und Trends bis zu einem gewissen Grad verpassen.

Das kurzfristige RSI-Divergenzsignal kann zu einem frühen Urteil über Preisumkehrmöglichkeiten führen und wichtige Punkte rechtzeitig erfassen;
Der langfristige RSI-Filter verhindert, dass der Trend unsicher ist.
Mehrere Arten von Gewinnspielen und Teilgewinnspielen tragen zur Verringerung des Risikos bei.
Der Pyramidenmechanismus erlaubt das Hinzufügen von Positionen und erweitert das Gewinnpotenzial weiter.

Risiken

Die Strategie birgt auch einige Risiken:

RSI-Divergenzen sind nicht immer gültig und es können falsche Signale vorliegen;
Die Risiken werden nach dem Pyramidenspiel größer, die Verluste könnten sich beschleunigen, wenn das Urteil falsch ist.
Eine unsachgemäße Gewinneinstellung kann auch zu einer vorzeitigen Gewinneinschätzung oder zu unzureichenden Gewinnen führen.

Entsprechende Risikomanagementmaßnahmen umfassen: angemessene Festlegung von Stop-Loss-/Take-Profit-Bedingungen, Kontrolle der Positionsgröße, teilweise Gewinnnahme zur Glättung der Eigenkapitalkurve usw.

Optimierungsrichtlinien

Es besteht Raum für eine weitere Optimierung der Strategie:

Die RSI-Parameter können weiter optimiert werden, um die beste Kombination zu finden;
Divergenzsignale anderer Indikatoren wie MACD und KD können getestet werden;
Die Parameter können speziell für bestimmte Produkte (wie Rohöl, Edelmetalle usw.) optimiert werden, um die Anpassungsfähigkeit zu verbessern.

Zusammenfassung

Diese Strategie kombiniert die lang-/kurzfristigen und langfristigen RSI-Divergenzsignale, um die Rentabilität zu verbessern und gleichzeitig Risiken zu kontrollieren. Sie spiegelt mehrere Prinzipien in der quantitativen Strategieentwicklung wider, einschließlich wann man eintritt, wann man aussteigt, teilweise Gewinngewinn, Stop-Loss/Take-Profit-Einstellung usw. Dies ist eine beispielhafte RSI-Divergenzstrategie zur Referenz.

/*backtest
start: 2023-11-20 00:00:00
end: 2023-11-27 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © mohanee

//@version=4

//GOOGL setting  5 ,50 close, 3 , 1  profitLevel at 75 and No stop Loss shows win rate 99.03 % profit factor 5830.152

strategy(title="RSI5_50 with Divergence", overlay=false,pyramiding=2, default_qty_type=strategy.fixed, default_qty_value=3,    initial_capital=10000, currency=currency.USD)

len = input(title="RSI Period", minval=1, defval=5)
longRSILen = input(title="Long RSI Period", minval=10, defval=50)
src = input(title="RSI Source", defval=close)
lbR = input(title="Pivot Lookback Right", defval=3)
lbL = input(title="Pivot Lookback Left", defval=1)
takeProfitRSILevel = input(title="Take Profit at RSI Level", minval=50, defval=75)
stopLoss = input(title="Stop Loss%(if checked 8% rule applied)", defval=false)

shortTermRSI = rsi(close,len)
longTermRSI = rsi(close,longRSILen)

rangeUpper = input(title="Max of Lookback Range", defval=60)
rangeLower = input(title="Min of Lookback Range", defval=5)
plotBull = input(title="Plot Bullish", defval=true)
plotHiddenBull = input(title="Plot Hidden Bullish", defval=true)
plotBear = input(title="Plot Bearish", defval=true)
plotHiddenBear = input(title="Plot Hidden Bearish", defval=false)


bearColor = color.purple
bullColor = color.green
hiddenBullColor = color.new(color.green, 80)
hiddenBearColor = color.new(color.red, 80)
textColor = color.white
noneColor = color.new(color.white, 100)



plot(shortTermRSI, title="RSI", linewidth=2, color=#8D1699)
plot(longTermRSI, title="longTermRSI", linewidth=2, color=color.orange)

hline(50, title="Middle Line", linestyle=hline.style_dotted)
obLevel = hline(70, title="Overbought", linestyle=hline.style_dotted)
osLevel = hline(30, title="Oversold", linestyle=hline.style_dotted)
fill(obLevel, osLevel, title="Background", color=longTermRSI >=50 ? color.green:color.purple, transp=65)  // longTermRSI >=50

plFound = na(pivotlow(shortTermRSI, lbL, lbR)) ? false : true
phFound = na(pivothigh(shortTermRSI, lbL, lbR)) ? false : true

_inRange(cond) =>
    bars = barssince(cond == true)
    rangeLower <= bars and bars <= rangeUpper

//------------------------------------------------------------------------------
// Regular Bullish

// shortTermRSI: Higher Low
oscHL = shortTermRSI[lbR] > valuewhen(plFound, shortTermRSI[lbR], 1) and _inRange(plFound[1])

// Price: Lower Low
priceLL = low[lbR] < valuewhen(plFound, low[lbR], 1)

bullCond = plotBull and priceLL and oscHL and plFound

plot(
	 plFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bullish",
	 linewidth=2,
	 color=(bullCond ? bullColor : noneColor),
	 transp=0
	 )


plotshape(
	 bullCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bullish Label",
	 text=" Bull ",
	 style=shape.labelup,
	 location=location.absolute,
	 color=bullColor,
	 textcolor=textColor,
	 transp=0
	 )

//------------------------------------------------------------------------------
// Hidden Bullish

// shortTermRSI: Lower Low
oscLL = shortTermRSI[lbR] < valuewhen(plFound, shortTermRSI[lbR], 1) and _inRange(plFound[1])

// Price: Higher Low
priceHL = low[lbR] > valuewhen(plFound, low[lbR], 1)

hiddenBullCond = plotHiddenBull and priceHL and oscLL and plFound

plot(
	 plFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bullish",
	 linewidth=2,
	 color=(hiddenBullCond ? hiddenBullColor : noneColor),
	 transp=0
	 )

plotshape(
	 hiddenBullCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bullish Label",
	 text=" H Bull ",
	 style=shape.labelup,
	 location=location.absolute,
	 color=bullColor,
	 textcolor=textColor,
	 transp=0
	 )

longCondition= longTermRSI >=50  and ( (bullCond or hiddenBullCond ) )  or  (strategy.position_size>0 and crossover(shortTermRSI,20) )
//last condition above is to leg in if you are already in the Long trade, 


strategy.entry(id="RSIDivLE", long=true,  when=longCondition)


//------------------------------------------------------------------------------
// Regular Bearish

// shortTermRSI: Lower High
oscLH = shortTermRSI[lbR] < valuewhen(phFound, shortTermRSI[lbR], 1) and _inRange(phFound[1])

// Price: Higher High
priceHH = high[lbR] > valuewhen(phFound, high[lbR], 1)

bearCond = plotBear and priceHH and oscLH and phFound

plot(
	 phFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bearish",
	 linewidth=2,
	 color=(bearCond ? bearColor : noneColor),
	 transp=0
	 )

plotshape(
	 bearCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Regular Bearish Label",
	 text=" Bear ",
	 style=shape.labeldown,
	 location=location.absolute,
	 color=bearColor,
	 textcolor=textColor,
	 transp=0
	 )

//------------------------------------------------------------------------------
// Hidden Bearish

// shortTermRSI: Higher High
oscHH = shortTermRSI[lbR] > valuewhen(phFound, shortTermRSI[lbR], 1) and _inRange(phFound[1])

// Price: Lower High
priceLH = high[lbR] < valuewhen(phFound, high[lbR], 1)

hiddenBearCond = plotHiddenBear and priceLH and oscHH and phFound

plot(
	 phFound ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bearish",
	 linewidth=2,
	 color=(hiddenBearCond ? hiddenBearColor : noneColor),
	 transp=0
	 )

plotshape(
	 hiddenBearCond ? shortTermRSI[lbR] : na,
	 offset=-lbR,
	 title="Hidden Bearish Label",
	 text=" H Bear ",
	 style=shape.labeldown,
	 location=location.absolute,
	 color=bearColor,
	 textcolor=textColor,
	 transp=0
	 )
	 
	 
//calculate stop Loss
stopLossVal = stopLoss==true ? ( strategy.position_avg_price -  (strategy.position_avg_price*0.08) ) : 0

//partial profit
strategy.close(id="RSIDivLE", comment="TP1", qty=strategy.position_size*3/4, when=strategy.position_size>0 and (longTermRSI>=takeProfitRSILevel or crossover(longTermRSI,90)))
strategy.close(id="RSIDivLE",comment="TP2",   qty=strategy.position_size*3/4 , when=crossover(longTermRSI,70))
strategy.close(id="RSIDivLE",comment="TP3",   qty=strategy.position_size/2, when=crossover(longTermRSI,65))
strategy.close(id="RSIDivLE",comment="TP4",   qty=strategy.position_size/2 , when=crossover(longTermRSI,60))

//close the whole position when stoploss hits or longTermRSI goes below 30
strategy.close(id="RSIDivLE",comment="Exit",    when=crossunder(longTermRSI,30) or close<stopLossVal)

Mehr