Stratégie de trading à double moyenne mobile Golden Cross et Death Cross


Date de création: 2023-12-01 14:36:33 Dernière modification: 2023-12-01 14:36:33
Copier: 9 Nombre de clics: 614
avatar of ChaoZhang ChaoZhang
1
Suivre
1619
Abonnés

Stratégie de trading à double moyenne mobile Golden Cross et Death Cross

Aperçu

La stratégie de négociation bi-équilibrée génère des signaux de négociation en calculant des moyennes mobiles indicielles de différentes périodes, en formant des lignes rapides et lentes, et en observant leur forme de fourche dorée et de fourche morte. Lorsque la ligne rapide traverse la ligne lente par le bas, faites plus; lorsque la ligne rapide traverse la ligne lente par le haut et le bas, faites moins.

Principe de stratégie

Les indicateurs centraux de la stratégie de négociation en ligne biuniversale sont le calcul de la ligne rapide et de la ligne lente. La ligne rapide indique la moyenne mobile indicielle pour les périodes courtes, avec le paramètre par défaut de la ligne de 12 jours; la ligne lente indique la moyenne mobile indicielle pour les périodes longues, avec le paramètre par défaut de la ligne de 26 jours. La formule de calcul de la moyenne mobile indicielle est:

EMA(t) = (C(t) - EMA(t-1)) * SF + EMA(t-1)

La différence entre les moyennes mobiles indicielles et les moyennes mobiles arithmétiques ordinaires réside dans le fait que les moyennes mobiles indicielles donnent plus de poids aux données les plus récentes et peuvent répondre plus rapidement aux variations de prix.

Les règles de négociation de la stratégie de double équilibre sont:

  • La ligne rapide passe par la ligne lente en dessous, c’est-à-dire que la croix d’or est formée, ce qui permet une entrée supplémentaire.
  • La ligne rapide passe du haut en bas de la ligne lente, c’est-à-dire que la croix morte est formée, ouvrant l’entrée.
  • Quand les lignes rapides et les lignes lentes s’écartent, le joueur est éliminé.

Capture et surveille la forme croisée de la ligne de parité, réagit en temps opportun aux changements de la relation d’offre et de la demande du marché et réalise des bénéfices.

Analyse des avantages

La stratégie de négociation en deux lignes a les avantages suivants en tant que stratégie d’indicateur technique plus mature:

  1. La clarté d’esprit, la facilité de compréhension et de mise en œuvre;
  2. Les résultats de l’étude ont été publiés dans le journal L’Agence de l’Economie et de l’Industrie.
  3. Il est également possible de filtrer efficacement le bruit du marché pour capturer les principales tendances.
  4. Les applications sont adaptées aux différents marchés et aux différentes périodes de temps.
  5. Les résultats de l’étude ont été publiés dans le Journal of the World Economic Forum.
  6. Le taux d’utilisation des fonds est élevé, ce qui correspond à une forte demande de fonds.

Analyse des risques

Les stratégies de négociation en ligne à deux lignes présentent également des inconvénients et des risques:

  1. Le blogueur a écrit sur son blog:
  2. La tendance à la fausseté des signaux et à l’intensification des transactions due à de fréquentes vibrations mineures;
  3. Les paramètres doivent être optimisés pour les différentes variétés et périodes de temps.
  4. Il n’y a pas d’indications sur la position raisonnable de l’inverse.

Les risques ci-dessus peuvent être optimisés par des méthodes telles que l’ajustement des paramètres de cycle moyen, l’introduction de filtres supplémentaires, etc., afin d’assurer une stratégie plus robuste.

Direction d’optimisation

Les stratégies de négociation en ligne biuniversale peuvent être optimisées dans les domaines suivants:

  1. L’introduction de l’indicateur MACD pour évaluer les tendances fortes et faibles, afin d’éviter les erreurs de négociation dans les tendances faibles et instables;
  2. L’augmentation des volumes de transactions comme indicateur de confirmation, afin d’éviter les fausses ruptures qui entraîneraient une reprise de la tendance;
  3. la définition de conditions d’entrée et de sortie plus précises, combinées à d’autres indicateurs techniques tels que les lignes de Brin et K;
  4. L’optimisation automatique des paramètres de la ligne moyenne par des méthodes d’apprentissage automatique telles que LSTM permet une meilleure adaptabilité au marché.

Résumer

La stratégie de négociation en ligne biuniforme capte les opportunités de négociation en ligne biuniforme, détermine les points de retournement de la tendance des prix et réalise des bénéfices stables. L’avantage de cette stratégie réside dans sa simplicité et sa clarté, son efficacité financière et est la stratégie de choix pour la quantification.

Code source de la stratégie 
/*backtest
start: 2022-11-24 00:00:00
end: 2023-11-30 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © antondmt

//@version=5
strategy("Returns & Drawdowns Table", "R & DD", true, calc_on_every_tick = false, default_qty_type = strategy.percent_of_equity, default_qty_value = 100, process_orders_on_close = true)
i_eq_to_dd =            input.string("Compound Equity", "Mode", ["Simple Equity", "Compound Equity", "Drawdown"], group = "R & DD Table")
i_precision =           input.int(2, "Return Precision", group = "R & DD Table")
i_headers_col =         input.color(#D4D4D4, "Headers Color", group = "R & DD Table")
i_headers_text_col =    input.color(color.black, "Headers Text Color", group = "R & DD Table")
i_pos_col =             input.color(color.green, "Positive Color", group = "R & DD Table")
i_neg_col =             input.color(color.red, "Negative Color", group = "R & DD Table")
i_zero_col =            input.color(#DDDDDD, "Zero Color", group = "R & DD Table")
i_cell_text_col =       input.color(color.white, "Cell Text Color", group = "R & DD Table")

// TIME {
var month_times = array.new_int(0)                                                              // Array of all month times  
new_month = month(time) != month(time[1]) 
if(new_month or barstate.isfirst)
    array.push(month_times, time)

var year_times = array.new_int(0)                                                               
new_year = year(time) != year(time[1])  
if (new_year or barstate.isfirst)
    array.push(year_times, time)
//}

// SIMPLE EQUITY CALCULATIONS {
// Simple equity is strictly calculated from start to end of each month/year equity. There is no compound
var monthly_simp_pnls = array.new_float(0)                                                      // Array of all monthly profits and losses
var yearly_simp_pnls = array.new_float(0)                                                       

if(i_eq_to_dd == "Simple Equity")
    var initial_monthly_equity = strategy.equity                                                // Starting equity for each month
    cur_month_pnl = nz((strategy.equity - initial_monthly_equity) / initial_monthly_equity)     // Current month's equity change
    if(new_month or barstate.isfirst)
        initial_monthly_equity := strategy.equity
        array.push(monthly_simp_pnls, cur_month_pnl)
    else 
        array.set(monthly_simp_pnls, array.size(monthly_simp_pnls) - 1, cur_month_pnl)
    
    var initial_yearly_equity = strategy.equity
    cur_year_pnl = nz((strategy.equity - initial_yearly_equity) / initial_yearly_equity)
    if (new_year or barstate.isfirst)
        initial_yearly_equity := strategy.equity
        array.push(yearly_simp_pnls, cur_year_pnl)
    else 
        array.set(yearly_simp_pnls, array.size(yearly_simp_pnls) - 1, cur_year_pnl)
// }

// COMPOUND EQUITY CALCULATIONS {
// Compound equity is strictly calculated based on equity state from the beginning of time until the end of each month/year equity. It shows the exact equity movement through time
var monthly_comp_pnls = array.new_float(0)                                                      // Array of all monthly profits and losses
var yearly_comp_pnls = array.new_float(0)                                                       

if(i_eq_to_dd == "Compound Equity")
    var initial_equity = strategy.equity                                                
    cur_month_pnl = nz((strategy.equity - initial_equity) / initial_equity)                     // Current month's equity change
    if(new_month or barstate.isfirst)
        array.push(monthly_comp_pnls, cur_month_pnl)
    else 
        array.set(monthly_comp_pnls, array.size(monthly_comp_pnls) - 1, cur_month_pnl)
    
    cur_year_pnl = nz((strategy.equity - initial_equity) / initial_equity)
    if (new_year or barstate.isfirst)
        array.push(yearly_comp_pnls, cur_year_pnl)
    else 
        array.set(yearly_comp_pnls, array.size(yearly_comp_pnls) - 1, cur_year_pnl)
// }
    
// DRAWDOWN CALCULATIONS {
// Drawdowns are calculated from highest equity to lowest trough for the month/year
var monthly_dds = array.new_float(0)                                                            // Array of all monthly drawdowns
var yearly_dds = array.new_float(0)                                                             

if (i_eq_to_dd == "Drawdown")
    total_equity = strategy.equity - strategy.openprofit                        
    
    var cur_month_dd = 0.0  
    var m_ATH = total_equity                                                                    // Monthly All-Time-High (ATH). It is reset each month
    m_ATH := math.max(total_equity, nz(m_ATH[1]))
    m_drawdown = -math.abs(total_equity / m_ATH * 100 - 100) / 100                              // Drawdown at current bar
    if(m_drawdown < cur_month_dd)
        cur_month_dd := m_drawdown
    if(new_month or barstate.isfirst)
        cur_month_dd := 0.0
        m_ATH := strategy.equity - strategy.openprofit
        array.push(monthly_dds, 0)
    else 
        array.set(monthly_dds, array.size(monthly_dds) - 1, cur_month_dd)
    
    var cur_year_dd = 0.0
    var y_ATH = total_equity
    y_ATH := math.max(total_equity, nz(y_ATH[1]))
    y_drawdown = -math.abs(total_equity / y_ATH * 100 - 100) / 100
    if(y_drawdown < cur_year_dd)
        cur_year_dd := y_drawdown
    if (new_year or barstate.isfirst)
        cur_year_dd := 0.0
        y_ATH := strategy.equity - strategy.openprofit
        array.push(yearly_dds, 0)
    else 
        array.set(yearly_dds, array.size(yearly_dds) - 1, cur_year_dd) 
// }

// TABLE LOGIC { 
var main_table = table(na)
table.clear(main_table, 0, 0, 13, new_year ? array.size(year_times) - 1 : array.size(year_times))
main_table := table.new(position.bottom_right, columns = 14, rows = array.size(year_times) + 1, border_width = 1)

t_set_headers() =>                                                                              // Sets time headers of the table
    // Set month headers
    table.cell(main_table, 0,  0, "",     text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 1,  0, "Jan",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 2,  0, "Feb",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 3,  0, "Mar",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 4,  0, "Apr",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 5,  0, "May",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 6,  0, "Jun",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 7,  0, "Jul",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 8,  0, "Aug",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 9,  0, "Sep",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 10, 0, "Oct",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 11, 0, "Nov",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 12, 0, "Dec",  text_color = i_headers_text_col, bgcolor = i_headers_col)
    table.cell(main_table, 13, 0, str.tostring(i_eq_to_dd), text_color = i_headers_text_col, bgcolor = i_headers_col)

    // Set year headers
    for i = 0 to array.size(year_times) - 1
        table.cell(main_table, 0,  i + 1, str.tostring(year(array.get(year_times, i))), text_color = i_headers_text_col, bgcolor = i_headers_col)

t_set_months() =>                                                                               // Sets inner monthly data of the table
    display_array = switch i_eq_to_dd 
        "Simple Equity" => monthly_simp_pnls 
        "Compound Equity" => monthly_comp_pnls
        => monthly_dds
    for i = 0 to array.size(month_times) - 1
        m_row = year(array.get(month_times, i)) - year(array.get(year_times, 0)) + 1
        m_col = month(array.get(month_times, i)) 
        m_color = array.get(display_array, i) == 0 ? color.new(i_zero_col, transp = 30) : array.get(display_array, i) > 0 ? color.new(i_pos_col, transp = 30) : color.new(i_neg_col, transp = 30)
        table.cell(main_table, m_col, m_row, str.tostring(math.round(array.get(display_array, i) * 100, i_precision)), bgcolor = m_color, text_color = i_cell_text_col)
        
t_set_years() =>                                                                                // Sets inner yearly data of the table
    display_array = switch i_eq_to_dd 
        "Simple Equity" => yearly_simp_pnls 
        "Compound Equity" => yearly_comp_pnls
        => yearly_dds
    for i = 0 to array.size(year_times) - 1
        y_color = array.get(display_array, i) == 0 ? color.new(i_zero_col, transp = 30) : array.get(display_array, i) > 0 ? color.new(i_pos_col, transp = 20) : color.new(i_neg_col, transp = 20)
        table.cell(main_table, 13, i + 1, str.tostring(math.round(array.get(display_array, i) * 100, i_precision)), bgcolor = y_color, text_color = i_cell_text_col)

t_set_headers() 
t_set_months()
t_set_years()
// }

// PLACE YOUR STRATEGY CODE HERE {
// This is a sample code of a working strategy to show the table in action
fastLength = input(12)
slowlength = input(26)
MACDLength = input(9)
MACD = ta.ema(close, fastLength) - ta.ema(close, slowlength)
aMACD = ta.ema(MACD, MACDLength)
delta = MACD - aMACD
if (ta.crossover(delta, 0))
	strategy.entry("MacdLE", strategy.long, comment = "MacdLE")
if (ta.crossunder(delta, 0))
	strategy.entry("MacdSE", strategy.short, comment = "MacdSE")
// }
Forums
PINE Language FAQ Summary MyLanguage Web3 About Us
Product
Robot Strategy Node Platforms Tickets
API
Syntax guide User guide Trading api Blockchain Indicator

© 2015 - ∞ INVENTOR PTE LTD (SG)