1. Carré
  2. Moyenne mobile double avec stratégie de rupture d'élan

Moyenne mobile double avec stratégie de rupture d'élan

Auteur:ChaoZhang est là., Date: 2024-02-06 14h39 et 22h
Les étiquettes:

img

Résumé

Cette stratégie utilise la croix d'or de l'EMA de 12 jours et de l'EMA de 26 jours comme signal d'entrée. Pour filtrer les fausses ruptures, le MACD est appliqué pour juger de la tendance du marché et du RSI pour les niveaux de surachat/survente. La rupture de prix au-dessus de la résistance est également utilisée comme confirmation.

La stratégie prévoit trois méthodes optionnelles de stop loss: trailing stop loss, moving average stop et moving average crossover stop.

La logique de la stratégie

  1. Signal d'entrée
    • Croix d'or entre les EMA à 12 et 26 jours
    • Le MACD est positif et la ligne MACD est au-dessus de la ligne de signal
    • RSI dans la plage prédéfinie
  2. Confirmation d'entrée
    • Optionnel: rupture des prix au-dessus de la résistance dynamique
  3. Arrêtez la perte
    • L'exposition au risque de défaillance est calculée sur la base du prix d'entrée et du pourcentage prédéfini.
    • Fermeture inférieure à la SMA à 7 jours
    • Croisement baissier entre la EMA à 12 et à 26 jours
  4. Faites du profit
    • Deux étapes de prise d'objectifs de profit, sortie partielle position sur la première cible et tous sur la deuxième

Les avantages

  1. Le système MA filtre les faux signaux, améliore la précision d'entrée
  2. Options de stop loss multiples pour différents types de négociants
  3. Risques liés aux contrôles dynamiques de l'arrêt de traction
  4. Prenez des bénéfices par étapes verrouillez dans certains bénéfices

Les risques

  1. Plus de faux signaux lorsque le marché oscille
  2. L'arrêt de trail peut être pénétré après une forte course
  3. Ne pas sortir à temps lors d'un renversement de tendance

Les solutions:

  1. Utilisez le MACD pour juger de la tendance réelle
  2. Ajustement du pourcentage de retrait
  3. Utiliser d'autres méthodes d'arrêt ou combiner des arrêts

Amélioration

  1. Optimiser les paramètres MA pour obtenir les meilleures performances
  2. Testez différents arrêts et trouvez la meilleure méthode
  3. Ajustez les niveaux de profit pour une meilleure récompense
  4. Ajouter des filtres avec d' autres indicateurs
  5. Personnaliser pour différents produits et délais

Conclusion

La stratégie utilise le système MA pour le signal d'entrée, avec des filtres supplémentaires par MACD, RSI, etc. Les deux arrêts et les objectifs de profit sont optimisés pour correspondre à différents styles de commerçant.

/*backtest
start: 2023-01-30 00:00:00
end: 2024-02-05 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © AbdulRahimShama
//@version=5


strategy('12/26-IT strategy', overlay=true,initial_capital = 100000)



Show_Only_12_26_Crossover_Entry = input.bool(true, group = "Entry_Exit Criteria")
Show_12_26_Crossover_and_resistance_Entry = input.bool(false, group = "Entry_Exit Criteria")


Show_TSL_StopLoss = input.bool(true, group = "Entry_Exit Criteria")
Show_Crossdown_StopLoss = input.bool(true, group = "Entry_Exit Criteria")
Show_SMA7_StopLoss = input.bool(false, group = "Entry_Exit Criteria")



////////////////////////////////////////////////
////////////////TARGETS INPUT
////////////////////////////////////////////////

////////Target1

TargetPerc1 = input.float(title="Target (%)", minval=0,defval=5, group="Target-1") / 100
TargetPrice1 = strategy.position_avg_price * (1 + TargetPerc1)
Target1_exit_qty = input.int(50, group="Target-1",tooltip = "% qty to sell when Target1 is reached")



////////Target2

TargetPerc2 = input.float(title="Target (%)", minval=0,defval=10, group="Target-2") / 100
TargetPrice2 = strategy.position_avg_price * (1 + TargetPerc2)
Target2_exit_qty = input.int(100, group="Target-2",tooltip = "% qty to sell when Target2 is reached")



////////////////////////////////////////////////
////////////////TRAILING STOP LOSS
////////////////////////////////////////////////


TSLsource = input(low, title="TSL Source", group="Trailing StopLoss")

longTrailPerc = input.float(title='Trail Long Loss (%)', minval=0.0, step=0.1, defval=1, group="Trailing StopLoss") * 0.01

TrailStopPrice = 0.0

TrailStopPrice := if strategy.position_size > 0
    sPIVOT_highValue = TSLsource * (1 - longTrailPerc)
    math.max(sPIVOT_highValue, TrailStopPrice[1])
else
    0

TSL = close < TrailStopPrice
plot(series=strategy.position_size > 0 and Show_TSL_StopLoss ? TrailStopPrice : na, color=color.new(color.fuchsia, 0), style=plot.style_linebr, linewidth=2, title='Trailing StopLoss')




////////////////////////////////////////////////
////////////////Moving Averages
////////////////////////////////////////////////



EMA_12=ta.ema(close, 12)
EMA_26=ta.ema(close, 26)
EMA_21=ta.ema(close,21)

plot(EMA_12, title="EMA_12", color=color.rgb(0, 255, 0), offset=0, linewidth=1)
plot(EMA_26, title="EMA_26", color=color.rgb(0, 0, 255), offset=0, linewidth=1)
plot(Show_SMA7_StopLoss ? ta.sma(close,7) : na, title="SMA_7", color=color.rgb(255, 0, 0), offset=0, linewidth=1)



////////////////////////////////////////////////
////////////////RESISTANCE INPUT and PLOTTING
////////////////////////////////////////////////

CrossOverLookbackCandles = input.int(10, group= "RESISTANCE")

resistanceSRC = input(high, group= "RESISTANCE")
resistanceLEFT = input(10, group= "RESISTANCE")
resistanceRIGHT = input(10, group= "RESISTANCE")

hih = ta.pivothigh(resistanceSRC, resistanceLEFT, resistanceRIGHT)
top = ta.valuewhen(hih, resistanceSRC[resistanceRIGHT], 0)

res = plot(top, color=top != top[1] ? na : color.new(#00ff00, 50), offset=-resistanceLEFT, linewidth=2, title="Resistance Line")

EMA_12_Low = ta.lowest(EMA_12, CrossOverLookbackCandles)
EMA_26_Low = ta.lowest(EMA_26, CrossOverLookbackCandles)


////////////////////////////////////////////////
////////////////RSI INPUT and PLOTTING
////////////////////////////////////////////////
RSI = ta.rsi(close, 14)
RSILowerRange = input.int(50, tooltip = "RSI value should be ABOVE this value for entry", group = "RSI")
RSIUpperRange = input.int(70, tooltip = "RSI value should be BELOW this value for entry", group = "RSI")



////////////////////////////////////////////////
////////////////MACD
////////////////////////////////////////////////
fast_length = 12
slow_length = 26
MACD_src = close
signal_length = 9

fast_ma = ta.ema(MACD_src, fast_length)
slow_ma = ta.ema(MACD_src, slow_length)
macd = fast_ma - slow_ma
signal = ta.ema(macd, signal_length)
hist = macd - signal



////////////////////////////////////////////////
////////////////ENTRY CRITERIA
////////////////////////////////////////////////


BUYVALUE= input(100000, tooltip = "Buy qty displayed on chart will be based on this value")

BASEENTRY = macd > signal and RSI > RSILowerRange and RSI < RSIUpperRange and close > EMA_21 and close > ta.sma(close, 7)


Entry= ta.crossover(EMA_12, EMA_26) and BASEENTRY
Entry2 = ta.crossover(close, top) and EMA_12_Low < EMA_26_Low and EMA_12 > EMA_26 and RSI < 70

////////////////////////////////////////////////
////////////////BUY SELL STRATEGY
////////////////////////////////////////////////

if ((Entry and Show_Only_12_26_Crossover_Entry))
    strategy.entry("buy", strategy.long, qty=BUYVALUE/close)

if (Entry2 and Show_12_26_Crossover_and_resistance_Entry)
    strategy.entry("buy", strategy.long, qty=BUYVALUE/close)

strategy.exit("Tg1", "buy", limit=TargetPrice1, qty_percent = Target1_exit_qty)
strategy.exit("Tg2", "buy", limit=TargetPrice2, qty_percent = Target2_exit_qty)



if TSL and Show_TSL_StopLoss and close < EMA_12 
    strategy.close_all ("sl")

if ta.crossunder(EMA_12, EMA_26) and Show_Crossdown_StopLoss
    strategy.close_all ("sl")

if ta.crossunder(close, ta.sma(close, 7)) and Show_SMA7_StopLoss
    strategy.close_all ("sl")
Plus de

2019 FMZ - Tous les droits réservés