Estratégias de acompanhamento de tendências baseadas na divergência de preços
ChaoZhang
Visão geral
Esta estratégia baseia-se em indicadores de desvio de preço, combinados com a região de retorno de Fibonacci, para identificar e rastrear tendências. Quando os preços se desviam cada vez mais de uma determinada direção, pode ser considerado uma tendência e, portanto, gerar um sinal de negociação.
Princípio da estratégia
A estratégia usa o VWAP como eixo central do preço. Em seguida, com base na volatilidade do preço, calcula-se uma banda de desvio de preço de 1,618x e 2,618x o desvio padrão. Quando o preço se move de baixo para cima, gera-se um sinal de falta. Quando o preço se move de cima para baixo, gera-se um sinal de falta.
O sinal de parada de perda EXIT após a tomada de mais espaço é: a linha de parada de mais espaço é para baixo, a linha de parada de espaço é para cima.
Os principais passos são os seguintes:
Calculando o VWAP como o eixo médio do preço
Calculando a diferença padrão de preço sd como uma medida da volatilidade dos preços
Calculando ascensão e descensão em base a sd: ascensão e descensão VWAP + 1.618*sd e VWAP + 2.618*sd; sub-carril é VWAP - 1.618*sd e VWAP - 2.618*sd
Quando o preço se move de baixo para cima e quebra 1.618 vezes a trajectória para baixo, gera um sinal de fazer mais; quando o preço se move de cima para baixo e quebra 1.618 vezes a trajectória para cima, gera um sinal de fazer menos
Fazer um stop-loss EXIT: o preço quebra 2.618 vezes para baixo; fazer um stop-loss EXIT: o preço quebra 2.618 vezes para cima
Análise de vantagens
A estratégia tem as seguintes vantagens:
O uso de indicadores de desvio de preço permite determinar e acompanhar de forma eficaz as tendências de preços
Combinação com a zona de retorno de Fibonacci para tornar a entrada e a saída de stop loss mais claras
O VWAP, como eixo central do preço, também aumentou o valor de referência do indicador
Adapta-se a diferentes variedades e ciclos através de ajustes de parâmetros
Análise de Riscos
A estratégia também apresenta alguns riscos:
A tendência é de que os investidores se preocupem mais com o crescimento do mercado de capitais.
Parâmetros mal definidos também podem afetar a eficácia da política
Risco de perda maior em situações de alta volatilidade
Resposta:
Reduzir adequadamente o ciclo de detenção e parar o prejuízo em tempo hábil
Parâmetros de otimização, procurando a melhor combinação de parâmetros
Aumentar a gestão de posições e controlar os perdas individuais
Direção de otimização
A estratégia também pode ser melhorada nas seguintes direções:
Combinação de indicadores de tendência para evitar negociações adversas
Adesão ao mecanismo de gestão de posições
Optimizar configurações de parâmetros
Optimização de retrospectiva em múltiplos períodos de tempo
Resumir
A estratégia baseia-se na idéia de desvio de preço, combinada com a VWAP e a área de diferença padrão de Fibonacci, permitindo a identificação e o rastreamento de tendências. Em comparação com indicadores como a linha média, a estratégia é mais clara no julgamento e o controle de risco é mais claro. Através do ajuste e otimização de parâmetros, a estratégia pode ser aplicada a diferentes variedades e ciclos, obtendo assim melhores efeitos da estratégia.
/*backtest
start: 2024-01-14 00:00:00
end: 2024-01-21 00:00:00
period: 1m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © Mysteriown
//@version=4
strategy(title="VWAP + Fibo Dev Extensions Strategy", overlay=true, pyramiding=5, commission_value=0.08)
// -------------------------------------
// ------- Inputs Fibos Values ---------
// -------------------------------------
fib1 = input(title="Fibo extension 1", type=input.float, defval=1.618)
fib2 = input(title="Fibo extension 2", type=input.float, defval=2.618)
reso = input(title="Resolution VWAP", type=input.resolution, defval="W")
dev = input(title="Deviation value min.", type=input.integer, defval=150)
// -------------------------------------
// -------- VWAP Calculations ----------
// -------------------------------------
t = time(reso)
debut = na(t[1]) or t > t[1]
addsource = hlc3 * volume
addvol = volume
addsource := debut ? addsource : addsource + addsource[1]
addvol := debut ? addvol : addvol + addvol[1]
VWAP = addsource / addvol
sn = 0.0
sn := debut ? sn : sn[1] + volume * (hlc3 - VWAP[1]) * (hlc3 - VWAP)
sd = sqrt(sn / addvol)
Fibp2 = VWAP + fib2 * sd
Fibp1 = VWAP + fib1 * sd
Fibm1 = VWAP - fib1 * sd
Fibm2 = VWAP - fib2 * sd
// -------------------------------------
// -------------- Plots ----------------
// -------------------------------------
plot(VWAP, title="VWAP", color=color.orange)
pFibp2 = plot(Fibp2, color=color.red)
pFibp1 = plot(Fibp1, color=color.red)
pFibm1 = plot(Fibm1, color=color.lime)
pFibm2 = plot(Fibm2, color=color.lime)
fill(pFibp2,pFibp1, color.red)
fill(pFibm2,pFibm1, color.lime)
// -------------------------------------
// ------------ Positions --------------
// -------------------------------------
bull = crossunder(low[1],Fibm1[1]) and low[1]>=Fibm2[1] and low>Fibm2 and low<Fibm1 and sd>dev
bear = crossover(high[1],Fibp1[1]) and high[1]<=Fibp2[1] and high<Fibp2 and high>Fibp1 and sd>dev
//plotshape(bear, title='Bear', style=shape.triangledown, location=location.abovebar, color=color.red, offset=0)
//plotshape(bull, title='Bull', style=shape.triangleup, location=location.belowbar, color=color.green, offset=0)
// -------------------------------------
// --------- Strategy Orders -----------
// -------------------------------------
strategy.entry("Long", true, when = bull)
strategy.close("Long", when = crossover(high,VWAP) or crossunder(low,Fibm2))
strategy.entry("Short", false, when = bear)
strategy.close("Short", when = crossunder(low,VWAP) or crossover(high,Fibp2))