Strategi Perdagangan Kombinasi Ichimoku Cloud dan Bollinger Bands
ChaoZhang
Ringkasan
Strategi ini menggabungkan indikator Jepang dengan indikator Bollinger Bands untuk menghasilkan sinyal perdagangan. Strategi ini dapat secara efektif menilai tren pasar, dan melakukan penilaian ketika indikator Bollinger Bands mengeluarkan sinyal kosong, untuk menghindari perdagangan yang salah.
Prinsip Strategi
Sebuah grafik awan terdiri dari garis konversi, garis acuan, garis penundaan, dan garis terdepan. Garis konversi adalah garis rata-rata 9 hari, dan garis acuan adalah garis rata-rata 26 hari. Ketika garis konversi berada di atas garis acuan, sinyalnya adalah sinyal multihead, sebaliknya adalah sinyal kosong.
Garis penundaan adalah pergerakan penundaan harga. Ketika garis penundaan di atas menunjukkan tren multihead, di bawah adalah tren kosong.
Garis awan terdiri dari dua garis terdepan, yaitu garis rata-rata 52 hari dan garis rata-rata 26 hari.
Beringin terdiri dari n rata-rata harian dan standar deviasi, adalah band volatilitas harga saham. Lihat lebih banyak ketika harga menembus band atas, dan lihat lebih sedikit ketika harga menembus band bawah.
Strategi ini menghasilkan aturan perdagangan ketika sebuah grafik awan mengeluarkan sinyal kosong, dan pada saat yang sama menilai bahwa Brin Belt telah pecah. Misalnya, garis konversi ke atas telah menerobos garis acuan, garis lag di atas, harga telah menerobos awan dan telah menerobos Brin Belt.
Keunggulan Strategis
Sebuah grafik awan menilai tren dengan jelas, garis konversi dan garis penundaan dapat menilai tren jangka pendek, dan garis awan menilai arah tren jangka panjang.
Brin mendeteksi jika harga telah melampaui batas, sehingga dapat menyaring sebagian transaksi yang tidak perlu.
Kombinasi indikator, membuat sinyal perdagangan lebih jelas dan lebih dapat diandalkan, menghindari risiko perdagangan.
Risiko dan optimasi
Tidak tepatnya pengaturan parameter Brinband dapat menyebabkan sinyal perdagangan tidak akurat. Parameter harus diatur dengan hati-hati sesuai dengan standar yang berbeda.
Persentase kepemilikan harus disesuaikan dengan tepat untuk mengendalikan risiko. Pemilikan yang berlebihan dapat menyebabkan peningkatan kerugian.
Anda dapat mempertimbangkan untuk memasukkan strategi stop loss, yang menghentikan kerugian jika harga bergerak ke arah yang tidak menguntungkan di atas tingkat tertentu.
Lebih banyak indikator dapat diuji dan dikombinasikan dengan grafik awan untuk menghasilkan strategi perdagangan yang lebih andal.
Meringkaskan
Strategi ini secara efektif menggunakan grafik awan untuk menentukan arah tren dan sinyal penyaringan indikator Brin. Sinyal strategi lebih jelas dan dapat diandalkan, dengan penyesuaian parameter dan pengoptimalan stop loss, dapat mengurangi risiko perdagangan dan mendapatkan keuntungan yang lebih baik.
/*backtest
start: 2023-12-19 00:00:00
end: 2023-12-26 00:00:00
period: 10m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Coinrule
//@version=5
strategy("Ichimoku Cloud and Bollinger Bands",
overlay=true,
initial_capital=1000,
process_orders_on_close=true,
default_qty_type=strategy.percent_of_equity,
default_qty_value=30,
commission_type=strategy.commission.percent,
commission_value=0.1)
showDate = input(defval=true, title='Show Date Range')
timePeriod = true
notInTrade = strategy.position_size <= 0
//Ichimoku Cloud
//Inputs
ts_bars = input.int(9, minval=1, title="Tenkan-Sen Bars")
ks_bars = input.int(26, minval=1, title="Kijun-Sen Bars")
ssb_bars = input.int(52, minval=1, title="Senkou-Span B Bars")
cs_offset = input.int(26, minval=1, title="Chikou-Span Offset")
ss_offset = input.int(26, minval=1, title="Senkou-Span Offset")
long_entry = input(true, title="Long Entry")
short_entry = input(true, title="Short Entry")
middle(len) => math.avg(ta.lowest(len), ta.highest(len))
// Components of Ichimoku Cloud
tenkan = middle(ts_bars)
kijun = middle(ks_bars)
senkouA = math.avg(tenkan, kijun)
senkouB = middle(ssb_bars)
// Plot Ichimoku Cloud
plot(tenkan, color=#0496ff, title="Tenkan-Sen")
plot(kijun, color=#991515, title="Kijun-Sen")
plot(close, offset=-cs_offset+1, color=#459915, title="Chikou-Span")
sa=plot(senkouA, offset=ss_offset-1, color=color.green, title="Senkou-Span A")
sb=plot(senkouB, offset=ss_offset-1, color=color.red, title="Senkou-Span B")
fill(sa, sb, color = senkouA > senkouB ? color.green : color.red, title="Cloud color")
ss_high = math.max(senkouA[ss_offset-1], senkouB[ss_offset-1])
ss_low = math.min(senkouA[ss_offset-1], senkouB[ss_offset-1])
// Entry/Exit Conditions
tk_cross_bull = tenkan > kijun
tk_cross_bear = tenkan < kijun
cs_cross_bull = ta.mom(close, cs_offset-1) > 0
cs_cross_bear = ta.mom(close, cs_offset-1) < 0
price_above_kumo = close > ss_high
price_below_kumo = close < ss_low
//Bollinger Bands Indicator
length = input.int(20, minval=1)
src = input(close, title="Source")
mult = input.float(2.0, minval=0.001, maxval=50, title="StdDev")
basis = ta.sma(src, length)
dev = mult * ta.stdev(src, length)
upper = basis + dev
lower = basis - dev
offset = input.int(0, "Offset", minval = -500, maxval = 500)
plot(basis, "Basis", color=#FF6D00, offset = offset)
p1 = plot(upper, "Upper", color=#2962FF, offset = offset)
p2 = plot(lower, "Lower", color=#2962FF, offset = offset)
fill(p1, p2, title = "Background", color=color.rgb(33, 150, 243, 95))
bullish = tk_cross_bull and cs_cross_bull and price_above_kumo and ta.crossover(lower, close)
bearish = tk_cross_bear and cs_cross_bear and price_below_kumo and ta.crossover(close, lower)
strategy.entry('Long', strategy.long, when=bullish and long_entry and timePeriod)
strategy.close('Long', when=bearish and not short_entry)
strategy.entry('Short', strategy.short, when=bearish and short_entry and timePeriod)
strategy.close('Short', when=bullish and not long_entry)
//Works well on BTC 30m/1h (11.29%), ETH 2h (29.05%), MATIC 2h/30m (37.12%), AVAX 1h/2h (49.2%), SOL 45m (45.43%)