Estratégia de Breakout SR

Data de criação: 2024-05-15 16:30:14 última modificação: 2024-05-15 16:30:14

cópia: 1 Cliques: 568

ChaoZhang

focar em Mensagem privada

focar em

1617

Seguidores

Estratégia de Breakout SR

Visão geral

A estratégia SR Breakout Strategy é uma estratégia de ruptura de resistência de suporte desenvolvida com base no indicador de breakout finder da LonesomeTheBlue. A principal idéia da estratégia é gerar um sinal de fazer ou fazer o que for necessário, julgando se o preço de fechamento quebrou o nível de suporte ou resistência. A configuração padrão é baseada na linha K de 8 horas, mas há uma configuração de parâmetros melhor na linha K de 4 horas.

Princípio da estratégia

Usando a função pivothigh e a função pivotlow, calcula-se respectivamente os pontos altos e baixos de um determinado período passado e são armazenados na matriz.
O preço de fechamento atual deve ser julgado acima da resistência e, se for, deve ser julgado como uma ruptura de pessimismo, gerando um sinal de aumento.
A avaliação de que o preço de fechamento atual está abaixo do nível de suporte, e se for, a avaliação de que o preço de fechamento está abaixo do nível de suporte, gerando um sinal de curto prazo.
Após a geração do sinal de negociação, o preço de parada e o preço de parada são calculados de acordo com a proporção de parada e parada definida e os respectivos pedidos de parada e de parada são definidos.
O correspondente intervalo de ruptura é traçado de acordo com a direção da ruptura.

Vantagens estratégicas

A quebra de resistência de suporte é uma estratégia de negociação clássica, com uma base de batalha.
O pivothigh e o pivotlow podem ser usados para calcular o suporte e a resistência.
A estrutura do código da estratégia é clara e pode ser facilmente rastreada e otimizada por armazenar os pontos altos e baixos em uma matriz.
A configuração de Stop Loss e Stop Stop permite um melhor controle de risco.

Risco estratégico

A estratégia de ruptura de resistência de suporte não funciona bem em situações de choque, sendo propensa a frequentes breakouts falsos.
A proporção fixa de stop loss pode não se adaptar a diferentes situações, levando a um desequilíbrio de risco-receita.
A estratégia leva em consideração apenas o fator preço, sem levar em conta outros indicadores importantes, como volume de negócios, podendo perder sinais importantes.

Direção de otimização da estratégia

Pode-se considerar a introdução de mais indicadores técnicos, como volume de transação, MACD, etc., para melhorar a precisão e a confiabilidade do sinal.
Para parar e parar, pode-se considerar o uso de parar móvel ou proporção de parar e parar dinâmico, para melhor se adaptar a diferentes situações.
Pode-se considerar a introdução de condições de filtragem, como filtragem de tendência, filtragem de taxa de flutuação, etc., para reduzir o falso breakout em situações de turbulência.
Pode-se considerar a otimização dos níveis de suporte e resistência, como o uso de ciclos de adaptação, a introdução de níveis de Fibonacci, etc.

Resumir

A estratégia de ruptura de SR é uma estratégia de negociação baseada na clássica ideia de ruptura de resistência de suporte, calculada com base nas funções de pivothigh e pivotlow para calcular a posição de suporte e resistência e gerar um sinal de negociação julgando se o preço de fechamento vai quebrar essas posições. A vantagem da estratégia reside na clareza da idéia, na facilidade de implementação e otimização.

Código-fonte da estratégia

/*backtest
start: 2024-05-07 00:00:00
end: 2024-05-14 00:00:00
period: 10m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © LonesomeTheBlue © chanu_lev10k

//@version=5
strategy('SR Breakout Strategy', overlay=true, max_bars_back=500, max_lines_count=400)
prd = input.int(defval=5, title='Period', minval=2)
bo_len = input.int(defval=71, title='Max Breakout Length', minval=30, maxval=300)
cwidthu = input.float(defval=3., title='Threshold Rate %', minval=1., maxval=10) / 100
mintest = input.int(defval=2, title='Minimum Number of Tests', minval=1)
bocolorup = input.color(defval=color.blue, title='Breakout Colors', inline='bocol')
bocolordown = input.color(defval=color.red, title='', inline='bocol')
// lstyle = input.string(defval=line.style_solid, title='Line Style')
issl = input.bool(title='SL', inline='linesl1', group='Stop Loss / Take Profit:', defval=false)
slpercent = input.float(title=', %', inline='linesl1', group='Stop Loss / Take Profit:', defval=18.0, minval=0.0, step=0.1)
istp = input.bool(title='TP', inline='linetp1', group='Stop Loss / Take Profit:', defval=false)
tppercent = input.float(title=', %', inline='linetp1', group='Stop Loss / Take Profit:', defval=18.0, minval=0.0, step=0.1)

//width
lll = math.max(math.min(bar_index, 300), 1)
float h_ = ta.highest(lll)
float l_ = ta.lowest(lll)
float chwidth = (h_ - l_) * cwidthu

// check if PH/PL
ph = ta.pivothigh(prd, prd)
pl = ta.pivotlow(prd, prd)

//keep Pivot Points and their locations in the arrays
var phval = array.new_float(0)
var phloc = array.new_int(0)
var plval = array.new_float(0)
var plloc = array.new_int(0)

// keep PH/PL levels and locations
if bool(ph)
    array.unshift(phval, ph)
    array.unshift(phloc, bar_index - prd)
    if array.size(phval) > 1  // cleanup old ones
        for x = array.size(phloc) - 1 to 1 by 1
            if bar_index - array.get(phloc, x) > bo_len
                array.pop(phloc)
                array.pop(phval)

if bool(pl)
    array.unshift(plval, pl)
    array.unshift(plloc, bar_index - prd)
    if array.size(plval) > 1  // cleanup old ones
        for x = array.size(plloc) - 1 to 1 by 1
            if bar_index - array.get(plloc, x) > bo_len
                array.pop(plloc)
                array.pop(plval)

// check bullish cup
float bomax = na
int bostart = bar_index
num = 0
hgst = ta.highest(prd)[1]
if array.size(phval) >= mintest and close > open and close > hgst
    bomax := array.get(phval, 0)
    xx = 0
    for x = 0 to array.size(phval) - 1 by 1
        if array.get(phval, x) >= close
            break
        xx := x
        bomax := math.max(bomax, array.get(phval, x))
        bomax
    if xx >= mintest and open <= bomax
        for x = 0 to xx by 1
            if array.get(phval, x) <= bomax and array.get(phval, x) >= bomax - chwidth
                num += 1
                bostart := array.get(phloc, x)
                bostart
        if num < mintest or hgst >= bomax
            bomax := na
            bomax

// if not na(bomax) and num >= mintest
//     line.new(x1=bar_index, y1=bomax, x2=bostart, y2=bomax, color=bocolorup)
//     line.new(x1=bar_index, y1=bomax - chwidth, x2=bostart, y2=bomax - chwidth, color=bocolorup)
//     line.new(x1=bostart, y1=bomax - chwidth, x2=bostart, y2=bomax, color=bocolorup)
//     line.new(x1=bar_index, y1=bomax - chwidth, x2=bar_index, y2=bomax, color=bocolorup)

plotshape(not na(bomax) and num >= mintest, location=location.belowbar, style=shape.triangleup, color=bocolorup, size=size.small)
//alertcondition(not na(bomax) and num >= mintest, title='Breakout', message='Breakout')

// check bearish cup
float bomin = na
bostart := bar_index
num1 = 0
lwst = ta.lowest(prd)[1]
if array.size(plval) >= mintest and close < open and close < lwst
    bomin := array.get(plval, 0)
    xx = 0
    for x = 0 to array.size(plval) - 1 by 1
        if array.get(plval, x) <= close
            break
        xx := x
        bomin := math.min(bomin, array.get(plval, x))
        bomin
    if xx >= mintest and open >= bomin
        for x = 0 to xx by 1
            if array.get(plval, x) >= bomin and array.get(plval, x) <= bomin + chwidth
                num1 += 1
                bostart := array.get(plloc, x)
                bostart
        if num1 < mintest or lwst <= bomin
            bomin := na
            bomin

// if not na(bomin) and num1 >= mintest
//     line.new(x1=bar_index, y1=bomin, x2=bostart, y2=bomin, color=bocolordown)
//     line.new(x1=bar_index, y1=bomin + chwidth, x2=bostart, y2=bomin + chwidth, color=bocolordown)
//     line.new(x1=bostart, y1=bomin + chwidth, x2=bostart, y2=bomin, color=bocolordown)
//     line.new(x1=bar_index, y1=bomin + chwidth, x2=bar_index, y2=bomin, color=bocolordown)

plotshape(not na(bomin) and num1 >= mintest, location=location.abovebar, style=shape.triangledown, color=bocolordown, size=size.small)

//alertcondition(not na(bomin) and num1 >= mintest, title='Breakdown', message='Breakdown')
//alertcondition(not na(bomax) and num >= mintest or not na(bomin) and num1 >= mintest, title='Breakout or Breakdown', message='Breakout or Breakdown')

// Long Short conditions
longCondition = not na(bomax) and num >= mintest
if longCondition
    strategy.entry('Long', strategy.long)
shortCondition = not na(bomin) and num1 >= mintest
if shortCondition
    strategy.entry('Short', strategy.short)

// Entry price / Take Profit / Stop Loss
//entryprice = strategy.position_avg_price
entryprice = ta.valuewhen(condition=longCondition or shortCondition, source=close, occurrence=0)
pm = longCondition ? 1 : shortCondition ? -1 : 1 / math.sign(strategy.position_size)
takeprofit = entryprice * (1 + pm * tppercent * 0.01)
stoploss = entryprice * (1 - pm * slpercent * 0.01)
strategy.exit(id='Exit Long', from_entry='Long', stop=issl ? stoploss : na, limit=istp ? takeprofit : na, alert_message='Exit Long')
strategy.exit(id='Exit Short', from_entry='Short', stop=issl ? stoploss : na, limit=istp ? takeprofit : na, alert_message='Exit Short')

Forums

PINE Language FAQ Summary MyLanguage Web3 About Us

Product

Robot Strategy Node Platforms Tickets

API

Syntax guide User guide Trading api Blockchain Indicator