Strategi Perdagangan Ichimoku Kinko Hyo


Tarikh penciptaan: 2023-12-12 17:32:08 Akhirnya diubah suai: 2023-12-12 17:32:08
Salin: 2 Bilangan klik: 707
avatar of ChaoZhang ChaoZhang
1
fokus pada
1621
Pengikut

Strategi Perdagangan Ichimoku Kinko Hyo

Gambaran keseluruhan

Ini adalah strategi dagangan saham berbilang mata berdasarkan Indeks Ichimoku Kinko Hyo. Strategi ini menggunakan prinsip asas keseimbangan sekilas untuk menentukan masa masuk dan keluar dari pasaran.

Prinsip Strategi

Strategi ini mula mengira unsur-unsur yang seimbang pada pandangan pertama, termasuk garis antenna ((Tenkan-Sen), garis asas ((Kijun-Sen), garis pendahuluan ((Senkou Span A) dan garis penangguhan ((Senkou Span B)).

Pendaftaran tambahan boleh dilakukan apabila syarat-syarat berikut dipenuhi:

  • Garis acuan yang dipotong di atas antena, menunjukkan bahawa garis rata-rata jangka pendek dipotong di atas garis rata-rata jangka panjang, dan merupakan isyarat garpu emas
  • Grafik harga yang menunjukkan bahawa harga saham mendapat sokongan dan mula naik
  • Awan masa depan berwarna merah, menunjukkan trend masa depan
  • Harga kurang dari 2 kali ATR dari garis swap, menunjukkan harga tidak tinggi, sesuai dengan strategi mengejar
  • Harga kurang daripada 3 kali ATR dari garis asas, menunjukkan harga tidak tinggi, sesuai dengan strategi mengejar
  • Garis langit-langit dan garis rujukan di atas peta awan, menunjukkan trend ke atas pada pandangan pertama

Apabila syarat-syarat berikut dipenuhi, kedudukan kosong akan dimainkan:

  • Garis langit-langit yang menembusi garis rujukan, yang menunjukkan garis purata jangka pendek yang menembusi garis purata jangka panjang, yang tergolong dalam isyarat garpu mati
  • Harga turun ke bawah, menunjukkan harga saham kehilangan sokongan
  • Atau keuntungan melebihi 30%, mengikut strategi penangguhan
  • atau kerugian melebihi 3%, mengikut strategi stop loss

Analisis kelebihan

  • Menggunakan indikator keseimbangan sekilas untuk menentukan trend harga saham, ketepatan yang lebih tinggi
  • Terpadu dengan ATR untuk mengawal kejatuhan dan mengelakkan pembelian berlebihan
  • Mencari pelbagai isyarat dan mengelakkan isyarat palsu
  • Strategi penambahbaikan boleh mempercepatkan keuntungan

Analisis risiko

  • Isyarat keseimbangan pertama mungkin terlewat dan perlu digabungkan dengan petunjuk lain.
  • Tetapan parameter ATR yang salah boleh menyebabkan overbuying dan overselling
  • Strategi penambahbaikan boleh meningkatkan risiko kerugian
  • Parameter yang perlu ditentukan secara manual, parameter berbeza untuk setiap saham

Arah pengoptimuman

  • Boleh digabungkan dengan MACD, KDJ dan lain-lain untuk mengesahkan isyarat
  • Anda boleh meningkatkan margin stop dan mengurangkan margin stop.
  • Parameter ATR boleh dioptimumkan secara automatik berdasarkan data sejarah
  • Kajian mengenai perbezaan parameter dalam saham industri yang berbeza untuk membina kolam parameter

ringkaskan

Ini adalah strategi dagangan saham yang sangat praktikal, menggunakan trend penilaian keseimbangan sekilas, ATR mengawal risiko, untuk mendapatkan keuntungan dari cara mengejar hentian. Kelebihan strategi ini jelas, setelah pengoptimuman parameter dan pengoptimuman indikator gabungan, kesannya lebih baik, sesuai untuk perdagangan cakera keras.

Kod sumber strategi 
/*backtest
start: 2022-12-05 00:00:00
end: 2023-12-11 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// Author Obarut
//@version=5
strategy("İchimoku Strategy With Money Management",overlay=true)

//Inputs
ts_period = input.int(9, minval=1, title="Tenkan-Sen Period")
ks_period = input.int(26, minval=1, title="Kijun-Sen Period")
ssb_period = input.int(52, minval=1, title="Senkou-Span B Period")
cs_offset = input.int(26, minval=1, title="Chikou-Span Offset")
ss_offset = input.int(26, minval=1, title="Senkou-Span Offset")


// Back Testing Period

fromday = input.int(defval=1,title="Start Date",minval=1,maxval=31) 
frommonth = input.int(defval=1,title="Start Month",minval=1,maxval=12)
fromyear = input.int(defval=1980,title="Start Year",minval=1800, maxval=2100)
today = input.int(defval=1,title="En Date",minval=1,maxval=31)
tomonth = input.int(defval=1,title="End Month",minval=1,maxval=12)
toyear =input.int(defval=2100,title="End Year",minval=1800,maxval=2200)


start=timestamp(fromyear,frommonth,fromday,00,00)
finish=timestamp(toyear,tomonth,today,00,00)
timewindow= time>=start and time<=finish

middle(len) => math.avg(ta.lowest(len), ta.highest(len))

// Ichimoku Components

tenkan = middle(ts_period)
kijun = middle(ks_period)
senkouA = math.avg(tenkan, kijun)
senkouB = middle(ssb_period)


atr = ta.atr(14)
ss_above = math.max(senkouA[ss_offset-1], senkouB[ss_offset-1])
ss_below = math.min(senkouA[ss_offset-1], senkouB[ss_offset-1])

// Price Distance From Tenkan

distance = close - tenkan

// Price Distance from Kijun

distancek = close - kijun

// Entry/Exit Signals

tk_cross_kijun_bull = tenkan >= kijun
tk_cross_kijun_bear = tenkan <= kijun
cs_cross_bull = ta.mom(close, cs_offset-1) > 0
cs_cross_bear = ta.mom(close, cs_offset-1) < 0
price_above_kumo = close > ss_above
pbsenkA = close < ss_above
pasenkB = close > ss_below
price_below_kumo = close < ss_above
future_kumo_bull = senkouA > senkouB
future_kumo_bear = senkouA < senkouB
// Price Distance From Tenken
disbull = distance < 2*atr
//Price Distance From Kijun
disbullk = distancek < 3*atr
//Price Above Tenkan Condition
patk = close > tenkan
// Kijun Above Senkou Span Condition
kjasenkA = kijun > ss_above
// Price Below Kijun Condition
pbkijun = close < kijun

//Bullish Condition

bullish= tk_cross_kijun_bull and cs_cross_bull and price_above_kumo and future_kumo_bull and patk and disbull and disbullk 
     and (tenkan>ss_above) and (kijun>ss_above)

if(bullish and timewindow )
    strategy.entry("Long Entry", strategy.long)

// Bearish Condition

bearish=tk_cross_kijun_bear and pbsenkA and cs_cross_bear  
      or pbkijun or price_below_kumo 

lastentryprice = strategy.opentrades.entry_price(strategy.opentrades - 1)

// Take Profit or Stop Loss in Bearish

if(bearish and timewindow or (close>1.30*lastentryprice and close<kijun ) or (close< 0.93*lastentryprice))
    strategy.close("Long Entry")




if(time>finish)
    strategy.close_all("time up")


plot(tenkan, color=#0496ff, title="Tenkan-Sen")
plot(kijun, color=#991515, title="Kijun-Sen")
plot(close, offset=-cs_offset+1, color=#2e640e, title="Chikou-Span")
sa=plot(senkouA, offset=ss_offset-1, color=color.rgb(17, 122, 21), title="Senkou-Span A")
sb=plot(senkouB, offset=ss_offset-1, color=color.rgb(88, 8, 8), title="Senkou-Span B")
fill(sa, sb, color = senkouA > senkouB ? color.rgb(198, 234, 198) : color.rgb(208, 153, 153), title="Cloud color")
Forums
PINE Language FAQ Summary MyLanguage Web3 About Us
Product
Robot Strategy Node Platforms Tickets
API
Syntax guide User guide Trading api Blockchain Indicator

© 2015 - ∞ INVENTOR PTE LTD (SG)