多重指数移動平均クロスオーバートレンドフィルター取引戦略

/*backtest
start: 2024-05-20 00:00:00
end: 2024-08-17 00:00:00
period: 1h
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"DOGE_USDT"}]
*/

// @version=6
strategy("EMA sabit usdt ve Alarm)", overlay=true, margin_long=1, margin_short=1)

// —— GİRDİLER —— //
fastLen        = input.int(6,   "EMA6 Periyodu")
slowLen        = input.int(14,  "EMA14 Periyodu")
midLen         = input.int(50,  "EMA50 Periyodu")
longLen        = input.int(200, "EMA200 Periyodu")

tpMode         = input.string("Percent", "Take Profit Modu", options=["Percent", "EMA Cross"])
tpPerc         = input.float(2.0, "TP (%)", step=0.1)
slPerc         = input.float(7.0, "Stop Loss (%)", step=0.1)

orderSizeMode  = input.string("Percent", "Pozisyon Boyutu Modu", options=["Percent", "Fixed"])
orderSizePerc  = input.float(10.0, "Boyut (%)", minval=0.1, step=0.1)
orderSizeFixed = input.float(5.0,  "Boyut (Sabit) [USDT]", minval=0)

leverage       = input.int(1, "Kaldıraç", minval=1)

minEMAPct      = input.float(1.0, "%50–200 Min Fark", step=0.1)

// —— EMA HESAPLAMALARI —— //
ema6   = ta.ema(close, fastLen)
ema14  = ta.ema(close, slowLen)
ema50  = ta.ema(close, midLen)
ema200 = ta.ema(close, longLen)

plot(ema6,   title="EMA 6",   linewidth=1)
plot(ema14,  title="EMA 14",  linewidth=1)
plot(ema50,  title="EMA 50",  linewidth=2)
plot(ema200, title="EMA 200", linewidth=2)

crossUp    = ta.crossover(ema6, ema14)
crossDown  = ta.crossunder(ema6, ema14)
priceAbove50  = close > ema50
priceBelow50  = close < ema50
priceAbove200 = close > ema200
priceBelow200 = close < ema200
upTrend    = ema50 > ema200
downTrend  = ema50 < ema200
zoneLong   = priceBelow50 and priceAbove200
zoneShort  = priceAbove50 and priceBelow200
emaDistPct = math.abs(ema50 - ema200) / ema200 * 100
strongTrend= emaDistPct >= minEMAPct

// —— KOŞULLAR —— //
longCond  = crossUp and upTrend and strongTrend and (priceAbove50 or zoneLong)
shortCond = crossDown and downTrend and strongTrend and (priceBelow200 or zoneShort)

// —— POZİSYON MİKTARI —— //
var float qty = na
if orderSizeMode == "Percent"
    qty := strategy.equity * (orderSizePerc/100) * leverage
else
    qty := (orderSizeFixed / close) * leverage

// —— SİNYAL KOŞULLARI — statik mesajlar —— //
alarmLongID  = "EMA_Long_Signal"
alarmShortID = "EMA_Short_Signal"

// —— GİRİŞLER —— //
if longCond
    strategy.entry("Long", strategy.long, qty=qty)
    label.new(bar_index, high, text="Long", yloc=yloc.abovebar)

if shortCond
    strategy.entry("Short", strategy.short, qty=qty)
    label.new(bar_index, low, text="Short", yloc=yloc.belowbar)

// —— ALERTCONDITION ile sabit mesaj —— //
alertcondition(longCond, title="Long Alarm", message=alarmLongID)
alertcondition(shortCond, title="Short Alarm", message=alarmShortID)

// ÇIKIŞLAR (TP/SL) —— //
if tpMode == "Percent"
    if strategy.position_size > 0
        slPrice = strategy.position_avg_price * (1 - slPerc/100)
        tpPrice = strategy.position_avg_price * (1 + tpPerc/100)
        strategy.exit("Exit Long", from_entry="Long", stop=slPrice, limit=tpPrice)
    if strategy.position_size < 0
        slPrice = strategy.position_avg_price * (1 + slPerc/100)
        tpPrice = strategy.position_avg_price * (1 - tpPerc/100)
        strategy.exit("Exit Short", from_entry="Short", stop=slPrice, limit=tpPrice)
else
    if strategy.position_size > 0
        slPrice = strategy.position_avg_price * (1 - slPerc/100)
        strategy.exit("Stop Long", from_entry="Long", stop=slPrice)
    if strategy.position_size < 0
        slPrice = strategy.position_avg_price * (1 + slPerc/100)
        strategy.exit("Stop Short", from_entry="Short", stop=slPrice)