DCCI Breakout Strategi

Penulis:ChaoZhang, Tarikh: 2024-02-18 10:13:21
Tag:

Ringkasan

DCCI Breakout Strategy adalah strategi perdagangan jangka pendek yang mengenal pasti situasi oversold dan overbought menggunakan penunjuk CCI. Ia menggabungkan penunjuk CCI dan garis purata bergerak WMA. Ia menjadi panjang apabila penunjuk CCI melantun kembali dari zon oversold dan menjadi pendek apabila penunjuk CCI jatuh kembali dari zon overbought, keluar selepas membuat keuntungan.

Logika Strategi

Strategi ini menggunakan penunjuk CCI untuk menilai keadaan overbought / oversold pasaran. Penunjuk CCI dapat dengan berkesan mengenal pasti keadaan harga yang tidak normal. Nilai di bawah -100 menunjukkan pasaran terlalu laris sementara nilai di atas 100 menunjukkan pasaran terlalu laris. Strategi akan menjadi panjang apabila penunjuk CCI melintasi di atas -100 dari bawah; dan akan menjadi pendek apabila penunjuk CCI melintasi di bawah 100 dari atas.

Pada masa yang sama, strategi ini juga menggabungkan garis purata bergerak WMA untuk menentukan arah trend. Hanya apabila harga penutupan di atas garis WMA isyarat panjang akan sah; hanya apabila harga penutupan di bawah garis WMA isyarat pendek akan sah. Ini membantu menapis beberapa isyarat perdagangan yang tidak jelas.

Selepas memasuki kedudukan, strategi menggunakan stop loss untuk mengawal risiko. Terdapat tiga kaedah stop loss pilihan: berhenti strategi tetap, berhenti swing tinggi / rendah, berhenti ATR. Apabila panjang, kedudukan akan dihentikan jika harga jatuh ke tahap berhenti; apabila pendek, kedudukan akan dihentikan jika harga naik ke tahap berhenti.

Analisis Kelebihan

Strategi ini mempunyai kelebihan berikut:

Mengesan peluang terlalu banyak dijual dan terlalu banyak dibeli dengan tepat pada masanya dengan mengenal pasti pembalikan menggunakan penunjuk CCI.
Mengelakkan perdagangan terhadap trend dengan menggabungkan analisis arah trend menggunakan purata bergerak.
Menyediakan pelbagai kaedah stop loss pilihan yang boleh diselaraskan berdasarkan keadaan pasaran.
Isyarat perdagangan yang mudah dan jelas yang mudah dilaksanakan.

Analisis Risiko

Strategi ini juga mempunyai risiko berikut:

Indikator CCI boleh dengan mudah menghasilkan isyarat palsu yang tidak dapat dielakkan sepenuhnya.
Penempatan stop loss yang tidak betul boleh menyebabkan over-stopping.
Ketidakupayaan untuk mengenal pasti trend bermakna terlalu banyak perdagangan yang tidak perlu boleh dihasilkan di pasaran yang berbeza.
Ketidakupayaan untuk menilai arah keseluruhan pasaran boleh menyebabkan perdagangan ke arah yang salah.

Untuk menangani risiko ini, pendekatan pengoptimuman utama adalah:

Masukkan penunjuk lain untuk menapis isyarat CCI.
Mengoptimumkan penempatan berhenti melalui backtesting.
Tambah penunjuk pengenalan trend untuk mengelakkan pasaran yang bergelombang.
Menentukan arah perdagangan berdasarkan analisis kawasan sokongan dan rintangan utama.

Arahan pengoptimuman

Aspek utama untuk mengoptimumkan strategi ini termasuk:

Pengoptimuman Parameter CCI: Sesuaikan tempoh carian CCI, mengoptimumkan parameter penunjuk.
Pengoptimuman Stop Loss: Uji kaedah berhenti yang berbeza dan pilih stop loss yang optimum. Pertimbangkan untuk menambah stop trailing.
Pengoptimuman penapis: Tambah penapis tambahan seperti MACD, RSI untuk membina sistem penapis pelbagai penunjuk untuk mengurangkan isyarat palsu.
Penapisan Trend: Tambah penunjuk pengenalan trend seperti purata bergerak untuk mengelakkan perdagangan kontra-trend.
Pengambilan keuntungan automatik: Membina mekanisme pengambilan keuntungan dinamik untuk mengambil keuntungan secara automatik berdasarkan turun naik pasaran.

Kesimpulan

Secara keseluruhannya, DCCI Breakout Strategy adalah sistem perdagangan jangka pendek yang sangat praktikal. Ia mengenal pasti situasi overbought / oversold menggunakan penunjuk CCI dan menggabungkan purata bergerak untuk bias hala tuju. Risiko dikendalikan melalui stop loss. Isyarat yang mudah dan jelas menjadikan strategi ini mudah dilaksanakan untuk perdagangan jangka pendek. Ujian dan pengoptimuman berterusan dapat meningkatkan prestasi strategi.

/*backtest
start: 2023-02-11 00:00:00
end: 2023-09-20 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © tweakerID

// ---From the "Bitcoin Trading Strategies" book, by David Hanson---

// After testing, works better with an ATR stop instead of the Strategy Stop. This paramater
// can be changed from the strategy Inputs panel.

// "CCI Scalping Strategy
// Recommended Timeframe: 5 minutes
// Indicators: 20 Period CCI, 20 WMA
// Long when: Price closes above 20 WMA and CCI is below -100, enter when CCI crosses above -100.
// Stop: Above 20 WMA"

//@version=4
strategy("CCI Scalping Strat", 
     overlay=true, 
     default_qty_type=strategy.percent_of_equity, 
     default_qty_value=100, 
     initial_capital=10000, 
     commission_value=0.04, 
     calc_on_every_tick=false, 
     slippage=0)

direction = input(0, title = "Strategy Direction", type=input.integer, minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))

/////////////////////// STRATEGY INPUTS ////////////////////////////////////////
title1=input(true, "-----------------Strategy Inputs-------------------")  

i_Stop = input(0, step=.05, title="Strategy Stop Mult")*.01
i_CCI=input(16, title="CCI Length")
i_WMA=input(5, title="WMA Length")

/////////////////////// BACKTESTER /////////////////////////////////////////////
title2=input(true, "-----------------General Inputs-------------------")  

// Backtester General Inputs
i_SL=input(true, title="Use Stop Loss and Take Profit")
i_SLType=input(defval="ATR Stop", title="Type Of Stop", options=["Strategy Stop", "Swing Lo/Hi", "ATR Stop"])
i_SPL=input(defval=10, title="Swing Point Lookback")
i_PercIncrement=input(defval=2, step=.1, title="Swing Point SL Perc Increment")*0.01
i_ATR = input(14, title="ATR Length")
i_ATRMult = input(10, step=.1, title="ATR Multiple")
i_TPRRR = input(1.5, step=.1, title="Take Profit Risk Reward Ratio")

// Bought and Sold Boolean Signal
bought = strategy.position_size > strategy.position_size[1] 
 or strategy.position_size < strategy.position_size[1]

// Price Action Stop and Take Profit
LL=(lowest(i_SPL))*(1-i_PercIncrement)
HH=(highest(i_SPL))*(1+i_PercIncrement)
LL_price = valuewhen(bought, LL, 0)
HH_price = valuewhen(bought, HH, 0)
entry_LL_price = strategy.position_size > 0 ? LL_price : na 
entry_HH_price = strategy.position_size < 0 ? HH_price : na 
tp=strategy.position_avg_price + (strategy.position_avg_price - entry_LL_price)*i_TPRRR
stp=strategy.position_avg_price - (entry_HH_price - strategy.position_avg_price)*i_TPRRR

// ATR Stop
ATR=atr(i_ATR)*i_ATRMult
ATRLong = ohlc4 - ATR
ATRShort = ohlc4 + ATR
ATRLongStop = valuewhen(bought, ATRLong, 0)
ATRShortStop = valuewhen(bought, ATRShort, 0)
LongSL_ATR_price = strategy.position_size > 0 ? ATRLongStop : na 
ShortSL_ATR_price = strategy.position_size < 0 ? ATRShortStop : na 
ATRtp=strategy.position_avg_price + (strategy.position_avg_price - LongSL_ATR_price)*i_TPRRR
ATRstp=strategy.position_avg_price - (ShortSL_ATR_price - strategy.position_avg_price)*i_TPRRR

/////////////////////// STRATEGY LOGIC /////////////////////////////////////////

//CCI
CCI=cci(close, i_CCI)
//WMA
WMA=wma(close, i_WMA)

//Stops
LongStop=valuewhen(bought, WMA, 0)*(1-i_Stop)
ShortStop=valuewhen(bought, WMA, 0)*(1+i_Stop)
StratTP=strategy.position_avg_price + (strategy.position_avg_price - LongStop)*i_TPRRR
StratSTP=strategy.position_avg_price - (ShortStop - strategy.position_avg_price)*i_TPRRR

BUY = (close > WMA) and crossover(CCI , -100)
SELL = (close < WMA) and crossunder(CCI , 100)

//Trading Inputs
DPR=input(true, "Allow Direct Position Reverse")
reverse=input(false, "Reverse Trades")

// Entries
if reverse
    if not DPR
        strategy.entry("long", strategy.long, when=SELL and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=BUY and strategy.position_size == 0)
    else     
        strategy.entry("long", strategy.long, when=SELL)
        strategy.entry("short", strategy.short, when=BUY)
else
    if not DPR 
        strategy.entry("long", strategy.long, when=BUY and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=SELL and strategy.position_size == 0)
    else
        strategy.entry("long", strategy.long, when=BUY)
        strategy.entry("short", strategy.short, when=SELL)


SL= i_SLType == "Swing Lo/Hi" ? entry_LL_price : i_SLType == "ATR Stop" ? LongSL_ATR_price : LongStop
SSL= i_SLType == "Swing Lo/Hi" ? entry_HH_price : i_SLType == "ATR Stop" ? ShortSL_ATR_price : ShortStop
TP= i_SLType == "Swing Lo/Hi" ? tp : i_SLType == "ATR Stop" ? ATRtp : StratTP
STP= i_SLType == "Swing Lo/Hi" ? stp : i_SLType == "ATR Stop" ? ATRstp : StratSTP

strategy.exit("TP & SL", "long", limit=TP, stop=SL, when=i_SL)
strategy.exit("TP & SL", "short", limit=STP, stop=SSL, when=i_SL)

/////////////////////// PLOTS //////////////////////////////////////////////////


plot(WMA)
plot(i_SL and strategy.position_size > 0 ? SL : na , title='SL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size < 0 ? SSL : na , title='SSL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size > 0 ? TP : na, title='TP', style=plot.style_cross, color=color.green)
plot(i_SL and strategy.position_size < 0 ? STP : na, title='STP', style=plot.style_cross, color=color.green)
// Draw price action setup arrows
plotshape(BUY ? 1 : na, style=shape.triangleup, location=location.belowbar, 
 color=color.green, title="Bullish Setup", size=size.auto)
plotshape(SELL ? 1 : na, style=shape.triangledown, location=location.abovebar, 
 color=color.red, title="Bearish Setup", size=size.auto)

Lebih lanjut

2019 FMZ - Semua hak dilindungi