El indicador MA es la abreviatura del inglés ((Moving average) y se llama el indicador de promedio móvil. El promedio móvil ((MA) tiene una característica de tendencia, que es relativamente estable, a diferencia de la línea K del día que subirá y caerá. Cuanto más largo sea el promedio móvil, más estable será el rendimiento. No es fácil subir y bajar, debe esperar a la verdadera claridad de la tendencia del precio de las acciones.
En este número, compartimos la estrategia de combinación del índice MACD + MA. En el análisis técnico, la combinación de indicadores es muy común. Diferentes indicadores tienen diferentes puntos de operación y métodos de análisis. La combinación de indicadores puede mejorar la precisión de la señal. La estrategia es comparar la relación entre el precio y el MA, y luego medir la aceleración del movimiento del precio por el índice MACD para juzgar el estado del mercado y construir una estrategia de negociación de tiempo simple.
(*backtest
start: 2018-11-01 00:00:00
end: 2018-11-22 00:00:00
period: 1h
exchanges: [{"eid":"Bitfinex","currency":"BTC_USD"}]
*)
// MACD calculation
FASTLENGTH:=12;
SLOWLENGTH:=26;
MACDLENGTH:=9;
// Length of MA
L1:=50;
L2:=120;
// stop loss 止损 5%
STOPLOSS:=5;
//MACD
MACDVALUE:=EMA(CLOSE,FASTLENGTH)-EMA(CLOSE,SLOWLENGTH);
AVGMACD:=EMA(MACDVALUE,MACDLENGTH);
MACDDIFF:=MACDVALUE-AVGMACD;
//MA1、MA2
DMA1:=MA(C,L1);
DMA2:=MA(C,L2);
BUYCONDITION:=MACDVALUE>0 && DMA1>DMA2 && MACDDIFF>0 && C>DMA1 && REF(C,1)>REF(DMA1,1);
SELLCONDITION:=MACDVALUE<0 && DMA1<DMA2 && MACDDIFF<0 && C<DMA1 && REF(C,1)<REF(DMA1,1);
// 开仓条件 When to open position
BKVOL=0 AND BUYCONDITION,BK;
SETSIGPRICETYPE(BK,NEW_ORDER);
SKVOL=0 AND SELLCONDITION,SK;
SETSIGPRICETYPE(SK,NEW_ORDER);
// 离场条件 When to close position
BKVOL>0 AND (REF(MACDVALUE,1)<0 OR REF(DMA1,1)<REF(DMA2,1)),SP;
SKVOL>0 AND (REF(MACDVALUE,1)>0 OR REF(DMA1,1)>REF(DMA2,1)),BP;
// 启动止损 Start stop loss
SKVOL>0 AND HIGH>=SKPRICE*(1+STOPLOSS*0.01),BP;
BKVOL>0 AND LOW<=BKPRICE*(1-STOPLOSS*0.01),SP;
AUTOFILTER;