Zスコア動的移動平均クロスオーバー定量取引戦略

/*backtest
start: 2024-07-13 18:40:00
end: 2025-06-25 08:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT","balance":50000000}]
*/

//@version=6
strategy("Z Score 主图策略 — v1.02", overlay=true)

// 参数
enableZScore = input.bool(true, title="启用Z分数策略")
zBaseLength  = input.int(3, minval=1, title="Z分数基础周期")
shortSmooth  = input.int(3, title="短期平滑")
longSmooth   = input.int(5, title="长期平滑")
gapBars      = input.int(5, minval=1, title="相同信号间隔K线数")

// Z 分数
f_zscore(src, len) =>
    mean = ta.sma(src, len)
    std = ta.stdev(src, len)
    (src - mean) / std

zRaw   = f_zscore(close, zBaseLength)
zShort = ta.sma(zRaw, shortSmooth)
zLong  = ta.sma(zRaw, longSmooth)

baseLongCond = zShort > zLong
baseExitCond = zShort < zLong

// 信号间隔
var int lastEntryBar = na
var int lastExitBar  = na

// 策略逻辑
if enableZScore
    if baseLongCond and (na(lastEntryBar) or bar_index - lastEntryBar > gapBars)
        strategy.entry("Z Score", strategy.long)
        lastEntryBar := bar_index
        alert("Z分数策略触发买入信号，建议开多仓", alert.freq_once_per_bar)

    if baseExitCond and (na(lastExitBar) or bar_index - lastExitBar > gapBars)
        strategy.close("Z Score", comment="Z Score")
        lastExitBar := bar_index
        alert("Z分数策略触发卖出信号，建议平仓离场", alert.freq_once_per_bar)

// 买卖图标
plotshape(baseLongCond and (na(lastEntryBar) or bar_index - lastEntryBar > gapBars),
     title="买入信号", location=location.belowbar, color=color.green, style=shape.labelup, text="买")

plotshape(baseExitCond and (na(lastExitBar) or bar_index - lastExitBar > gapBars),
     title="卖出信号", location=location.abovebar, color=color.red, style=shape.labeldown, text="卖")

// 盈亏表格
var table positionTable = table.new(position.bottom_right, 2, 2, border_width=1)
table.cell(positionTable, 0, 0, "开仓价", text_color=color.white, bgcolor=color.gray)
table.cell(positionTable, 1, 0, "未实现盈亏 (%)", text_color=color.white, bgcolor=color.gray)

isLong        = strategy.position_size > 0
entryPrice    = strategy.position_avg_price
unrealizedPnL = isLong ? (close - entryPrice) / entryPrice * 100 : na
pnlColor      = unrealizedPnL > 0 ? color.green : unrealizedPnL < 0 ? color.red : color.gray

if isLong
    table.cell(positionTable, 0, 1, str.tostring(entryPrice, "#.####"), text_color=color.gray, bgcolor=color.new(color.gray, 90))
    table.cell(positionTable, 1, 1, str.tostring(unrealizedPnL, "#.##") + " %", text_color=pnlColor, bgcolor=color.new(pnlColor, 90))
else
    table.cell(positionTable, 0, 1, "—", text_color=color.gray, bgcolor=color.new(color.gray, 90))
    table.cell(positionTable, 1, 1, "—", text_color=color.gray, bgcolor=color.new(color.gray, 90))
    // === 显示 MA 均线 ===
showMA        = input.bool(true, title="显示 MA 均线")
maShortPeriod = input.int(5, title="短期 MA 周期")
maMidPeriod   = input.int(21, title="中期 MA 周期")
maLongPeriod  = input.int(60, title="长期 MA 周期")

maShort = ta.sma(close, maShortPeriod)
maMid   = ta.sma(close, maMidPeriod)
maLong  = ta.sma(close, maLongPeriod)

plot(showMA ? maShort : na, title="MA 短期", color=color.rgb(0, 9, 11, 1), linewidth=1)
plot(showMA ? maMid   : na, title="MA 中期", color=color.orange, linewidth=1)
plot(showMA ? maLong  : na, title="MA 长期", color=color.blue, linewidth=1)