Estratégia de inversão de tendência de rastreamento

Autora:ChaoZhang, Data: 2024-01-16 14:44:35
Tags:

Resumo

A estratégia de reversão de rastreamento de tendências é uma estratégia de negociação de tendências de curto prazo baseada em futuros NQ de 15 minutos.

Estratégia lógica

A estratégia baseia-se principalmente nos seguintes princípios:

Utilize uma EMA de 8 períodos como o principal filtro de tendência, com sinais longos acima da EMA e sinais curtos abaixo da EMA.
Identifique padrões específicos de reversão do candelabro como sinais de entrada, incluindo velas verdes longas seguidas por velas vermelhas curtas para sinais longos e velas vermelhas longas seguidas por velas verdes curtas para sinais curtos.
Os pontos de entrada são definidos perto do alto/baixo da vela de reversão, com níveis de stop loss no alto/baixo da própria vela de reversão, permitindo rácios de risco/recompensação eficientes.
Validar sinais de reversão usando regras de relação de candelabro, por exemplo, o preço de abertura da vela vermelha está acima do corpo da última vela verde, o corpo engloba completamente etc. para filtrar o ruído.
A estratégia deve ser utilizada apenas durante horas de negociação específicas, evitando períodos voláteis em torno de grandes movimentações de contratos, etc., para evitar perdas desnecessárias devido a uma ação anormal dos preços.

Análise das vantagens

As principais vantagens desta estratégia incluem:

Lógica de sinal simples e eficaz, fácil de compreender e executar.
Baseado na tendência e na inversão, evitando os golpes dos mercados de touros e ursos.
Bom controlo de riscos com colocação razoável de stop loss para preservar o capital.
As necessidades de dados baixos se adaptam a várias plataformas e ferramentas.
A alta frequência de negociação é adequada ao estilo ativo de negociação a curto prazo.

Riscos e soluções

Há alguns riscos a ter em conta:

Ocorrerá uma redução dos critérios de reversão para permitir mais sinais.
Adicione mais filtros para a lógica combinatória.
Restringir a operação estratégica às horas de negociação dos EUA.
flexibilidade de otimização limitada. Considere aprendizagem de máquina para melhor ajuste de parâmetros.

Oportunidades de melhoria

Há espaço para otimização:

Teste períodos EMA mais longos para melhorar a definição da tendência.
Adicionar filtros de índices de ações como filtros de tendência suplementares.
Usar técnicas de aprendizagem de máquina para ajustar automaticamente os níveis de entrada e de perda.
Introduzir o dimensionamento das posições ajustado à volatilidade e as paradas dinâmicas.
Explorar a arbitragem entre ativos para diversificar os riscos sistémicos de um único ativo.

Conclusão

A estratégia de reversão de rastreamento de tendências oferece uma estrutura de estratégia de curto prazo muito prática que é simples de implementar com parâmetros limitados e bom controle de risco pessoal.

/*backtest
start: 2023-12-01 00:00:00
end: 2023-12-31 23:59:59
period: 3h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © bdrex95

//@version=5

// Rob Reversal Strategy - Official
// Using Rob Reversal Indicator: Original
// Description
// This indicator is based on the strategy created by Trader Rob on the NQ 15m chart.
// 
// Timeframe for trading is 8:30am-1:15pm Central.
// 
// Above the EMA line, look for a long position. You will have a short candle, then a long candle that opens below the short candle. It will have a lower high and a lower low. Once the long candle closes, your entry will be 1 tick above the wick (green line) and stop loss will be at the bottom of the bottom wick (red line).
// 
// Below the EMA line, look for a short position. You will have a long candle, then a short candle that opens above the long candle. It will have a higher high and a higher low. Once the short candle closes, your entry will be 1 tick below the wick (green line) and stop loss will be at the top of the top wick (red line).
//

strategy("Trader Rob Reversal Strategy NQ 15min", shorttitle="Official Rob Rev Strat", overlay=true)


//--- Session Input ---
sess = input(defval = "0930-1415", title="Trading Session")
t = time(timeframe.period, sess)
sessionOpen = na(t) ? false : true

flat_time = input(defval = "1515-1558", title="Close All Open Trades")
ft = time(timeframe.period, flat_time)
flatOpen = na(ft) ? false : true


// Calculate start/end date and time condition
startDate = input(timestamp('2018-12-24T00:00:00'),group = "ALL STRATEGY SETTINGS BELOW")
finishDate = input(timestamp('2029-02-26T00:00:00'),group = "ALL STRATEGY SETTINGS BELOW")
time_cond = true


emaColor = input.color(color.orange, title="EMA Color")
emaLength = input.int(8, title="EMA Length")


emaInd = ta.ema(close, emaLength)


rr = input(1.0,"Enter RR",group = "TP/SL CONDITION INPUTS HERE")


sellShapeInput = input.string("Arrow", title="Sell Entry Shape", options=["Arrow", "Triangle"])
buyShapeInput = input.string("Arrow", title="Buy Entry Shape", options=["Arrow", "Triangle"])


sellShapeOption = switch sellShapeInput
    "Arrow" => shape.arrowdown
    "Triangle" => shape.triangledown
   
buyShapeOption = switch buyShapeInput
    "Arrow" => shape.arrowup
    "Triangle" => shape.triangleup


O = open
C = close
H = high
L = low


sellEntry = (C[1] > O[1]) and (C < O) and (H[1] < H) and (C < H[1]) and (C > L[1]) and (L > L[1]) and (C < emaInd) and sessionOpen and time_cond
buyEntry = (C[1] < O[1]) and (C > O) and (H[1] > H) and (L[1] > L) and (C < H[1]) and (C > L[1]) and (C > emaInd) and sessionOpen and time_cond


sellEntry_index = ta.valuewhen(sellEntry,bar_index,0)
sellEntry_hi = ta.valuewhen(sellEntry,high,0)
sellEntry_low = ta.valuewhen(sellEntry,low,0)
buyEntry_index = ta.valuewhen(buyEntry,bar_index,0)
buyEntry_hi = ta.valuewhen(buyEntry,high,0)
buyEntry_lo = ta.valuewhen(buyEntry,low,0)


plotshape(buyEntry, color = color.green, location = location.belowbar, style = buyShapeOption, size = size.small)
plotshape(sellEntry, color = color.red, location = location.abovebar, style = sellShapeOption, size = size.small)
plot(emaInd, color=emaColor)


// Risk Management
entry_price_long = (buyEntry_hi + syminfo.mintick)
entry_price_short = (sellEntry_low - syminfo.mintick)
long_sl_price = (buyEntry_lo-syminfo.mintick)
short_sl_price = (sellEntry_hi + syminfo.mintick)
long_tp_price = ((entry_price_long - long_sl_price)*rr) + entry_price_long
short_tp_price = entry_price_short - ((short_sl_price - entry_price_short)*rr)


long_sl_ticks = (entry_price_long - long_sl_price) / syminfo.mintick
short_sl_ticks = (short_sl_price - entry_price_short) / syminfo.mintick


long_tp_ticks = (long_tp_price - entry_price_long) / syminfo.mintick
short_tp_ticks = (entry_price_short - short_tp_price) / syminfo.mintick


// Positions
if (buyEntry)
    strategy.entry("Long", strategy.long,stop = H + syminfo.mintick)
if strategy.position_size > 0
    strategy.exit("Long Ex","Long", loss = long_sl_ticks, profit = long_tp_ticks, comment_loss = "SL Long", comment_profit = "TP Long")


if (sellEntry)
    strategy.entry("Short", strategy.short,stop = L - syminfo.mintick)
if strategy.position_size < 0
    strategy.exit("Short Ex","Short",loss = short_sl_ticks, profit = short_tp_ticks, comment_loss = "SL Short", comment_profit = "TP Short")


// Cancel order if close beyond ema
if (C < emaInd)
    strategy.cancel("Long")


if (C > emaInd)
    strategy.cancel("Short")


// Go flat at close (for futures funded account)
if strategy.position_size > 0 and flatOpen
    strategy.close_all(comment = "EOD Flat")
if strategy.position_size < 0 and flatOpen
    strategy.close_all(comment = "EOD Flat")
 
//END

Mais.