Captador de tendencias de doble ruta
EMA MACD VOLUME PINBAR RESISTANCE
ianzeng123
Esta no es una estrategia de EMA común, sino un sistema de francotiradores de precisión de dos vías
Este conjunto de estrategias de dos pasos de MNO descompone el comercio de tendencias en dos caminos completamente diferentes: el camino de ruptura de MOU y el camino de reajuste de KAKU. Los datos de retrospectiva muestran que el diseño de dos caminos mejora la tasa de éxito en más del 30% en comparación con la estrategia tradicional de una sola señal.
La lógica central es sencilla: el 5/13/26 triple EMA Gold se alineará para confirmar la dirección de la tendencia y luego elegir diferentes momentos de entrada según el estado del mercado. No todos los breaks merecen la pena de ser seguidos, ni todos los retrocesiones pueden ser subtraídos.
MOU Breakout Path: Gran intercambio de trabajo en el forquillo de oro cerca del eje cero del MACD
El camino MOU se divide en dos situaciones. La primera es la entrada de retroceso después de la clásica ruptura de resistencia, que requiere una amplitud de retroceso de entre el 5% y el 15%, demasiado superficial para indicar la incapacidad de la ruptura, demasiado profunda para indicar la falsa ruptura. La segunda es la entrada de ruptura directa, pero las condiciones son más exigentes.
La confirmación de la ruptura requiere que el precio de cierre supere el nivel de resistencia anterior en más del 0.3%, y que la entidad de la línea K sea más del 20% mayor que la entidad promedio de los últimos 20 ciclos. Este diseño filtra el 90% de las señales de falsa ruptura.
El factor de volumen de ventas está configurado entre 1.3 y 3.0 veces. Menos de 1.3 veces indica impotencia para romper, más de 3.0 veces suele ser un estímulo informativo, con una gran probabilidad de debilidad posterior.
Reconocimiento de KAKU: 8 condiciones básicas + 3 confirmaciones finales
KAKU es una versión estricta, que requiere cumplir con 8 condiciones básicas para entrar en el grupo de candidatos. Luego, se debe pasar por 3 confirmaciones finales: la forma de la línea K de los pinos, el tenedor de plata del MACD en el eje cero, el tráfico de fuerza ((más de 1,5 veces)) [2].
La idea de diseño es clara: buscar el punto de retorno más seguro para comprar solo en las tendencias más fuertes. La retrospectiva histórica muestra que las señales de KAKU tienen más del 75% de éxito, pero tienen una frecuencia 60% menor que las MOU.
El criterio de juicio de la línea K de los pinos es que la longitud de la línea de sombra inferior es ≥ 2 veces la entidad, y el precio de cierre es ≥ el precio de apertura. Esta forma tiene la mayor tasa de éxito en la regresión de fuerza.
Diseño de control de viento: 2% de detención y 1% de detención, hasta 30 ciclos de tenencia
El Stop Loss Ratio de 2:1 parece conservador, pero combinado con 30 períodos para obligar a cerrar posiciones, en realidad se trata de controlar el costo del tiempo. Los datos muestran que las posiciones de más de 30 períodos, incluso si finalmente son rentables, la rentabilidad anual disminuye significativamente.
El mayor riesgo de esta estrategia es el mercado de las sacudidas. Cuando los precios oscilan repetidamente cerca de EMA26, se producen una gran cantidad de falsas señales. Se recomienda su uso en mercados de tendencia clara, evitando la temporada de resultados y antes y después de eventos importantes.
Recomendación de ajuste de parámetros: Ajuste el multiplicador de volumen de transacción según la fluctuación del indicador
Para los indicadores de alta volatilidad (como las acciones de crecimiento), se recomienda reducir el multiplicador de volumen de transacciones a 1.2-2.5 veces. Para los indicadores de baja volatilidad (como los planes de inversión), se puede aumentar a 1.5-3.5 veces.
El umbral del eje cero del MACD de 0,2 está optimizado para el nivel de la línea de sol, y si se utiliza en el nivel de 4 horas o 1 hora, se recomienda ajustar a 0,1 o 0,05.
La amplitud de regresión del 5% al 15% también necesita ser ajustada según las características de la norma. La norma de alta beta puede ser flexibilizada hasta el 3% al 20% y la norma de baja beta puede ser ajustada hasta el 4% al 12%.
Aplicaciones en la guerra: prioridad para las señales KAKU, MOU como complemento
Si aparece una señal KAKU y una MOU al mismo tiempo, seleccione KAKU. Si solo desea una señal de la más alta calidad, puede configurarla como “modo solo KAKU”, y esperar que la cantidad de señales disminuya pero la calidad sea mayor.
Esta estrategia no es adecuada para los operadores frecuentes, que pueden tener una media de 2-3 señales de alta calidad por mes. Pero la rentabilidad ajustada al riesgo de cada señal es claramente superior a la media del mercado.
Recuerde: el retroceso histórico no representa ganancias futuras, y cualquier estrategia tiene la posibilidad de pérdidas continuas.
/*backtest
start: 2024-12-17 00:00:00
end: 2025-12-15 08:00:00
period: 1h
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT","balance":500000}]
*/
//@version=5
strategy("MNO_2Step_Strategy_MOU_KAKU (Publish-Clear)", overlay=true, default_qty_value=10)
// =========================
// Inputs
// =========================
emaSLen = input.int(5, "EMA Short (5)")
emaMLen = input.int(13, "EMA Mid (13)")
emaLLen = input.int(26, "EMA Long (26)")
macdFast = input.int(12, "MACD Fast")
macdSlow = input.int(26, "MACD Slow")
macdSignal = input.int(9, "MACD Signal")
macdZeroTh = input.float(0.2, "MOU: MACD near-zero threshold", step=0.05)
volLookback = input.int(5, "Volume MA days", minval=1)
volMinRatio = input.float(1.3, "MOU: Volume ratio min", step=0.1)
volStrong = input.float(1.5, "Strong volume ratio (Breakout/KAKU)", step=0.1)
volMaxRatio = input.float(3.0, "Volume ratio max (filter)", step=0.1)
wickBodyMult = input.float(2.0, "Pinbar: lowerWick >= body*x", step=0.1)
pivotLen = input.int(20, "Resistance lookback", minval=5)
pullMinPct = input.float(5.0, "Pullback min (%)", step=0.1)
pullMaxPct = input.float(15.0, "Pullback max (%)", step=0.1)
breakLookbackBars = input.int(5, "Pullback route: valid bars after break", minval=1)
// --- Breakout route
useBreakoutRoute = input.bool(true, "Enable MOU Breakout Route (no pullback)")
breakConfirmPct = input.float(0.3, "Break confirm: close > R*(1+%)", step=0.1)
bigBodyLookback = input.int(20, "Break candle body MA length", minval=5)
bigBodyMult = input.float(1.2, "Break candle: body >= MA*mult", step=0.1)
requireCloseNearHigh = input.bool(true, "Break candle: close near high")
closeNearHighPct = input.float(25.0, "Close near high threshold (% of range)", step=1.0)
allowMACDAboveZeroInstead = input.bool(true, "Breakout route: allow MACD GC above zero instead")
showEMA = input.bool(true, "Plot EMAs")
showMouLabels = input.bool(true, "Show MOU/MOU-B labels")
showKakuLabels = input.bool(true, "Show KAKU labels")
showDebugTbl = input.bool(true, "Show debug table (last bar)")
showStatusLbl = input.bool(true, "Show status label (last bar always)")
locChoice = input.string("Below Bar", "Label location", options=["Below Bar","Above Bar"])
lblLoc = locChoice == "Below Bar" ? location.belowbar : location.abovebar
// =========================
// =========================
enableTPSL = input.bool(true, "Enable TP/SL")
tpPct = input.float(2.0, "Take Profit (%)", step=0.1, minval=0.1) // ←投稿クリア向けに近め
slPct = input.float(1.0, "Stop Loss (%)", step=0.1, minval=0.1) // ←投稿クリア向けに近め
maxHoldBars = input.int(30, "Max bars in trade (force close)", minval=1)
entryMode = input.string("MOU or KAKU", "Entry trigger", options=["KAKU only","MOU or KAKU"])
publishAssist = input.bool(true, "Publish Assist (safety entry if 0 trades)")
// =========================
// EMA
// =========================
emaS = ta.ema(close, emaSLen)
emaM = ta.ema(close, emaMLen)
emaL = ta.ema(close, emaLLen)
plot(showEMA ? emaS : na, color=color.new(color.yellow, 0), title="EMA 5")
plot(showEMA ? emaM : na, color=color.new(color.blue, 0), title="EMA 13")
plot(showEMA ? emaL : na, color=color.new(color.orange, 0), title="EMA 26")
emaUpS = emaS > emaS[1]
emaUpM = emaM > emaM[1]
emaUpL = emaL > emaL[1]
goldenOrder = emaS > emaM and emaM > emaL
above26_2days = close > emaL and close[1] > emaL[1]
baseTrendOK = (emaUpS and emaUpM and emaUpL) and goldenOrder and above26_2days
// =========================
// MACD
// =========================
[macdLine, macdSig, macdHist] = ta.macd(close, macdFast, macdSlow, macdSignal)
macdGC = ta.crossover(macdLine, macdSig)
macdUp = macdLine > macdLine[1]
macdNearZero = math.abs(macdLine) <= macdZeroTh
macdGCAboveZero = macdGC and macdLine > 0 and macdSig > 0
macdMouOK = macdGC and macdNearZero and macdUp
macdBreakOK = allowMACDAboveZeroInstead ? (macdMouOK or macdGCAboveZero) : macdMouOK
// =========================
// Volume
// =========================
volMA = ta.sma(volume, volLookback)
volRatio = volMA > 0 ? (volume / volMA) : na
volumeMouOK = volRatio >= volMinRatio and volRatio <= volMaxRatio
volumeStrongOK = volRatio >= volStrong and volRatio <= volMaxRatio
// =========================
// Candle patterns
// =========================
body = math.abs(close - open)
upperWick = high - math.max(open, close)
lowerWick = math.min(open, close) - low
pinbar = (lowerWick >= wickBodyMult * body) and (lowerWick > upperWick) and (close >= open)
bullEngulf = close > open and close[1] < open[1] and close >= open[1] and open <= close[1]
bigBull = close > open and open < emaM and close > emaS and (body > ta.sma(body, 20))
candleOK = pinbar or bullEngulf or bigBull
// =========================
// Resistance / Pullback route
// =========================
res = ta.highest(high, pivotLen)
pullbackPct = res > 0 ? (res - close) / res * 100.0 : na
pullbackOK = pullbackPct >= pullMinPct and pullbackPct <= pullMaxPct
brokeRes = ta.crossover(close, res[1])
barsSinceBreak = ta.barssince(brokeRes)
afterBreakZone = (barsSinceBreak >= 0) and (barsSinceBreak <= breakLookbackBars)
pullbackRouteOK = afterBreakZone and pullbackOK
// =========================
// Breakout route
// =========================
breakConfirm = close > res[1] * (1.0 + breakConfirmPct / 100.0)
bullBreak = close > open
bodyMA = ta.sma(body, bigBodyLookback)
bigBodyOK = bodyMA > 0 ? (body >= bodyMA * bigBodyMult) : false
rng = math.max(high - low, syminfo.mintick)
closeNearHighOK = not requireCloseNearHigh ? true : ((high - close) / rng * 100.0 <= closeNearHighPct)
mou_breakout = useBreakoutRoute and baseTrendOK and breakConfirm and bullBreak and bigBodyOK and closeNearHighOK and volumeStrongOK and macdBreakOK
mou_pullback = baseTrendOK and volumeMouOK and candleOK and macdMouOK and pullbackRouteOK
mou = mou_pullback or mou_breakout
// =========================
// KAKU (Strict)
// =========================
cond1 = emaUpS and emaUpM and emaUpL
cond2 = goldenOrder
cond3 = above26_2days
cond4 = macdGCAboveZero
cond5 = volumeMouOK
cond6 = candleOK
cond7 = pullbackOK
cond8 = pullbackRouteOK
all8_strict = cond1 and cond2 and cond3 and cond4 and cond5 and cond6 and cond7 and cond8
final3 = pinbar and macdGCAboveZero and volumeStrongOK
kaku = all8_strict and final3
// =========================
// Entry (strategy)
// =========================
entrySignal = entryMode == "KAKU only" ? kaku : (mou or kaku)
canEnter = strategy.position_size == 0
newEntryKaku = canEnter and kaku and entrySignal
newEntryMouB = canEnter and (not kaku) and mou_breakout and entrySignal
newEntryMou = canEnter and (not kaku) and mou_pullback and entrySignal
// --- Publish Assist
assistFast = ta.ema(close, 5)
assistSlow = ta.ema(close, 20)
assistEntry = publishAssist and strategy.closedtrades == 0 and canEnter and ta.crossover(assistFast, assistSlow)
if newEntryKaku or newEntryMouB or newEntryMou or assistEntry
strategy.entry("LONG", strategy.long)
inPos = strategy.position_size > 0
tpPx = inPos ? strategy.position_avg_price * (1.0 + tpPct/100.0) : na
slPx = inPos ? strategy.position_avg_price * (1.0 - slPct/100.0) : na
if enableTPSL
strategy.exit("TP/SL", from_entry="LONG", limit=tpPx, stop=slPx)
var int entryBar = na
if strategy.position_size > 0 and strategy.position_size[1] == 0
entryBar := bar_index
if strategy.position_size == 0
entryBar := na
forceClose = inPos and not na(entryBar) and (bar_index - entryBar >= maxHoldBars)
if forceClose
strategy.close("LONG")
closedThisBar = (strategy.position_size[1] > 0) and (strategy.position_size == 0)
avgPrev = strategy.position_avg_price[1]
tpPrev = avgPrev * (1.0 + tpPct/100.0)
slPrev = avgPrev * (1.0 - slPct/100.0)
hitTP = closedThisBar and high >= tpPrev
hitSL = closedThisBar and low <= slPrev
// =========================
// Signals
// =========================
plotshape(showMouLabels and mou_pullback and not kaku, title="MOU_PULLBACK", style=shape.labelup, text="猛",
color=color.new(color.lime, 0), textcolor=color.black, location=lblLoc, size=size.tiny)
plotshape(showMouLabels and mou_breakout and not kaku, title="MOU_BREAKOUT", style=shape.labelup, text="猛B",
color=color.new(color.lime, 0), textcolor=color.black, location=lblLoc, size=size.tiny)
plotshape(showKakuLabels and kaku, title="KAKU", style=shape.labelup, text="確",
color=color.new(color.yellow, 0), textcolor=color.black, location=lblLoc, size=size.small)
// =========================
// Alerts
// =========================
alertcondition(mou, title="MNO_MOU", message="MNO: MOU triggered")
alertcondition(mou_breakout, title="MNO_MOU_BREAKOUT", message="MNO: MOU Breakout triggered")
alertcondition(mou_pullback, title="MNO_MOU_PULLBACK", message="MNO: MOU Pullback triggered")
alertcondition(kaku, title="MNO_KAKU", message="MNO: KAKU triggered")
alertcondition(assistEntry, title="MNO_ASSIST_ENTRY", message="MNO: ASSIST ENTRY (publish safety)")