MA指標は英語の短縮名 ((移動平均線) と呼ばれ,移動平均線 (moving average) と呼ばれます.移動平均線 (moving average,MA) は,上昇と低下する日K線とは異なり,比較的安定したトレンド特性を持っています.移動平均線が長くなるほど,パフォーマンスがより安定します.上下が簡単ではありません.あなたは株式価格トレンドの真の明確さを待たなければなりません.移動平均線は,最終分析では,トレンドが終了したか逆転したか,新しいトレンドが出現しているか,容易に識別するトレンド追跡ツールです.
この問題では,MACD+MA指数組み合わせ戦略を共有します.技術分析では,指標の組み合わせは非常に一般的です.異なる指標には異なる操作ポイントと分析方法があります.指標の組み合わせは信号の精度を向上させることができます.戦略は価格とMAの関係を比較し,その後,市場の状態を判断し,簡単なタイミングの取引戦略を構築するためにMACD指数によって価格動きの加速を測定することです.
(*backtest
start: 2018-11-01 00:00:00
end: 2018-11-22 00:00:00
period: 1h
exchanges: [{"eid":"Bitfinex","currency":"BTC_USD"}]
*)
// MACD calculation
FASTLENGTH:=12;
SLOWLENGTH:=26;
MACDLENGTH:=9;
// Length of MA
L1:=50;
L2:=120;
// stop loss 止损 5%
STOPLOSS:=5;
//MACD
MACDVALUE:=EMA(CLOSE,FASTLENGTH)-EMA(CLOSE,SLOWLENGTH);
AVGMACD:=EMA(MACDVALUE,MACDLENGTH);
MACDDIFF:=MACDVALUE-AVGMACD;
//MA1、MA2
DMA1:=MA(C,L1);
DMA2:=MA(C,L2);
BUYCONDITION:=MACDVALUE>0 && DMA1>DMA2 && MACDDIFF>0 && C>DMA1 && REF(C,1)>REF(DMA1,1);
SELLCONDITION:=MACDVALUE<0 && DMA1<DMA2 && MACDDIFF<0 && C<DMA1 && REF(C,1)<REF(DMA1,1);
// 开仓条件 When to open position
BKVOL=0 AND BUYCONDITION,BK;
SETSIGPRICETYPE(BK,NEW_ORDER);
SKVOL=0 AND SELLCONDITION,SK;
SETSIGPRICETYPE(SK,NEW_ORDER);
// 离场条件 When to close position
BKVOL>0 AND (REF(MACDVALUE,1)<0 OR REF(DMA1,1)<REF(DMA2,1)),SP;
SKVOL>0 AND (REF(MACDVALUE,1)>0 OR REF(DMA1,1)>REF(DMA2,1)),BP;
// 启动止损 Start stop loss
SKVOL>0 AND HIGH>=SKPRICE*(1+STOPLOSS*0.01),BP;
BKVOL>0 AND LOW<=BKPRICE*(1-STOPLOSS*0.01),SP;
AUTOFILTER;