戦略をフォローする2つのタイムフレームDIの傾向

作者: リン・ハーンチャオチャン, 日付: 2023年11月7日 16:31:07
タグ:

概要

この戦略は,長期および短期間のトレンドのトレンド方向を決定するために,2つのタイムフレームで平均方向指数 (DI+) と負の方向指数 (DI-) を使用する.DI+がより大きなおよびより小さなタイムフレームの両方でDI-よりも高ければ,上昇傾向を示し,長い信号が起動する.DI-が両方のフレームでDI+よりも高ければ,ダウン傾向を示し,ショート信号が起動する.

働き方

この戦略はいくつかの原則に基づいています.

DI+とDIを計算します. 高値,近値,低値を使ってDI+とDIを計算します.
DI+とDI-を2つのタイムフレームで比較する.DI+とDI-をそれぞれメインチャートタイムフレーム (例えば1時間) とより大きなタイムフレーム (例えば毎日) で計算する.両方のタイムフレーム間の値を比較する.
トレンド方向を決定する.DI+がDI-よりも大きい場合,大きくなった場合も,小さくなった場合も,上昇傾向を示します.DI-がDI+よりも大きい場合も,下落傾向を示します.
DI+>DI-は2つのフレームで長い信号を表示します.
ストップロスを設定します.動的ストップロスを計算するためにATRを使用します.
ストップ・ロスはヒットするか,価格が逆転するときに終了します.

利点

この戦略には以下の利点があります.

二重タイムフレームで DIをフィルタリングして
ATRの遅延ストップは利益保護を最大化しストップが狭すぎないようにします
タイムリーストップ・ロスは,単一の取引での損失を制御します.
トレンドで取引することでトレンドを継続的に把握できます
シンプルで明瞭なルールでリアルタイムの取引で簡単に実行できます

リスクと解決策

リスクもいくつかあります

DIには遅延効果があり,入力タイムを逃す可能性があります.パラメータを最適化したり,他の指標を追加することができます.
2つのタイムフレームは,より大きなTFとより小さなTFの間に差がある可能性があります.より多くのタイムフレームの検証を追加します.
ストップ・ロスは過剰な取引を引き起こす可能性があります
横向きの市場では,頻繁に取引を引き起こす可能性があります. 取引頻度を減らすためにフィルターを追加します.
パラメータ最適化は,歴史的なデータに依存し,過度に配置されることがあります. パラメータの強度を慎重に評価します.

オプティマイゼーションの方向性

戦略は以下の点で改善できる:

最適なパラメータセットのためにDI計算パラメータを最適化します.
信号の精度を向上させるために他の指標フィルターを追加します.例えばMACD,KDJなど.
ストップ・ロスの戦略を強化し,トライリング・ストップや待機中のオーダーなど,より多くの市場条件に適応する.
重要なニュースイベントを避けるために取引セッションフィルターを追加します.
適応性を向上させるため,異なる製品でパラメータの強度を試験する.
機械学習を導入しモデルを歴史データで訓練する

結論

概要すると,これは,傾向方向を決定し,傾向に沿って利益をロックするためにストップロスを設定するためにDIを使用する典型的なトレンドフォロー戦略です.利点は,明確な論理とライブトレーディングの容易な実装にあります.パラメータ最適化,フィルター追加などを通じて改善の余地もあります.さらなる最適化と強度テストにより,非常に実践的なトレンドフォロー戦略になることができます.

/*backtest
start: 2022-10-31 00:00:00
end: 2023-11-06 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © DojiEmoji

//@version=5
strategy("DI+/- multi TF Strat [KL]", overlay=true, pyramiding=1, initial_capital=1000000000, default_qty_type=strategy.percent_of_equity, default_qty_value=5)
var string GROUP_ALERT    = "Alerts"
var string GROUP_SL       = "Stop loss"
var string GROUP_ORDER    = "Order size"
var string GROUP_TP       = "Profit taking"
var string GROUP_HORIZON  = "Time horizon of backtests"
var string GROUP_IND      = "Directional IndicatorDI+ DI-"

// ADX Indicator {
adx_len = input(14, group=GROUP_IND, tooltip="Typically 14")
tf1 = input.timeframe("", title="DI +/- in Timeframe 1", group=GROUP_IND, tooltip="Main: DI+ > DI-")
tf2 = input.timeframe("1D", title="DI +/- in Timeframe 2", group=GROUP_IND, tooltip="Confirmation: DI+ > DI-")
// adx_thres = input(20, group=GROUP_IND)   //threshold not used in this strategy

get_ADX(_high, _close, _low) =>
// (high, close, mid) -> [plus_DM, minus_DM]
    // Based on TradingView user BeikabuOyaji's implementation
    _tr = math.max(math.max(_high - _low, math.abs(_high - nz(_close[1]))), math.abs(_low - nz(_close[1])))
    smooth_tr = 0.0
    smooth_tr := nz(smooth_tr[1]) - nz(smooth_tr[1]) / adx_len + _tr

    smooth_directional_mov_plus = 0.0
    smooth_directional_mov_plus := nz(smooth_directional_mov_plus[1]) - nz(smooth_directional_mov_plus[1]) / adx_len + (_high - nz(_high[1]) > nz(_low[1]) - _low ? math.max(_high - nz(_high[1]), 0) : 0)

    smooth_directional_mov_minus = 0.0
    smooth_directional_mov_minus := nz(smooth_directional_mov_minus[1]) - nz(smooth_directional_mov_minus[1]) / adx_len + (nz(_low[1]) - _low > _high - nz(_high[1]) ? math.max(nz(_low[1]) - _low, 0) : 0)

    plus_DM = smooth_directional_mov_plus / smooth_tr * 100
    minus_DM = smooth_directional_mov_minus / smooth_tr * 100
    // DX = math.abs(plus_DM - minus_DM) / (plus_DM + minus_DM) * 100   // DX not used in this strategy
    [plus_DM, minus_DM]

// DI +/- from timeframes 1 and 2
[plus_DM_tf1, minus_DM_tf1] = get_ADX(request.security(syminfo.tickerid, tf1, high), request.security(syminfo.tickerid, tf1, close),request.security(syminfo.tickerid, tf1, low))
[plus_DM_tf2, minus_DM_tf2] = get_ADX(request.security(syminfo.tickerid, tf2, high),request.security(syminfo.tickerid, tf2, close),request.security(syminfo.tickerid, tf2, low))
// } end of block: ADX Indicator


var string ENUM_LONG      = "LONG"
var string LONG_MSG_ENTER = input.string("Long entered", title="Alert MSG for buying (Long position)", group=GROUP_ALERT)
var string LONG_MSG_EXIT  = input.string("Long closed", title="Alert MSG for closing (Long position)", group=GROUP_ALERT)
backtest_timeframe_start = input(defval=timestamp("01 Apr 2020 13:30 +0000"), title="Backtest Start Time", group=GROUP_HORIZON)
within_timeframe         = true

// Signals for entry
_uptrend_confirmed = plus_DM_tf1 > minus_DM_tf1 and plus_DM_tf2 > minus_DM_tf2
entry_signal_long = _uptrend_confirmed

plotshape(_uptrend_confirmed, style=shape.triangleup, location=location.bottom, color=color.green)
plotshape(not _uptrend_confirmed, style=shape.triangledown, location=location.bottom, color=color.red)

// Trailing stop loss ("TSL") {
tsl_multi                 = input.float(2.0, title="ATR Multiplier for trailing stoploss", group=GROUP_SL)
SL_buffer                 = ta.atr(input.int(14, title="Length of ATR for trailing stoploss", group=GROUP_SL)) * tsl_multi
TSL_source_long           = low
var stop_loss_price_long  = float(0)
var pos_opened_long       = false

stop_loss_price_long := pos_opened_long ? math.max(stop_loss_price_long, TSL_source_long - SL_buffer) : TSL_source_long - SL_buffer

// MAIN: {
if pos_opened_long and TSL_source_long <= stop_loss_price_long
    pos_opened_long := false
    alert(LONG_MSG_EXIT, alert.freq_once_per_bar)
    strategy.close(ENUM_LONG, comment=close < strategy.position_avg_price ? "stop loss" : "take profit")

// (2) Update the stoploss to latest trailing amt.
if pos_opened_long
    strategy.exit(ENUM_LONG, stop=stop_loss_price_long, comment="SL")

// (3) INITIAL ENTRY:
if within_timeframe and entry_signal_long
    pos_opened_long := true
    alert(LONG_MSG_ENTER, alert.freq_once_per_bar)
    strategy.entry(ENUM_LONG, strategy.long, comment="long")

// Plotting: 
TSL_transp_long = pos_opened_long and within_timeframe ? 0 : 100
plot(stop_loss_price_long, color=color.new(color.green, TSL_transp_long))

// CLEAN UP: Setting variables back to default values once no longer in use
if ta.change(strategy.position_size) and strategy.position_size == 0
    pos_opened_long := false

if not pos_opened_long
    stop_loss_price_long := float(0)

// } end of MAIN block

もっと

2019 FMZ - すべての権利は保護されています.

戦略をフォローする2つのタイムフレームDIの傾向

概要

働き方

利点

リスク と 解決策

オプティマイゼーションの方向性

結論

リスクと解決策