As bandas de Bollinger e a estratégia de combinação do RSI

Autora:ChaoZhang, Data: 2024-01-30 15:15:32
Tags:

Resumo

Esta estratégia combina as Bandas de Bollinger e o Índice de Força Relativa (RSI) para identificar oportunidades quando as Bandas de Bollinger estão a diminuir e o RSI está a aumentar, com um stop loss para controlar os riscos.

Estratégia lógica

A lógica central desta estratégia é identificar o aperto das Bandas de Bollinger e prever a quebra de preços quando o RSI está em tendência de alta. Especificamente, quando o desvio padrão da faixa média do BB de 20 períodos é menor que ATR * 2, determinamos que o aperto do BB está acontecendo; enquanto isso, se o RSI de 10 e 14 períodos estiver aumentando, prevemos que os preços possam ultrapassar a faixa superior do BB em breve e ficar compridos.

Após a entrada no mercado, usamos a distância de segurança ATR + stop loss adaptativo para bloquear o lucro e gerenciar riscos. As posições serão fechadas quando o preço atingir o stop loss ou o RSI ficar sobrecomprado (14-período RSI acima de 70 e 10-período RSI excede 14).

Análise das vantagens

A maior vantagem desta estratégia é identificar o período de consolidação com o aperto do BB e prever a direção de ruptura com o RSI. Além disso, o uso de stop loss adaptativo baseado na volatilidade do mercado em vez de stop loss fixo pode melhor bloquear o lucro enquanto controla o risco.

Análise de riscos

O principal risco desta estratégia é a identificação errada da pressão do BB e da tendência de alta do RSI, o que pode levar a uma falha de ruptura. Além disso, o stop loss adaptativo pode falhar em fechar posições em tempo hábil durante alta volatilidade.

Orientações de otimização

Esta estratégia pode ser melhorada nos seguintes aspectos:

Melhorar os parâmetros do BB para identificar a compressão com mais precisão
Teste diferentes valores para períodos do RSI
Examinar outras técnicas de stop loss como curva SL ou SL retrospectiva
Ajustar os parâmetros com base nas características do símbolo

Conclusão

Esta estratégia aproveita a complementaridade do BB e do RSI para alcançar bons retornos ajustados ao risco.

/*backtest
start: 2023-12-01 00:00:00
end: 2023-12-31 23:59:59
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © DojiEmoji
// 

//@version=4
strategy("[KL] BOLL + RSI Strategy",overlay=true,pyramiding=1)

// Timeframe {
backtest_timeframe_start = input(defval = timestamp("01 Apr 2016 13:30 +0000"), title = "Backtest Start Time", type = input.time)
USE_ENDTIME = input(false,title="Define backtest end-time (If false, will test up to most recent candle)")
backtest_timeframe_end = input(defval = timestamp("01 May 2021 19:30 +0000"), title = "Backtest End Time (if checked above)", type = input.time)
within_timeframe = true
// }

// Bollinger bands (sdv=2, len=20) {
BOLL_length = 20, BOLL_src = close, SMA20 = sma(BOLL_src, BOLL_length), BOLL_sDEV_x2 = 2 * stdev(BOLL_src, BOLL_length)
BOLL_upper = SMA20 + BOLL_sDEV_x2, BOLL_lower = SMA20 - BOLL_sDEV_x2
plot(SMA20, "Basis", color=#872323, offset = 0)
BOLL_p1 = plot(BOLL_upper, "BOLL Upper", color=color.navy, offset = 0, transp=50)
BOLL_p2 = plot(BOLL_lower, "BOLL Lower", color=color.navy, offset = 0, transp=50)
fill(BOLL_p1, BOLL_p2, title = "Background", color=#198787, transp=85)
// }

// Volatility Indicators {
ATR_x2 = atr(BOLL_length) * 2 // multiplier aligns with BOLL
avg_atr = sma(ATR_x2, input(1,title="No. of candles to lookback when determining ATR is decreasing"))
plot(SMA20+ATR_x2, "SMA20 + ATR_x2", color=color.gray, offset = 0, transp=50)
plot(SMA20-ATR_x2, "SMA20 - ATR_x2", color=color.gray, offset = 0, transp=50)
plotchar(ATR_x2, "ATR_x2", "", location = location.bottom)
//}

// Trailing stop loss {
TSL_source = low
var entry_price = float(0), var stop_loss_price = float(0)

trail_profit_line_color = color.green
if strategy.position_size == 0 or not within_timeframe
    trail_profit_line_color := color.black
    stop_loss_price := TSL_source - ATR_x2
else if strategy.position_size > 0
    stop_loss_price := max(stop_loss_price, TSL_source - ATR_x2)
plot(stop_loss_price, color=trail_profit_line_color)

if strategy.position_size > 0 and stop_loss_price > stop_loss_price[1]
	alert("Stop loss limit raised", alert.freq_once_per_bar)

// } end of Trailing stop loss

//Buy setup - Long positions {
is_squeezing = ATR_x2 > BOLL_sDEV_x2
if is_squeezing and within_timeframe and not is_squeezing[1]
	alert("BOLL bands are squeezing", alert.freq_once_per_bar)
else if not is_squeezing and within_timeframe and is_squeezing[1]
	alert("BOLL bands stopped squeezing", alert.freq_once_per_bar)

ema_trend = ema(close, 20)

concat(a, b) =>
	concat = a
	if a != ""
		concat := concat + ", "
	concat := concat + b
	concat
// }

// Sell setup - Long position {
rsi_10 = rsi(close, 10), rsi_14 = rsi(close, 14)
overbought = rsi_14 > input(70,title="[Exit] RSI(14) value considered as overbought") and rsi_10 > rsi_14
// } end of Sell setup - Long position

// MAIN: {
if within_timeframe
	entry_msg = ""
	exit_msg = ""

    // ENTRY {
	conf_count = 0	
    volat_decr = avg_atr <= avg_atr[1]
	rsi_upslope = rsi_10 > rsi_10[1] and rsi_14 > rsi_14[1]

	if volat_decr and rsi_upslope and is_squeezing and strategy.position_size == 0
		strategy.entry("Long",strategy.long, comment=entry_msg)
		entry_price := close
		stop_loss_price := TSL_source - ATR_x2
	// }

    // EXIT	{
	if strategy.position_size > 0
		bExit = false
		if close <= entry_price and TSL_source <= stop_loss_price
            exit_msg := concat(exit_msg, "stop loss [TSL]")
			bExit := true
        else if close > entry_price and TSL_source <= stop_loss_price
            exit_msg := concat(exit_msg, "take profit [TSL]")
            bExit := true
		else if overbought
			exit_msg := concat(exit_msg, "overbought")
			bExit := true

        strategy.close("Long", when=bExit, comment=exit_msg)
	// }
// }

// CLEAN UP:
if strategy.position_size == 0 and not is_squeezing
	entry_price := 0
	stop_loss_price := float(0)

Mais.