3移動平均ゴールデンクロス取引戦略

作成日: 2024-01-16 18:18:02 最終変更日: 2024-01-16 18:18:02

コピー: 0 クリック数: 724

ChaoZhang

フォローダイレクトメッセージ

フォロー

1617

フォロワー

3移動平均ゴールデンクロス取引戦略

概要

三均線ゴールドクロス取引戦略は,典型的な技術分析戦略である.この戦略は,3つの異なる時間長さの移動平均を同時に利用してトレンドを捉え,低リスクの取引を実現する.短期移動平均が中期移動平均を横切って,中期移動平均が長期移動平均より高くなったとき,買入シグナルを生成する.短期移動平均が中期移動平均を横切って,中期移動平均が長期移動平均より低くなったとき,売出シグナルを生成する.

戦略原則

三均線金十字戦略は,トレンドの方向を判断するために主に3つの移動平均に依存する.短期移動平均は,価格の変化に敏感に反応する.中期移動平均は,より明確なトレンド判断を提供する.長期移動平均は,市場騒音をフィルターして,長期のトレンドの方向を決定する.

短期移動平均線が中期移動平均線を横切るときは,価格が上方へ突破し始めることを示す.この時点で,中期移動平均線が長期移動平均線より高い場合は,現在上昇中であることを示すので,この時点で買取シグナルが生じる.

逆に,短期移動平均線が中期移動平均線を下を通るときは,価格が下方へ突破し始めることを示す.このとき,中期移動平均線が長期移動平均線より低い場合は,現在下落傾向にあることを示すので,このときセールシグナルが生じます.

この戦略は同時にストップ・ストップ・フローラインを設定する.取引後に,設定されたストップ・ストップの比率に基づいてストップ・ストップとストップ・価格を計算する.価格がストップ・ストップまたはストップ・フローラインに触れた場合は,平仓を退場する.

戦略的優位性

3つの移動平均を使ってトレンドを判断し,判断の精度を高めます.
ストップ・ストップを設定し,単一取引のリスクを効果的に制御します.
異なる品種に適用できるカスタマイズ可能な移動平均のパラメータ
選択可能な7種類の移動平均と豊富な戦略タイプ

戦略的リスクと解決策

三等線が一致すると,誤信号が生じます.

解決策: 移動平均のパラメータを適切に調整して,誤った信号を回避する.

ストップ・ストップの比率を過度に設定する

解決策: ストップダストの比率を適切に調整し,大きすぎたり小さすぎたりしないでください

パラメータの設定が不適切で,取引頻度が高すぎまたは低すぎます.

解決策:異なるパラメータをテストし,最適なパラメータの組み合わせを探します.

戦略最適化の方向性

三均線黄金交差策は以下の点で最適化できる.

異なる種類のパラメータをテストし,異なる長さのパラメータをテストし,最適なパラメータを探します.

異なる長さまたは異なるタイプの移動平均の組み合わせをテストして,最適な取引効果を得ることができます

他の技術指標のフィルター信号を追加する

KDJ,MACDなどの他の指標を戦略に追加し,マルチファクター検証を行い,誤った信号をフィルタリングできます.

種別特性の選択パラメータ

高波動の品種に対して移動平均周期を短縮することができる.低波動の品種に対して移動平均周期を長縮することができる.

機械学習により最適のパラメータの組み合わせを探します.

アルゴリズムでパラメータ空間を自動で回り,最適なパラメータを素早く特定する

要約する

三均線ゴールドクロス戦略は,全体として,よりシンプルで実用的なトレンド追跡戦略である. それは,同時に,移動平均の3つのトレンド方向を捕捉し,ストップ・ストップ・コントロールのリスクを設定し,安定した収益を得ることができる.パラメータを最適化し,他の技術指標を追加することで,戦略の効果をさらに高めることができる.全体として,この戦略は,安定した利益を追求する投資家に適しています.

ストラテジーソースコード

/*backtest
start: 2024-01-08 00:00:00
end: 2024-01-15 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=3
strategy("Kozlod - 3 MA strategy with SL/PT", shorttitle="kozlod_3ma", overlay = true, default_qty_type = strategy.percent_of_equity, default_qty_value = 5)

// 
// author: Kozlod
// date: 2018-03-25
// 

////////////
// INPUTS //
////////////

ma_type        = input(title = "MA Type",            defval = "SMA", options = ['SMA', 'EMA', 'WMA', 'VWMA', 'HMA', 'SMMA', 'DEMA'])
short_ma_len   = input(title = "Short MA Length",    defval = 5,     minval = 1)
short_ma_src   = input(title = "Short MA Source",    defval = close)
medium_ma_len  = input(title = "Medium MA Length",   defval = 20,    minval = 2)
medium_ma_src  = input(title = "Medium MA Source",   defval = close)
long_ma_len    = input(title = "Long MA Length",     defval = 100,   minval = 3)
long_ma_src    = input(title = "Long MA Source",     defval = close)

sl_lev_perc    = input(title = "SL Level % (0 - Off)", type = float,   defval = 0,  minval = 0, step = 0.01)
pt_lev_perc    = input(title = "PT Level % (0 - Off)", type = float,   defval = 0,  minval = 0, step = 0.01)

// Set initial values to 0
short_ma  = 0.0
long_ma   = 0.0
medium_ma = 0.0

// Simple Moving Average (SMA)
if ma_type == 'SMA' 
    short_ma  := sma(short_ma_src,  short_ma_len)
    medium_ma := sma(medium_ma_src, medium_ma_len)
    long_ma   := sma(long_ma_src,   long_ma_len)

// Exponential Moving Average (EMA)
if ma_type == 'EMA'
    short_ma  := ema(short_ma_src,  short_ma_len)
    medium_ma := ema(medium_ma_src, medium_ma_len)
    long_ma   := ema(long_ma_src,   long_ma_len)

// Weighted Moving Average (WMA)
if ma_type == 'WMA'
    short_ma  := wma(short_ma_src,  short_ma_len)
    medium_ma := wma(medium_ma_src, medium_ma_len)
    long_ma   := wma(long_ma_src,   long_ma_len)

// Hull Moving Average (HMA)
if ma_type == 'HMA'
    short_ma  := wma(2*wma(short_ma_src,  short_ma_len  / 2) - wma(short_ma_src,  short_ma_len),  round(sqrt(short_ma_len)))
    medium_ma := wma(2*wma(medium_ma_src, medium_ma_len / 2) - wma(medium_ma_src, medium_ma_len), round(sqrt(medium_ma_len)))
    long_ma   := wma(2*wma(long_ma_src,   long_ma_len   / 2) - wma(long_ma_src,   long_ma_len),   round(sqrt(long_ma_len)))

// Volume-weighted Moving Average (VWMA)
if ma_type == 'VWMA'
    short_ma  := vwma(short_ma_src,  short_ma_len)
    medium_ma := vwma(medium_ma_src, medium_ma_len)
    long_ma   := vwma(long_ma_src,   long_ma_len)

// Smoothed Moving Average (SMMA)    
if ma_type == 'SMMA'
    short_ma  := na(short_ma[1])  ? sma(short_ma_src, short_ma_len)   : (short_ma[1]  * (short_ma_len  - 1) + short_ma_src)  / short_ma_len
    medium_ma := na(medium_ma[1]) ? sma(medium_ma_src, medium_ma_len) : (medium_ma[1] * (medium_ma_len - 1) + medium_ma_src) / medium_ma_len
    long_ma   := na(long_ma[1])   ? sma(long_ma_src,  long_ma_len)    : (long_ma[1]   * (long_ma_len   - 1) + long_ma_src)   / long_ma_len

// Double Exponential Moving Average (DEMA)
if ma_type == 'DEMA'
    e1_short  = ema(short_ma_src , short_ma_len)
    e1_medium = ema(medium_ma_src, medium_ma_len)
    e1_long   = ema(long_ma_src,   long_ma_len)
    
    short_ma  := 2 * e1_short  - ema(e1_short,  short_ma_len)
    medium_ma := 2 * e1_medium - ema(e1_medium, medium_ma_len)
    long_ma   := 2 * e1_long   - ema(e1_long,   long_ma_len)

/////////////
// SIGNALS //
/////////////

long_signal  = crossover( short_ma, medium_ma) and medium_ma > long_ma
short_signal = crossunder(short_ma, medium_ma) and medium_ma < long_ma

// Calculate PT/SL levels 
// Initial values 
last_signal    = 0
prev_tr_price  = 0.0
pt_level       = 0.0
sl_level       = 0.0

// Calculate previous trade price
prev_tr_price := (long_signal[1] and nz(last_signal[2]) != 1) or (short_signal[1] and nz(last_signal[2]) != -1) ? open : nz(last_signal[1]) != 0 ? prev_tr_price[1] : na

// Calculate SL/PT levels 
pt_level := nz(last_signal[1]) == 1 ? prev_tr_price * (1 + pt_lev_perc / 100) : nz(last_signal[1]) == -1 ? prev_tr_price * (1 - pt_lev_perc / 100)  : na
sl_level := nz(last_signal[1]) == 1 ? prev_tr_price * (1 - sl_lev_perc / 100) : nz(last_signal[1]) == -1 ? prev_tr_price * (1 + sl_lev_perc / 100)  : na

// Calculate if price hit sl/pt 
long_hit_pt = pt_lev_perc > 0 and nz(last_signal[1]) ==  1 and close >= pt_level
long_hit_sl = sl_lev_perc > 0 and nz(last_signal[1]) ==  1 and close <= sl_level

short_hit_pt = pt_lev_perc > 0 and nz(last_signal[1]) ==  -1 and close <= pt_level
short_hit_sl = sl_lev_perc > 0 and nz(last_signal[1]) ==  -1 and close >= sl_level

// What is last active trade? 
last_signal := long_signal ? 1 : short_signal ? -1 : long_hit_pt or long_hit_sl or short_hit_pt or short_hit_sl ? 0 : nz(last_signal[1])

//////////////
// PLOTTING //
//////////////

// Plot MAs
plot(short_ma,  color = red,    linewidth = 2)
plot(medium_ma, color = green,  linewidth = 2)
plot(long_ma,   color = yellow, linewidth = 2)


// Plot Levels 
plotshape(prev_tr_price, style = shape.cross, color = gray, location  = location.absolute, size = size.small)


plotshape(sl_lev_perc > 0 ? sl_level : na, style = shape.cross, color = red,   location  = location.absolute, size = size.small)
plotshape(pt_lev_perc > 0 ? pt_level : na, style = shape.cross, color = green, location  = location.absolute, size = size.small)

//////////////
// STRATEGY //
//////////////

strategy.entry("long",  true,  when = long_signal)
strategy.entry("short", false, when = short_signal)

strategy.close("long",  when = long_hit_pt  or long_hit_sl)
strategy.close("short", when = short_hit_pt or short_hit_sl)

Forums

PINE Language FAQ Summary MyLanguage Web3 About Us

Product

Robot Strategy Node Platforms Tickets

API

Syntax guide User guide Trading api Blockchain Indicator