Estratégia de Impulso Simples Baseada na SMA, EMA e Volume

Autora:ChaoZhang, Data: 2023-12-08 11:15:30
Tags:

Resumo

Esta é uma estratégia de momentum intradiário simples que só vai longo e não curto. Utiliza indicadores de SMA, EMA e volume para tentar entrar no mercado no momento ideal quando tanto o preço quanto o momentum estão tendendo para cima. Sua vantagem é ser simples enquanto tem alguma capacidade de reconhecimento de tendência.

Princípio da estratégia

A lógica do sinal de entrada é: quando a SMA é superior à EMA e há um padrão de tendência de alta consecutivo de 3 bares ou 4 bares, com o preço mais baixo das barras do meio sendo maior que o preço aberto da barra de tendência de alta inicial, um sinal de entrada é gerado.

A lógica do sinal de saída é: quando a SMA cruza abaixo da EMA, um sinal de saída é gerado.

Esta estratégia só vai longo e não curto. sua lógica de entrada e saída tem alguma capacidade em reconhecer tendências de alta persistentes.

Análise das vantagens

As vantagens desta estratégia:

A lógica é simples e fácil de compreender e implementar;
Utiliza indicadores técnicos comuns como SMA, EMA e volume para flexibilidade no ajuste dos parâmetros;
Tem alguma capacidade de aproveitar algumas oportunidades durante tendências de alta persistentes.

Análise de riscos

Os riscos desta estratégia:

Incapacidade de detectar tendências de queda ou mercados de consolidação, levando a grandes retrações;
Incapacidade de utilizar oportunidades de curto prazo, incapacidade de se proteger contra tendências descendentes, perda de boas oportunidades de lucro;
Indicador de volume não funciona bem em dados de alta frequência, os parâmetros precisam de ajuste;
Pode utilizar o stop loss para controlar os riscos.

Orientações de otimização

Esta estratégia pode ser otimizada nos seguintes aspectos:

Adicionar a capacidade de curto prazo para oportunidades de reversão média;
Utilização de indicadores mais avançados como o MACD e o RSI para uma melhor detecção de tendências;
Otimizar a lógica de stop loss para reduzir os drawdowns;
Ajustar parâmetros e testar diferentes prazos para encontrar conjuntos de parâmetros ideais.

Conclusão

Em resumo, esta é uma tendência muito simples após a estratégia utilizando SMA, EMA e volume para o tempo de entrada. Sua vantagem é ser simples e fácil de implementar, bom para iniciantes aprenderem, mas não pode detectar consolidação ou tendências de queda e tem riscos. Melhorias podem ser feitas através da introdução de curto, otimização de indicadores e stop loss etc.

/*backtest
start: 2023-11-07 00:00:00
end: 2023-12-02 00:00:00
period: 2h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © slip_stream

//@version=4

// Simple strategy for riding the momentum and optimising the timings of truer/longer price moves upwards for an long posistions on a daily basis (can be used, but with less effect
// on other time frames. Volume settings would have to be adjusted by the user accordingly. (short positions are not used).
// This strategy has default settings of a short(er) SMA of 10, a long(er) EMA of 20, and Volume trigger of 10 units and above. All these settings can be changed by the user
// using the GUI settings and not having to change the script.

// The strategy will only open a long position when there is a clear indication that price momentum is upwards through the SMA moving and remaining above the EMA (mandatory) and price period indicators
// of either 1) a standard 3 bar movement upwards, 2) a standard but "aggressive" 3 or 4 bar play where the low of the middle resting bars can be equal to or higher than (i.e. not
// the more standard low of about half) of the opening of the ignition bar. The "aggression" of the 3/4 bar play was done in order to counteract the conservatisme of having a mandatory
// SMA remaining higher than the EMA (this would have to be changed in the script by the user if they want to optimise to their own specifications. However, be warned, all programmatic
// settings for the maximum acceptable low of the middle resting bars runs a risk of ignoring good entry points due to the low being minutely e.g. 0.01%, lower than the user defined setting)


strategy(title = "Simple Momentum Strategy Based on SMA, EMA and Volume", overlay = true, pyramiding = 1, initial_capital = 100000, currency = currency.USD)


// Obtain inputs
sma_length = input(defval = 10, minval=1, type = input.integer, title = "SMA (small length)")
ema_length = input(defval = 20,minval=1, type = input.integer, title = "EMA (large length)")
volume_trigger = input(defval = 10, title = "Volume Trigger", type = input.integer)
sma_line = sma(close, sma_length)
ema_line = ema(close, ema_length)


// plot SMA and EMA lines with a cross for when they intersect
plot(sma_line, color = #8b0000, title = "SMA")
plot(ema_line, color = #e3d024, title = "EMA")
plot(cross(sma_line, ema_line) ? sma_line : na, style = plot.style_cross, linewidth = 4, color = color.white)


// Create variables
// variables to check if trade should be entered
//three consecutive bar bar moves upwards and volume of at least one bar is more than 10
enter_trade_3_bar_up = sma_line > ema_line and close[1] >= close [2] and close[3] >= close[4] and close[2] >= close[3] and (volume[1] >= volume_trigger or volume[2] >= volume_trigger or volume[3] >= volume_trigger)
// aggressive three bar play that ensures the low of the middle bar is equal to or greater than the open of the instigator bar. Volume is not taken into consideration (i.e. aggressive/risky)
enter_3_bar_play = sma_line > ema_line and close[1] > close[3] and low[2] >= open[3]
// aggressive four bar play similar to the 3 bar play above
enter_4_bar_play = sma_line > ema_line and close[1] > close[4] and low[2] >= open[4]
trade_entry_criteria = enter_trade_3_bar_up or enter_3_bar_play or enter_4_bar_play // has one of the trade entry criterias returned true?

// exit criteria for the trade: when the sma line goes under the ema line
trade_exit_criteria = crossunder (sma_line, ema_line)


if (year >= 2019)
    strategy.entry(id = "long", long = true, qty = 1, when = trade_entry_criteria)
    strategy.close(id = "long", when = trade_exit_criteria, qty = 1)
    // for when you want to brute force close all open positions: strategy.close_all (when = trade_exit_criteria)

Mais.