1. スクエア
  2. 多期RSIと移動平均取引戦略

多期RSIと移動平均取引戦略

作者: リン・ハーンチャオチャン開催日:2024年1月22日11時20分
タグ:

img

概要

この戦略は,RSIインジケーター,単純な移動平均線 (SMA) と重度の移動平均線 (WMA) を組み合わせて,取引信号を識別する. 5分と1時間のタイムフレームで同時にトレンド方向を判断する. 安定したトレンド中に速いRSI線がスローラインを越えたり下を通過したとき,取引信号が生成される.

戦略の論理

この戦略は,まず,1時間および5分間のタイムフレームの両方で144期WMAと5期SMAを計算する. 5分間のSMAがWMAを超える場合にのみ,バリーッシュマーケットが特定される.その後,戦略は,RSIオシレーターと対応するKとDラインを計算する.KラインがオーバーセールエリアからDラインを下に横切るとセール信号が生成される.KラインがオーバーセールエリアからDラインを越えたときセール信号が生成される.

利点分析

これは非常に効果的なトレンドフォロー戦略である.トレンドを決定するために2つのタイムフレームを組み込むことで,誤ったシグナルを大幅に減少させる.さらに,RSI,SMA,WMAを含む複数のフィルターを組み合わせて,シグナルをより信頼性の高いものにする.KDJをRSIとドライブすることによって,通常のKDJ戦略に固有のいくつかの偽信号を回避する.さらに,適切なストップ損失と利益の設定は利益とリスクを制御するのに役立ちます.

リスク分析

この戦略の最大のリスクは,間違ったトレンド判断にあります.ターニングポイントでは,短期および長期移動平均が上下向きに転がり,間違った信号が生じる可能性があります.また,RSIは,市場変動中により騒々しい信号を生む可能性があります.しかし,これらのリスクは,SMA,WMAおよびRSIパラメータの期間を適切に調整することによって軽減できます.

オプティマイゼーションの方向性

戦略は以下の側面から改善できます.

  1. 最適な組み合わせを見つけるために SMA,WMA,RSIの異なる長さをテストする
  2. 信号の信頼性を確認するためにMACD,ボリンジャー帯などの他の指標を組み込む
  3. ストップ・ロストを最適化し,固定比率ストップ,トレーリング・ストップ等をテストすることで 利益を得るメカニズムを最適化します.
  4. 取引のサイズと全体的なリスク露出を制御するための資本管理モジュールを追加
  5. 機械学習モデルを導入し,大規模なバックテストを通じて最高のパフォーマンスのパラメータを見つける

概要

この戦略は,移動平均値と振動器の強みを完全に活用し,比較的堅牢なトレンドフォローシステムを構築する.複数のタイムフレームとインジケーターのシグナルを確認することで,中期から長期間のトレンドをスムーズに捕捉することができます.ストップ損失と収益の設定はまた,一定の程度に通常の市場変動に耐えるようにします.しかし,より多くのインジケーターの組み合わせをテストし,パラメータ最適化のために機械学習を活用するなどの改善余地があります.全体的に見ると,これは非常に有望な取引戦略です.

/*backtest
start: 2023-12-22 00:00:00
end: 2024-01-21 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © bufirolas

// Works well with a wide stop with 20 bars lookback
// for the SL level and a 2:1 reward ratio Take Profit .
// These parameters can be modified in the Inputs section of the strategy panel.

// "an entry signal it's a cross down or up on
// the stochastics. if you're in a downtrend
// on the hourly time frame you
// must also be in a downtrend on the five
// minute so the five period has to be below the 144
// as long as the five period is still trading below
// the 144 period on both the hourly and the five minutes
// we are looking for these short signals crosses down
// in the overbought region of the stochastic. Viceversa for longs"

//@version=4
strategy("Stoch + WMA + SMA strat", overlay=true)

//SL & TP Inputs
i_SL=input(true, title="Use Swing Lo/Hi Stop Loss & Take Profit")
i_SwingLookback=input(20, title="Swing Lo/Hi Lookback")
i_SLExpander=input(defval=10, step=1, title="SL Expander")
i_TPExpander=input(defval=30, step=1, title="TP Expander")
i_reverse=input(false, title="Reverse Trades")
i_TStop =input(false, title="Use Trailing Stop")

//Strategy Inputs
src4 = input(close, title="RSI Source")
stochOS=input(defval=20, step=5, title="Stochastics Oversold Level")
stochOB=input(defval=80, step=5, title="Stochastics Overbought Level")

//Stoch rsi Calculations
smoothK = input(3, minval=1)
smoothD = input(3, minval=1)
lengthRSI = input(14, minval=1)
lengthStoch = input(14, minval=1)
rsi1 = rsi(src4, lengthRSI)
k = sma(stoch(rsi1, rsi1, rsi1, lengthStoch), smoothK)
d = sma(k, smoothD)
h0 = hline(80, linestyle=hline.style_dotted)
h1 = hline(20, linestyle=hline.style_dotted)

//MA
wmalen=input(defval=144, title="WMA Length")
WMA = security(syminfo.tickerid, "60", wma(close, wmalen))
SMA = security(syminfo.tickerid, "60", sma(close, 5))
minWMA = wma(close, wmalen)
minSMA = sma(close, 5)

//Entry Logic
stobuy = crossover(k, d) and k < stochOS
stosell = crossunder(k, d) and k > stochOB
mabuy = minSMA > minWMA
daymabuy = SMA > WMA

//SL & TP Calculations
SwingLow=lowest(i_SwingLookback)
SwingHigh=highest(i_SwingLookback)
bought=strategy.position_size != strategy.position_size[1]
LSL=valuewhen(bought, SwingLow, 0)-((valuewhen(bought, atr(14), 0)/5)*i_SLExpander)
SSL=valuewhen(bought, SwingHigh, 0)+((valuewhen(bought, atr(14), 0)/5)*i_SLExpander)
lTP=(strategy.position_avg_price + (strategy.position_avg_price-(valuewhen(bought, SwingLow, 0)))+((valuewhen(bought, atr(14), 0)/5)*i_TPExpander))
sTP=(strategy.position_avg_price - (valuewhen(bought, SwingHigh, 0) - strategy.position_avg_price))-((valuewhen(bought, atr(14), 0)/5)*i_TPExpander)
islong=strategy.position_size > 0
isshort=strategy.position_size < 0

//TrailingStop
dif=(valuewhen(strategy.position_size>0 and strategy.position_size[1]<=0, high,0))
 -strategy.position_avg_price
trailOffset     = strategy.position_avg_price - LSL
var tstop = float(na)
if strategy.position_size > 0
    tstop := high- trailOffset - dif
    if tstop<tstop[1]
        tstop:=tstop[1]
else
    tstop := na
StrailOffset     = SSL - strategy.position_avg_price
var Ststop = float(na)
Sdif=strategy.position_avg_price-(valuewhen(strategy.position_size<0 
 and strategy.position_size[1]>=0, low,0))
if strategy.position_size < 0
    Ststop := low+ StrailOffset + Sdif
    if Ststop>Ststop[1]
        Ststop:=Ststop[1]
else
    Ststop := na
    
//Stop Selector
SL= islong ? LSL : isshort ? SSL : na
if i_TStop 
    SL:= islong ? tstop : isshort ? Ststop : na
TP= islong ? lTP : isshort ? sTP : na


//Entries
if stobuy and mabuy and daymabuy
    strategy.entry("long", long=not i_reverse?true:false)
if stosell and not mabuy and not daymabuy
    strategy.entry("short", long=not i_reverse?false:true)


//Exit
if i_SL
    strategy.exit("longexit", "long", stop=SL, limit=TP)
    strategy.exit("shortexit", "short", stop=SL, limit=TP)

//Plots
plot(i_SL ? SL : na, color=color.red, style=plot.style_cross)
plot(i_SL ? TP : na, color=color.green, style=plot.style_cross)
plot(minWMA)
plot(minSMA, color=color.green)
もっと

2019 FMZ - すべての権利は保護されています.