1. Carré
  2. Stratégie de rupture de la DCCI

Stratégie de rupture de la DCCI

Auteur:ChaoZhang est là., Date: le 18 février 2024
Les étiquettes:

img

Résumé

La stratégie de rupture du DCCI est une stratégie de trading à court terme qui identifie les situations de survente et de surachat à l'aide de l'indicateur CCI. Elle combine l'indicateur CCI et la ligne moyenne mobile WMA.

La logique de la stratégie

La stratégie utilise l'indicateur CCI pour juger des conditions de surachat/survente du marché. L'indicateur CCI peut identifier efficacement des situations de prix anormales. Les valeurs inférieures à -100 indiquent que le marché est survendu tandis que les valeurs supérieures à 100 indiquent que le marché est suracheté. La stratégie sera longue lorsque l'indicateur CCI franchit le seuil supérieur à -100 venant de bas; et sera courte lorsque l'indicateur CCI franchit le seuil inférieur à 100 venant de haut.

Dans le même temps, la stratégie intègre également la ligne moyenne mobile WMA pour déterminer la direction de la tendance. Seuls les signaux longs seront valides lorsque le prix de clôture est supérieur à la ligne WMA; seuls les signaux courts seront valides lorsque le prix de clôture est inférieur à la ligne WMA. Cela aide à filtrer certains signaux commerciaux ambiguës.

Après avoir entré dans une position, la stratégie utilise un stop loss pour contrôler les risques. Il existe trois méthodes de stop loss optionnelles: stop de stratégie fixe, stop swing high/low, stop ATR. Lorsqu'il est long, la position sera arrêtée si le prix tombe au niveau de l'arrêt; lorsqu'il est court, la position sera arrêtée si le prix monte au niveau de l'arrêt.

Analyse des avantages

La stratégie présente les avantages suivants:

  1. Capture en temps opportun les opportunités de survente et de surachat en identifiant les reverses à l'aide de l'indicateur CCI.

  2. Évite de négocier contre la tendance en incorporant une analyse de la direction de la tendance à l'aide de moyennes mobiles.

  3. Il fournit plusieurs méthodes de stop loss facultatives qui peuvent être ajustées en fonction des conditions du marché.

  4. Des signaux commerciaux simples et clairs, faciles à mettre en œuvre.

Analyse des risques

La stratégie comporte également les risques suivants:

  1. L'indicateur CCI peut facilement générer de faux signaux qui ne peuvent être complètement évités.

  2. Le placement incorrect d'un stop-loss peut entraîner un sur-stop.

  3. L'incapacité d'identifier les tendances signifie que trop de transactions inutiles peuvent être générées sur différents marchés.

  4. L'incapacité de juger de l'orientation globale du marché peut entraîner une négociation dans la mauvaise direction.

Pour faire face à ces risques, les principales approches d'optimisation sont les suivantes:

  1. Incorporer d'autres indicateurs pour filtrer les signaux CCI.

  2. Optimiser le placement de l'arrêt par le backtesting.

  3. Ajoutez des indicateurs d'identification des tendances pour éviter les marchés instables.

  4. Déterminer la direction du commerce sur la base de l'analyse des principales zones de soutien et de résistance.

Directions d'optimisation

Les principaux aspects pour optimiser cette stratégie sont les suivants:

  1. Optimisation du paramètre CCI: ajuster la période de révision du CCI, optimiser les paramètres des indicateurs.

  2. Optimisation de la perte d'arrêt: Testez différentes méthodes d'arrêt et sélectionnez la perte d'arrêt optimale.

  3. Optimisation des filtres: ajouter des filtres supplémentaires comme MACD, RSI pour créer un système de filtrage multi-indicateur pour réduire les faux signaux.

  4. Filtrage des tendances: ajouter des indicateurs d'identification des tendances tels que des moyennes mobiles pour éviter les opérations de contre-tendance.

  5. Prise automatique de bénéfices: construire des mécanismes dynamiques de prise de bénéfices pour prendre automatiquement des bénéfices en fonction de la volatilité du marché.

Conclusion

Dans l'ensemble, la stratégie DCCI Breakout est un système de trading à court terme très pratique. Elle identifie les situations de surachat/survente à l'aide de l'indicateur CCI et intègre la moyenne mobile pour le biais directionnel. Le risque est géré par des stop-loss. Les signaux simples et clairs facilitent la mise en œuvre de cette stratégie pour le trading à court terme.

/*backtest
start: 2023-02-11 00:00:00
end: 2023-09-20 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © tweakerID

// ---From the "Bitcoin Trading Strategies" book, by David Hanson---

// After testing, works better with an ATR stop instead of the Strategy Stop. This paramater
// can be changed from the strategy Inputs panel.

// "CCI Scalping Strategy
// Recommended Timeframe: 5 minutes
// Indicators: 20 Period CCI, 20 WMA
// Long when: Price closes above 20 WMA and CCI is below -100, enter when CCI crosses above -100.
// Stop: Above 20 WMA"

//@version=4
strategy("CCI Scalping Strat", 
     overlay=true, 
     default_qty_type=strategy.percent_of_equity, 
     default_qty_value=100, 
     initial_capital=10000, 
     commission_value=0.04, 
     calc_on_every_tick=false, 
     slippage=0)

direction = input(0, title = "Strategy Direction", type=input.integer, minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))

/////////////////////// STRATEGY INPUTS ////////////////////////////////////////
title1=input(true, "-----------------Strategy Inputs-------------------")  

i_Stop = input(0, step=.05, title="Strategy Stop Mult")*.01
i_CCI=input(16, title="CCI Length")
i_WMA=input(5, title="WMA Length")

/////////////////////// BACKTESTER /////////////////////////////////////////////
title2=input(true, "-----------------General Inputs-------------------")  

// Backtester General Inputs
i_SL=input(true, title="Use Stop Loss and Take Profit")
i_SLType=input(defval="ATR Stop", title="Type Of Stop", options=["Strategy Stop", "Swing Lo/Hi", "ATR Stop"])
i_SPL=input(defval=10, title="Swing Point Lookback")
i_PercIncrement=input(defval=2, step=.1, title="Swing Point SL Perc Increment")*0.01
i_ATR = input(14, title="ATR Length")
i_ATRMult = input(10, step=.1, title="ATR Multiple")
i_TPRRR = input(1.5, step=.1, title="Take Profit Risk Reward Ratio")

// Bought and Sold Boolean Signal
bought = strategy.position_size > strategy.position_size[1] 
 or strategy.position_size < strategy.position_size[1]

// Price Action Stop and Take Profit
LL=(lowest(i_SPL))*(1-i_PercIncrement)
HH=(highest(i_SPL))*(1+i_PercIncrement)
LL_price = valuewhen(bought, LL, 0)
HH_price = valuewhen(bought, HH, 0)
entry_LL_price = strategy.position_size > 0 ? LL_price : na 
entry_HH_price = strategy.position_size < 0 ? HH_price : na 
tp=strategy.position_avg_price + (strategy.position_avg_price - entry_LL_price)*i_TPRRR
stp=strategy.position_avg_price - (entry_HH_price - strategy.position_avg_price)*i_TPRRR

// ATR Stop
ATR=atr(i_ATR)*i_ATRMult
ATRLong = ohlc4 - ATR
ATRShort = ohlc4 + ATR
ATRLongStop = valuewhen(bought, ATRLong, 0)
ATRShortStop = valuewhen(bought, ATRShort, 0)
LongSL_ATR_price = strategy.position_size > 0 ? ATRLongStop : na 
ShortSL_ATR_price = strategy.position_size < 0 ? ATRShortStop : na 
ATRtp=strategy.position_avg_price + (strategy.position_avg_price - LongSL_ATR_price)*i_TPRRR
ATRstp=strategy.position_avg_price - (ShortSL_ATR_price - strategy.position_avg_price)*i_TPRRR

/////////////////////// STRATEGY LOGIC /////////////////////////////////////////

//CCI
CCI=cci(close, i_CCI)
//WMA
WMA=wma(close, i_WMA)

//Stops
LongStop=valuewhen(bought, WMA, 0)*(1-i_Stop)
ShortStop=valuewhen(bought, WMA, 0)*(1+i_Stop)
StratTP=strategy.position_avg_price + (strategy.position_avg_price - LongStop)*i_TPRRR
StratSTP=strategy.position_avg_price - (ShortStop - strategy.position_avg_price)*i_TPRRR

BUY = (close > WMA) and crossover(CCI , -100)
SELL = (close < WMA) and crossunder(CCI , 100)

//Trading Inputs
DPR=input(true, "Allow Direct Position Reverse")
reverse=input(false, "Reverse Trades")

// Entries
if reverse
    if not DPR
        strategy.entry("long", strategy.long, when=SELL and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=BUY and strategy.position_size == 0)
    else     
        strategy.entry("long", strategy.long, when=SELL)
        strategy.entry("short", strategy.short, when=BUY)
else
    if not DPR 
        strategy.entry("long", strategy.long, when=BUY and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=SELL and strategy.position_size == 0)
    else
        strategy.entry("long", strategy.long, when=BUY)
        strategy.entry("short", strategy.short, when=SELL)


SL= i_SLType == "Swing Lo/Hi" ? entry_LL_price : i_SLType == "ATR Stop" ? LongSL_ATR_price : LongStop
SSL= i_SLType == "Swing Lo/Hi" ? entry_HH_price : i_SLType == "ATR Stop" ? ShortSL_ATR_price : ShortStop
TP= i_SLType == "Swing Lo/Hi" ? tp : i_SLType == "ATR Stop" ? ATRtp : StratTP
STP= i_SLType == "Swing Lo/Hi" ? stp : i_SLType == "ATR Stop" ? ATRstp : StratSTP

strategy.exit("TP & SL", "long", limit=TP, stop=SL, when=i_SL)
strategy.exit("TP & SL", "short", limit=STP, stop=SSL, when=i_SL)

/////////////////////// PLOTS //////////////////////////////////////////////////


plot(WMA)
plot(i_SL and strategy.position_size > 0 ? SL : na , title='SL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size < 0 ? SSL : na , title='SSL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size > 0 ? TP : na, title='TP', style=plot.style_cross, color=color.green)
plot(i_SL and strategy.position_size < 0 ? STP : na, title='STP', style=plot.style_cross, color=color.green)
// Draw price action setup arrows
plotshape(BUY ? 1 : na, style=shape.triangleup, location=location.belowbar, 
 color=color.green, title="Bullish Setup", size=size.auto)
plotshape(SELL ? 1 : na, style=shape.triangledown, location=location.abovebar, 
 color=color.red, title="Bearish Setup", size=size.auto)
Plus de

2019 FMZ - Tous les droits réservés