Estratégia de negociação quantitativa de dupla pressão

Autora:ChaoZhang, Data: 2023-11-02 13:56:23
Tags:

Resumo

A estratégia de negociação quantitativa de pressão dupla é uma estratégia de tendência que combina indicadores estocásticos e de volume.

Estratégia lógica

Signais de compra

O sinal de compra principal é acionado quando:

Ambas as linhas K e D cruzam abaixo da área de sobrevenda (por exemplo 20) e aumentam, e ambas as linhas K e D estão subindo
O volume está acima de um limiar (por exemplo, 1,4 vezes o volume médio)
Fechar é acima de abrir (luma branca)

Outros sinais de compra podem vir de:

Cruz de ouro: A EMA rápida cruza a EMA lenta, ambas em alta
Tanto o K como o D subem da zona baixa para a zona média (por exemplo, de abaixo de 20 para 20-80)

Venda de sinais

Os principais sinais de venda são acionados quando:

Tanto K como D entram na área de sobrecompra (por exemplo, acima de 80%)
Cruz de morte: EMA rápida cruza abaixo da EMA lenta
K cruza abaixo de D, e ambos K e D estão caindo

Parar de Perder

O nível de stop loss é definido como uma percentagem (por exemplo, 6%) abaixo do preço de compra.

Análise das vantagens

Estocástico duplo evita sinais falsos
O volume filtra o ruído e assegura a tendência
Múltiples sinais combinados melhoram a precisão
As médias móveis favorecem a tendência geral
Risco de controlo de perdas de paragem

Vantagem 1: Estocástico duplo evita sinais falsos

A combinação estocástica dupla filtra os sinais falsos e melhora a confiabilidade.

Vantagem 2: O volume filtra o ruído e garante a tendência

A condição de volume filtra pontos de baixo volume que não são tendências e reduz o risco de ficar preso.

Vantagem 3: múltiplos sinais melhoram a precisão

Vários indicadores devem se alinhar para desencadear sinais reais de negociação.

Vantagem 4: As médias móveis auxiliam a tendência geral

Regras como médias móveis duplas garantem que os sinais se alinhem com a tendência geral.

Vantagem 5: Controle do risco com stop loss

A lógica de stop loss realiza lucros e controla perdas em negociações individuais.

Análise de riscos

Os parâmetros precisam de uma otimização cuidadosa, configurações inadequadas levam a um mau desempenho
A colocação de stop loss deve ter em conta o risco de diferença
O risco de liquidez dos instrumentos de negociação deve ser monitorizado
Questão de retrospecção entre diferentes prazos

Risco 1: Os parâmetros precisam de uma otimização cuidadosa

A estratégia tem múltiplos parâmetros. Eles precisam de otimização para diferentes instrumentos, caso contrário o desempenho sofre.

Risco 2: A colocação de perdas de parada deve ter em conta o risco de diferença

O ponto de stop loss deve ter em conta cenários de diferença de preço.

Risco 3: Monitorizar o risco de liquidez

Para os instrumentos não líquidos, as regras de volume podem filtrar muitos sinais.

Risco 4: Questão de retrospectiva entre os prazos

O desalinhamento entre os sinais em diferentes prazos pode ocorrer. Os sinais devem ser verificados para coincidir.

Oportunidades de melhoria

A estratégia pode ser reforçada em domínios como:

Otimizar os parâmetros de robustez
Introduzir aprendizado de máquina para parâmetros adaptativos
Melhorar a estratégia de stop loss para reduzir a taxa de stop loss
Adicionar filtros para reduzir a frequência de negociação
Explorar ordens condicionais ou a obtenção de lucros para melhorar a recompensa

Oportunidade 1: Optimizar os parâmetros de robustez

Métodos como algoritmos genéticos podem otimizar sistematicamente parâmetros para estabilidade em todos os regimes de mercado.

Oportunidade 2: Introduzir o aprendizado de máquina para parâmetros adaptativos

Os modelos podem avaliar as condições do mercado e ajustar os parâmetros em conformidade, alcançando a otimização dinâmica.

Oportunidade 3: Melhorar a estratégia de stop loss para reduzir a taxa de stop loss

Algoritmos de stop loss melhores podem reduzir as paradas desnecessárias, mantendo o controle do risco.

Oportunidade 4: Adicionar filtros para reduzir a frequência do comércio

O reforço dos filtros pode reduzir a frequência do comércio, reduzir os custos e melhorar os retornos por comércio.

Oportunidade 5: Explorar ordens condicionais ou lucrativas

De acordo com as condições do mercado, ordens condicionais ou estratégias de captação de lucro podem maximizar melhor o lucro, controlando o risco.

Conclusão

A estratégia equilibra tendência, controle de risco, custos e outros aspectos. As principais vantagens são o duplo estocástico mais volume para tendência e stop loss para controle de risco. Os próximos passos são melhorar a robustez, parâmetros adaptativos, otimização de stop loss, etc. para gerar lucros constantes em mais regimes de mercado.

/*backtest
start: 2023-10-02 00:00:00
end: 2023-11-01 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=3
// SW SVE - Stochastic+Vol+EMAs [Sergio Waldoke]
// Script created by Sergio Waldoke (BETA VERSION v0.5, fine tuning PENDING)
// Stochastic process is the main source of signals, reinforced on buying by Volume. Also by Golden Cross.
// Selling is determined by K and D entering overselling zone or EMA's Death Cross signal, the first occurring,
// and some other signals combined.
// Buy Long when you see a long buy arrow.
// Sell when you see a close arrow.
// This is a version to be tuned and improved, but already showing excelent results after tune some parameters
// according to the kind of market.
// Strategy ready for doing backtests.

// SVE SYSTEM DESIGN:
// Buy Signal Trigger:
// - Both Stoch <= 20 crossing up and both growing and green candle and Vol/sma vol >= 1.40 Avg Vol
//   or
// - Both Stoch growing up and Vol/sma vol >= 1.40 Avg Vol and green candle and
//   both prior Stoch crossing up
//   or
//   [OPTIONAL]: (Bad for BTC 2018, excelent for 2017)
// - Crossingover(fast_ema, slow_ema) and growing(fast_ema) and growing(slow_ema) and green candle

// Exit position:
// - Both Stoch <= 20 and Both Stoch were > 20 during position
//   or
// - CrossingUnder(Fast EMA, Medium EMA)
//   or   [OPTIONAL] (Better for BTC 2018, Worse for BNB 1H)
// - CrossingUnder(k, d) and (k and d starting over over_buying) and (k and d descending) and k crossing down over_buying line

//calc_on_every_tick=true,
//calc_on_order_fills=true,   (affects historical calculation, triggers in middle of the bar, may be better for automatic orders)
strategy("SW SVE - Stochastic+Vol+EMAs [Sergio Waldoke]", shorttitle="SW SVE", overlay=true, max_bars_back=5000,
         default_qty_type=strategy.percent_of_equity, default_qty_value=100, currency="USD",
         commission_type=strategy.commission.percent, commission_value=0.25)

//Strategy Parameters
FromDay   = input(defval = 1, title = "From Day", minval = 1, maxval = 31)
FromMonth = input(defval = 1, title = "From Month", minval = 1, maxval = 12)
FromYear  = input(defval = 2018, title = "From Year", minval = 2009, maxval = 2200)
ToDay     = input(defval = 31, title = "To Day", minval = 1, maxval = 31)
ToMonth   = input(defval = 12, title = "To Month", minval = 1, maxval = 12)
ToYear    = input(defval = 2030, title = "To Year", minval = 2009, maxval = 2200)

//Indicator Parameters
//Original defaults for 4HS: 14, 3, 80, 20,   14, 23, 40,   20, 40,   3:
stoch_k = input(title="Stoch K",  defval=14, minval=1)
stoch_d = input(title="Stoch D",  defval=3, minval=1)
over_buying  = input(title="Stoch Overbuying Zone",  defval=80, minval=0, maxval=100)
over_selling = input(title="Stoch Overselling Zone",  defval=20, minval=0, maxval=100)

fast_ema_periods = input(title="Fast EMA (Death Cross)",  defval=14, minval=1, maxval=600)
slow_ema_periods = input(title="Slow EMA (Death Cross)",  defval=23, minval=1, maxval=600)
trend_ema_periods = input(title="Slowest EMA (Trend Test)",  defval=40, minval=1, maxval=600)

volume_periods = input(title="Volume Periods",  defval=20, minval=1, maxval=600)
volume_factor = input(title="Min Volume/Media Increase (%)",  defval=80, minval=-100) / 100 + 1

threshold_sl_perc = input(title="[Sell Trigger] Stop Loss Threshold %", defval=6.0, type=float, minval=0, maxval=100)

//before_buy = input(title="# Growing Before Buy",  defval=2, minval=1)
//before_sell = input(title="# Decreasing Before Sell",  defval=1, minval=1)
//stepsignal = input(title="Show White Steps", type=bool, defval=true)
//steps_base = input(title="White Steps Base",  defval=242, minval=0)

//Signals
fast_ema = ema(close, fast_ema_periods)
slow_ema = ema(close, slow_ema_periods)
trend_ema = ema(close, trend_ema_periods)
k = stoch(close, high, low, stoch_k)
d = sma(k, stoch_d)
vol_ma = sma(volume, volume_periods)

//REVIEW CONSTANT 1.75:
in_middle_zone(a) => a > over_selling * 1.75 and a < over_buying
growing(a) => a > a[1] 

was_in_middle_zone = k == d
was_in_middle_zone := was_in_middle_zone[1] or in_middle_zone(k) and in_middle_zone(d)

//Buy Signal Trigger:
//- Both Stoch <= 20 crossing up and both growing and 
//  green candle and Vol/sma vol >= 1.40 Avg Vol
buy = k <= over_selling and d <= over_selling and crossover(k, d) and growing(k) and growing(d) and
      close > open and volume/vol_ma >= volume_factor

//or
//- Both Stoch growing up and Vol/sma vol >= 1.40 Avg Vol and green candle and
//  both prior Stoch crossing up
buy := buy or (growing(k) and growing(d) and volume/vol_ma >= volume_factor and close > open and
              crossover(k[1], d[1]) )
//Worse:
//              (crossover(k[1], d[1]) or (crossover(k, d) and k[1] <= over_selling and d[1] <= over_selling) ) )

//or
//  [OPTIONAL]: (Bad for BTC 2018, excelent for 2017)
//- Crossingover(fast_ema, slow_ema) and growing(fast_ema) and growing(slow_ema) and green candle
buy := buy or (crossover(fast_ema, slow_ema) and growing(fast_ema) and growing(slow_ema) and close > open)


//Debug:
//d1 = close > open  ? 400 : 0
//plot(d1+5200, color=white, linewidth = 3, style = stepline)

//Exit position:
//- Both Stoch <= 20 and Both Stoch were > 20 during position
sell = k <= over_selling and d <= over_selling and was_in_middle_zone

//  or
//- CrossingUnder(Fast EMA, Medium EMA)
sell := sell or crossunder(fast_ema, slow_ema)

//  or  [OPTIONAL] (Better for BTC 2018, Worse for BNB 1H)
//- CrossingUnder(k, d) and (k and d starting over over_buying) and (k and d descending) and k crossing down over_buying line
sell := sell or (crossunder(k, d) and k[1] >= over_buying and d[1] >= over_buying and
                 not growing(k) and not growing(d) and k <= over_buying)

color = buy ? green : red

bought_price = close
bought_price := nz(bought_price[1])

already_bought = false
already_bought := nz(already_bought[1], false)

//Date Ranges
buy  := buy and  not already_bought


//d1 = buy ? 400 : 0
//plot(d1+6500, color=white, linewidth = 3, style = stepline)

was_in_middle_zone := (not buy and was_in_middle_zone) or (in_middle_zone(k) and in_middle_zone(d))

already_bought   := already_bought[1] or buy
bought_price := buy ? close * (1 - threshold_sl_perc/100) : bought_price[1]
trigger_SL = close < bought_price[0]
sell := sell or trigger_SL

sell := sell and  
                 already_bought and not buy and (was_in_middle_zone or trigger_SL)

//plot((sell?400:0)+5200, title="Buy-Sell", color=yellow, linewidth = 3, style = stepline)
                 
already_bought   := already_bought[0] and not sell
bought_price := sell ? 0 : bought_price[0]

//plot((was_in_middle_zone?400:0)+5200, title="Buy-Sell", color=yellow, linewidth = 3, style = stepline)

was_in_middle_zone := not sell and was_in_middle_zone

//Plot signals
plot(fast_ema, title="Fast EMA", color=red, linewidth = 4)
plot(slow_ema, title="Slow EMA", color=blue, linewidth = 4)
plot(trend_ema, title="Trend EMA", color=yellow, linewidth = 4)

//Stop Loss
plot(bought_price, color=gray, linewidth=2, style=cross, join=true, title="Stop Loss")

//Y = stepsignal ? lowest(40) : na
//Y = steps_base
//plot(mysignal+Y, title="Steps", color=white, linewidth = 3, style = stepline)
//Unit steps - for debugging
//plot(mysteps+Y, title="Steps2", color=yellow, linewidth = 3, style = stepline)

//Bought or not - for debugging
//plot((already_bought?400:0)+5200, title="Buy-Sell", color=yellow, linewidth = 3, style = stepline)
//plot((sell?400:0)+5200, title="Buy-Sell", color=yellow, linewidth = 3, style = stepline)

plotshape(buy, title="Buy arrows", style=shape.arrowup, location=location.belowbar, color=color, text="Buy", textcolor=color, size=size.huge, transp=30)
plotshape(sell, title="Sell arrows", style=shape.arrowdown, location=location.abovebar, color=color, text="Sell", textcolor=color, size=size.huge, transp=30)

//if n>2000
strategy.entry("buy", strategy.long, when=buy)
strategy.close_all(when=sell)

//plot(strategy.equity, title="Equity", color=white, linewidth = 4, style = line)

//AlertS trigger
//msg = "[SW Magic Signals EMA] BUY/SELL Signal has been triggered." + "(" + tostring(fastema) + ", " + tostring(slowema) + ") on " + tickerid + ", " + period + "."
msg = "SW SVE BUY/SELL Signal has been triggered. (#, #) on EXCH:PAIR, period: #."

alertcondition(buy or sell, title="SW SVE (BUY/SELL SIGNAL)", message=msg)
alertcondition(buy, title="SW SVE (BUY SIGNAL)", message=msg)
alertcondition(sell, title="SW SVE (SELL SIGNAL)", message=msg)

Mais.