더블 HMA 모멘텀 브레이크아웃 트레이딩 전략: 변동성 적응형 추세 추종 시스템

/*backtest
start: 2024-06-30 00:00:00
end: 2025-06-28 08:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT"}]
*/

//@version=5
strategy("⚡ HMA PowerPlay Strategy ⚡", overlay=true, default_qty_type=strategy.percent_of_equity, default_qty_value=5)

// === COLOR SETTINGS ===
bgColor            = input.color(color.new(color.white, 0), "Checklist Background")
titleColor         = input.color(color.blue, "Title Text Color")
textColor          = input.color(color.black, "Text Color")
trueColor          = input.color(color.green, "✅ Check Color")
falseColor         = input.color(color.red, "❌ Cross Color")
bullStrengthColor  = input.color(color.green, "Bullish Strength Color")
bearStrengthColor  = input.color(color.red, "Bearish Strength Color")
oscPanelBgColor    = input.color(color.new(color.white, 0), "Oscillator Panel Background")
pricePanelBgColor  = input.color(color.new(color.white, 0), "Price Panel Background")

// === INPUTS ===
rr_target   = input.float(3.0, "Final Reward Target", minval=0.5)
rr_riskFree = input.float(2.0, "Risk-Free Trigger", minval=0.5)
atrMult     = input.float(1.5, "ATR Multiplier for SL", minval=0.1)
hmaLen      = input.int(20, "HMA Period")
volLen      = input.int(20, "Volume SMA Length")

// === INDICATORS ===
hma20   = ta.hma(close, hmaLen)
hma200  = ta.hma(close, 200)
atr     = ta.atr(14)
volSMA  = ta.sma(volume, volLen)
sma5    = ta.sma(close, 5)
rsiVal  = ta.rsi(close, 14)
[macdLine, signalLine, _] = ta.macd(close, 12, 26, 9)

// === CANDLE STRENGTH ===
candleRange = high - low
bullishStrength = candleRange > 0 and close > open ? ((close - open) / candleRange) * 100 : na
bearishStrength = candleRange > 0 and close < open ? ((close - open) / candleRange) * 100 : na

// === ENTRY CONDITIONS ===
sezHigh = ta.highest(high, 200)
sezLow = ta.lowest(low, 200)
smoothHigh = ta.sma(sezHigh, 5)
smoothLow = ta.sma(sezLow, 5)
sezMidline = (smoothHigh + smoothLow) / 2
trendUp = hma20 > hma200 and sma5 > hma200
trendDown = hma20 < hma200 and sma5 < hma200
strongBullishCandle = close > open and close > high[1]
strongBearishCandle = close < open and close < low[1]
sufficientDistanceLong = (close - hma20) > (atr * 0.5)
sufficientDistanceShort = (hma20 - close) > (atr * 0.5)
volumeAboveAverage = volume > volSMA
longEntrySignal = trendUp and strongBullishCandle and sufficientDistanceLong and volumeAboveAverage and close > sezMidline
shortEntrySignal = trendDown and strongBearishCandle and sufficientDistanceShort and volumeAboveAverage and close < sezMidline

// === POSITION STATUS ===
hasPosition = strategy.position_size != 0
isLong = strategy.position_size > 0
isShort = strategy.position_size < 0

// === OSCILLATOR ENTRY CHECK ===
rsiValid = rsiVal > 30 and rsiVal < 70
macdMomentum = macdLine > signalLine
oscillatorEntryOk = rsiValid and macdMomentum

// === PRICE PANEL ===
weeklyClose = request.security(syminfo.tickerid, "W", close[1])
dailyClose = request.security(syminfo.tickerid, "D", close[1])
isAboveWeekly = close > weeklyClose
isAboveDaily = close > dailyClose

var table pricePanel = table.new(position.top_left, 2, 3, border_width=1, frame_color=pricePanelBgColor, frame_width=1)
table.cell(pricePanel, 0, 0, "Last Closed Candle", text_color=titleColor)
table.cell(pricePanel, 1, 0, "Close Price", text_color=titleColor)
table.cell(pricePanel, 0, 1, "Weekly", text_color=textColor)
table.cell(pricePanel, 1, 1, str.tostring(weeklyClose, "#.##"), text_color=isAboveWeekly ? trueColor : falseColor)
table.cell(pricePanel, 0, 2, "Daily", text_color=textColor)
table.cell(pricePanel, 1, 2, str.tostring(dailyClose, "#.##"), text_color=isAboveDaily ? trueColor : falseColor)

// === TRADE STATE ===
var bool inLong = false
var bool inShort = false
var float entryPrice = na
var float stopLoss = na
var float takeProfit = na
var float riskFreeLevel = na

if longEntrySignal and not inLong and not inShort
    entryPrice := close
    stopLoss := entryPrice - atr * atrMult
    takeProfit := entryPrice + (entryPrice - stopLoss) * rr_target
    riskFreeLevel := entryPrice + (entryPrice - stopLoss) * rr_riskFree
    strategy.entry("Long", strategy.long)
    inLong := true

if shortEntrySignal and not inShort and not inLong
    entryPrice := close
    stopLoss := entryPrice + atr * atrMult
    takeProfit := entryPrice - (stopLoss - entryPrice) * rr_target
    riskFreeLevel := entryPrice - (stopLoss - entryPrice) * rr_riskFree
    strategy.entry("Short", strategy.short)
    inShort := true

if inLong
    if high >= riskFreeLevel
        strategy.exit("Risk-Free Exit Long", from_entry="Long", stop=entryPrice)
    else
        strategy.exit("Final Exit Long", from_entry="Long", stop=stopLoss, limit=takeProfit)
    if strategy.position_size == 0
        inLong := false
        entryPrice := na
        stopLoss := na
        takeProfit := na
        riskFreeLevel := na

if inShort
    if low <= riskFreeLevel
        strategy.exit("Risk-Free Exit Short", from_entry="Short", stop=entryPrice)
    else
        strategy.exit("Final Exit Short", from_entry="Short", stop=stopLoss, limit=takeProfit)
    if strategy.position_size == 0
        inShort := false
        entryPrice := na
        stopLoss := na
        takeProfit := na
        riskFreeLevel := na

// === CHECKLIST TABLE ===
checkIcon(cond) => cond ? "✅" : "❌"
checkColor(cond) => cond ? trueColor : falseColor

// === PLOTS ===
plot(hma20, color=color.blue, title="HMA 20")
plot(hma200, color=color.gray, title="HMA 200")
plotshape(longEntrySignal, style=shape.triangleup, location=location.belowbar, color=color.green, title="Long Signal")
plotshape(shortEntrySignal, style=shape.triangledown, location=location.abovebar, color=color.red, title="Short Signal")