Стратегия параболического стоп-лосса на основе индикатора ATR
ChaoZhang
Эта стратегия называется ATR-полиграфическая стоп-стратегия. Она использует ATR для корректировки скорости сжимания кривой стоп-полиграфической линии, чтобы она могла адаптироваться к изменениям волатильности рынка.
Ускорение остановки традиционной параллельной линии остается неизменным и не может справиться с ростом волатильности. Эта стратегия ускоряет скорость сокращения параллельной линии с увеличением значения ATR, чтобы при увеличении волатильности стоп-кривая могла быстрее приближаться к цене и эффективно контролировать риск.
В частности, после определения направления ценового тренда, стратегия рассчитывает адаптивный ускоритель на основе значения ATR и на основе этого рисует кривую парализованной остановки. Когда цена пробивается через линию остановки, выполняется остановка убытков.
Преимущество этой стратегии заключается в том, что традиционная параллельная стоп-линия позволяет динамически корректироваться в зависимости от рыночных колебаний. Однако параметры ATR требуют оптимизации, а стоп-линия слишком чувствительна и легко может быть прорвана.
В целом, самостоятельное предотвращение убытков важно для защиты прибыли и контроля риска. Трейдеры должны выбирать подходящие показатели предотвращения убытков в соответствии с рыночными условиями, а также тестировать и оптимизировать параметры, чтобы максимально использовать стратегию предотвращения убытков.
/*backtest
start: 2023-08-13 00:00:00
end: 2023-09-12 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=4
strategy(title="ATR Parabolic SAR Strategy [QuantNomad]", shorttitle="ATR PSAR Strategy [QN]", overlay=true, default_qty_type = strategy.percent_of_equity, default_qty_value = 100)
atr_length = input(14)
start = input(0.02)
increment = input(0.02)
maximum = input(0.2)
entry_bars = input(1, title = "Entry on Nth trend bar")
atr = atr(atr_length)
atr := na(atr) ? tr : atr
psar = 0.0 // PSAR
af = 0.0 // Acceleration Factor
trend_dir = 0 // Current direction of PSAR
ep = 0.0 // Extreme point
trend_bars = 0
sar_long_to_short = trend_dir[1] == 1 and close <= psar[1] // PSAR switches from long to short
sar_short_to_long = trend_dir[1] == -1 and close >= psar[1] // PSAR switches from short to long
trend_change = barstate.isfirst[1] or sar_long_to_short or sar_short_to_long
// Calculate trend direction
trend_dir := barstate.isfirst[1] and close[1] > open[1] ? 1 :
barstate.isfirst[1] and close[1] <= open[1] ? -1 :
sar_long_to_short ? -1 :
sar_short_to_long ? 1 : nz(trend_dir[1])
trend_bars := sar_long_to_short ? -1 :
sar_short_to_long ? 1 :
trend_dir == 1 ? nz(trend_bars[1]) + 1 :
trend_dir == -1 ? nz(trend_bars[1]) - 1 :
nz(trend_bars[1])
// Calculate Acceleration Factor
af := trend_change ? start :
(trend_dir == 1 and high > ep[1]) or
(trend_dir == -1 and low < ep[1]) ?
min(maximum, af[1] + increment) :
af[1]
// Calculate extreme point
ep := trend_change and trend_dir == 1 ? high :
trend_change and trend_dir == -1 ? low :
trend_dir == 1 ? max(ep[1], high) :
min(ep[1], low)
// Calculate PSAR
psar := barstate.isfirst[1] and close[1] > open[1] ? low[1] :
barstate.isfirst[1] and close[1] <= open[1] ? high[1] :
trend_change ? ep[1] :
trend_dir == 1 ? psar[1] + af * atr :
psar[1] - af * atr
plot(psar, style=plot.style_cross, color=trend_dir == 1 ? color.green : color.red, linewidth = 2)
// Strategy
strategy.entry("Long", true, when = trend_bars == entry_bars)
strategy.entry("Short", false, when = trend_bars == -entry_bars)