Estratégia de ruptura da DCCI

Autora:ChaoZhang, Data: 2024-02-18 10:13:21
Tags:

Resumo

A estratégia de ruptura do DCCI é uma estratégia de negociação de curto prazo que identifica situações de sobrevenda e sobrecompra usando o indicador CCI. Ele combina o indicador CCI e a linha média móvel WMA.

Estratégia lógica

A estratégia usa o indicador CCI para julgar as condições de sobrecompra/supervenda do mercado. O indicador CCI pode identificar efetivamente situações anormais de preços. Valores abaixo de -100 indicam que o mercado está sobrevendido, enquanto valores acima de 100 indicam que o mercado está sobrecomprado. A estratégia será longa quando o indicador CCI cruzar acima de -100 vindo de baixo; e será curta quando o indicador CCI cruzar abaixo de 100 vindo de cima.

Ao mesmo tempo, a estratégia também incorpora a linha média móvel WMA para determinar a direção da tendência. Somente quando o preço de fechamento estiver acima da linha WMA, os sinais longos serão válidos; somente quando o preço de fechamento estiver abaixo da linha WMA, os sinais curtos serão válidos. Isso ajuda a filtrar alguns sinais comerciais ambíguos.

Após a entrada de uma posição, a estratégia usa stop loss para controlar os riscos. Existem três métodos opcionais de stop loss: stop estratégia fixa, stop swing alto/baixo, stop ATR. Quando longa, a posição será interrompida se o preço cair para o nível de parada; quando curta, a posição será interrompida se o preço subir para o nível de parada.

Análise das vantagens

A estratégia apresenta as seguintes vantagens:

Captura oportunamente oportunidades de sobrevenda e de sobrecompra, identificando reversões utilizando o indicador CCI.
Evitar a negociação contra a tendência, incorporando a análise da direção da tendência utilizando médias móveis.
Fornece múltiplos métodos opcionais de stop loss que podem ser ajustados com base nas condições do mercado.
Sinais comerciais simples e claros que são fáceis de implementar.

Análise de riscos

A estratégia apresenta igualmente os seguintes riscos:

O indicador CCI pode facilmente gerar falsos sinais que não podem ser completamente evitados.
A colocação incorreta de um stop loss pode causar um excesso de stop out.
A incapacidade de identificar tendências significa que podem ser geradas demasiadas transacções desnecessárias em mercados variados.
A incapacidade de julgar a direcção geral do mercado pode resultar na negociação na direcção errada.

Para fazer face a estes riscos, as principais abordagens de otimização são:

Incorporar outros indicadores para filtrar os sinais CCI.
Otimizar a colocação da paragem através de backtesting.
Adicionar indicadores de identificação de tendências para evitar mercados agitados.
Determinar a direcção do comércio com base na análise das principais zonas de apoio e resistência.

Orientações de otimização

Os principais aspectos para a otimização desta estratégia incluem:

Optimização do parâmetro CCI: ajustar o período de revisão do CCI, otimizar os parâmetros do indicador.
Optimização de Stop Loss: teste diferentes métodos de stop e selecione o stop loss ideal.
Otimização de filtros: adicionar filtros adicionais como MACD, RSI para construir um sistema de filtragem de múltiplos indicadores para reduzir os falsos sinais.
Filtragem de tendências: adicionar indicadores de identificação de tendências, como médias móveis, para evitar negociações de contra-tendência.
Automática de lucro: Construir mecanismos dinâmicos de lucro para tirar lucros automaticamente com base na volatilidade do mercado.

Conclusão

Em geral, a Estratégia de Breakout DCCI é um sistema de negociação de curto prazo muito prático. Identifica situações de sobrecompra / sobrevenda usando o indicador CCI e incorpora a média móvel para viés direcional. O risco é gerenciado através de stop losses. Os sinais simples e claros tornam essa estratégia fácil de implementar para negociação de curto prazo.

/*backtest
start: 2023-02-11 00:00:00
end: 2023-09-20 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © tweakerID

// ---From the "Bitcoin Trading Strategies" book, by David Hanson---

// After testing, works better with an ATR stop instead of the Strategy Stop. This paramater
// can be changed from the strategy Inputs panel.

// "CCI Scalping Strategy
// Recommended Timeframe: 5 minutes
// Indicators: 20 Period CCI, 20 WMA
// Long when: Price closes above 20 WMA and CCI is below -100, enter when CCI crosses above -100.
// Stop: Above 20 WMA"

//@version=4
strategy("CCI Scalping Strat", 
     overlay=true, 
     default_qty_type=strategy.percent_of_equity, 
     default_qty_value=100, 
     initial_capital=10000, 
     commission_value=0.04, 
     calc_on_every_tick=false, 
     slippage=0)

direction = input(0, title = "Strategy Direction", type=input.integer, minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))

/////////////////////// STRATEGY INPUTS ////////////////////////////////////////
title1=input(true, "-----------------Strategy Inputs-------------------")  

i_Stop = input(0, step=.05, title="Strategy Stop Mult")*.01
i_CCI=input(16, title="CCI Length")
i_WMA=input(5, title="WMA Length")

/////////////////////// BACKTESTER /////////////////////////////////////////////
title2=input(true, "-----------------General Inputs-------------------")  

// Backtester General Inputs
i_SL=input(true, title="Use Stop Loss and Take Profit")
i_SLType=input(defval="ATR Stop", title="Type Of Stop", options=["Strategy Stop", "Swing Lo/Hi", "ATR Stop"])
i_SPL=input(defval=10, title="Swing Point Lookback")
i_PercIncrement=input(defval=2, step=.1, title="Swing Point SL Perc Increment")*0.01
i_ATR = input(14, title="ATR Length")
i_ATRMult = input(10, step=.1, title="ATR Multiple")
i_TPRRR = input(1.5, step=.1, title="Take Profit Risk Reward Ratio")

// Bought and Sold Boolean Signal
bought = strategy.position_size > strategy.position_size[1] 
 or strategy.position_size < strategy.position_size[1]

// Price Action Stop and Take Profit
LL=(lowest(i_SPL))*(1-i_PercIncrement)
HH=(highest(i_SPL))*(1+i_PercIncrement)
LL_price = valuewhen(bought, LL, 0)
HH_price = valuewhen(bought, HH, 0)
entry_LL_price = strategy.position_size > 0 ? LL_price : na 
entry_HH_price = strategy.position_size < 0 ? HH_price : na 
tp=strategy.position_avg_price + (strategy.position_avg_price - entry_LL_price)*i_TPRRR
stp=strategy.position_avg_price - (entry_HH_price - strategy.position_avg_price)*i_TPRRR

// ATR Stop
ATR=atr(i_ATR)*i_ATRMult
ATRLong = ohlc4 - ATR
ATRShort = ohlc4 + ATR
ATRLongStop = valuewhen(bought, ATRLong, 0)
ATRShortStop = valuewhen(bought, ATRShort, 0)
LongSL_ATR_price = strategy.position_size > 0 ? ATRLongStop : na 
ShortSL_ATR_price = strategy.position_size < 0 ? ATRShortStop : na 
ATRtp=strategy.position_avg_price + (strategy.position_avg_price - LongSL_ATR_price)*i_TPRRR
ATRstp=strategy.position_avg_price - (ShortSL_ATR_price - strategy.position_avg_price)*i_TPRRR

/////////////////////// STRATEGY LOGIC /////////////////////////////////////////

//CCI
CCI=cci(close, i_CCI)
//WMA
WMA=wma(close, i_WMA)

//Stops
LongStop=valuewhen(bought, WMA, 0)*(1-i_Stop)
ShortStop=valuewhen(bought, WMA, 0)*(1+i_Stop)
StratTP=strategy.position_avg_price + (strategy.position_avg_price - LongStop)*i_TPRRR
StratSTP=strategy.position_avg_price - (ShortStop - strategy.position_avg_price)*i_TPRRR

BUY = (close > WMA) and crossover(CCI , -100)
SELL = (close < WMA) and crossunder(CCI , 100)

//Trading Inputs
DPR=input(true, "Allow Direct Position Reverse")
reverse=input(false, "Reverse Trades")

// Entries
if reverse
    if not DPR
        strategy.entry("long", strategy.long, when=SELL and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=BUY and strategy.position_size == 0)
    else     
        strategy.entry("long", strategy.long, when=SELL)
        strategy.entry("short", strategy.short, when=BUY)
else
    if not DPR 
        strategy.entry("long", strategy.long, when=BUY and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=SELL and strategy.position_size == 0)
    else
        strategy.entry("long", strategy.long, when=BUY)
        strategy.entry("short", strategy.short, when=SELL)


SL= i_SLType == "Swing Lo/Hi" ? entry_LL_price : i_SLType == "ATR Stop" ? LongSL_ATR_price : LongStop
SSL= i_SLType == "Swing Lo/Hi" ? entry_HH_price : i_SLType == "ATR Stop" ? ShortSL_ATR_price : ShortStop
TP= i_SLType == "Swing Lo/Hi" ? tp : i_SLType == "ATR Stop" ? ATRtp : StratTP
STP= i_SLType == "Swing Lo/Hi" ? stp : i_SLType == "ATR Stop" ? ATRstp : StratSTP

strategy.exit("TP & SL", "long", limit=TP, stop=SL, when=i_SL)
strategy.exit("TP & SL", "short", limit=STP, stop=SSL, when=i_SL)

/////////////////////// PLOTS //////////////////////////////////////////////////


plot(WMA)
plot(i_SL and strategy.position_size > 0 ? SL : na , title='SL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size < 0 ? SSL : na , title='SSL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size > 0 ? TP : na, title='TP', style=plot.style_cross, color=color.green)
plot(i_SL and strategy.position_size < 0 ? STP : na, title='STP', style=plot.style_cross, color=color.green)
// Draw price action setup arrows
plotshape(BUY ? 1 : na, style=shape.triangleup, location=location.belowbar, 
 color=color.green, title="Bullish Setup", size=size.auto)
plotshape(SELL ? 1 : na, style=shape.triangledown, location=location.abovebar, 
 color=color.red, title="Bearish Setup", size=size.auto)

Mais.