Стратегия торговли с прорывом в динамике

Автор:Чао Чжан, Дата: 2023-12-19 15:46:38
Тэги:

Обзор

Стратегия Momentum Breakout Trading - это стратегия, следующая за трендом, которая генерирует торговые сигналы путем обнаружения прорывов цен за пределами ключевых уровней поддержки / сопротивления.

Логика стратегии

Основным показателем этой стратегии является Дончианский канал. Дончианский канал состоит из самой высокой цены, самой низкой цены и средней цены в течение определенного периода. Верхняя и нижняя полосы канала соединяют самые высокие и самые низкие цены соответственно в течение обратного периода. Длинный сигнал генерируется, когда цена превышает верхнюю полосу, в то время как короткий сигнал генерируется при перерыве ниже нижней полосы, отражая сдвиги в рыночной динамике.

Передвижная средняя используется для оценки направления тренда.

В частности, условие входа состоит из следующего: цена выходит за пределы верхней полосы Дончианского канала И закрывается выше скользящей средней.

Стоп-лосс следует за нижней полосой Дончианского канала, что гарантирует, что стоп-лосс подстраивается выше вместе с трендом.

Анализ преимуществ

Эта стратегия эффективно сочетает в себе два индикатора для оценки направления тренда и импульса, избегая ошибочных сделок от ложных сигналов прорыва.

В частности, преимущества:

Дончианский канал динамически определяет ключевые уровни поддержки/сопротивления, определяя поворотные моменты тренда.
Движущаяся средняя отфильтровывает консолидацию, избегая ненужных сбоев.
Прохождение нижней полосы Дончянского канала позволяет максимизировать прибыль.
Разумные параметры обеспечивают гибкость в различных рыночных условиях.

Анализ рисков

Основные риски:

Риск неудачного выхода - цена не может поддерживать импульс после выхода выше верхней полосы.
Риск изменения тренда - цена изменяется до наступления остановки.
Риск оптимизации параметров - Неэффективные параметры приводят к переоценке или недостаточному количеству сигналов.

Для смягчения последствий следует учитывать такие факторы, как подтверждение объема, регулировка скользящей средней, разумные расстояния остановки.

Возможности для расширения

Дальнейшие оптимизации:

Добавьте фильтр громкости, чтобы обеспечить высокий импульс.
Оптимизировать периоды скользящей средней для характеристик прибора.
Механизм адаптивного стоп-лосса, основанный на динамике волатильности цен.
Механизм возобновления после первоначальной остановки для захвата дополнительных движений возобновления тренда.
Устойчивое тестирование на нескольких рынках для определения параметров по нюансам продукта.

Заключение

Стратегия трейдинга Momentum Breakout сочетает в себе индикаторы для эффективного измерения тренда и силы импульса, избегая распространенных проблем, с которыми сталкиваются системы тренда в отношении слепых входов.

/*backtest
start: 2022-12-12 00:00:00
end: 2023-12-18 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4

// Revision:        1
// Author:          @millerrh
// Strategy:  
//      Entry: Buy when Donchian Channel breaks out
//      Exit: Trail a stop with the lower Donchian Channel band
// Conditions/Variables:
//    1. Can add a filter to only take setups that are above a user-defined moving average (helps avoid trading counter trend) 
//    2. Manually configure which dates to back test
//    3. User-Configurable DC Channel length


// === CALL STRATEGY/STUDY, PROGRAMATICALLY ENTER STRATEGY PARAMETERS HERE SO YOU DON'T HAVE TO CHANGE THEM EVERY TIME YOU RUN A TEST ===
// (STRATEGY ONLY) - Comment out srategy() when in a study() 
strategy("Donchian Breakout", overlay=true, initial_capital=10000, currency='USD', 
   default_qty_type=strategy.percent_of_equity, default_qty_value=100, commission_type=strategy.commission.percent, commission_value=0.1)
// (STUDY ONLY) - Comment out study() when in a strategy() 
//study("Donchian Breakout", overlay=true)


// === BACKTEST RANGE ===
From_Year  = input(defval = 2019, title = "From Year")
From_Month = input(defval = 1, title = "From Month", minval = 1, maxval = 12)
From_Day   = input(defval = 1, title = "From Day", minval = 1, maxval = 31)
To_Year    = input(defval = 9999, title = "To Year")
To_Month   = input(defval = 1, title = "To Month", minval = 1, maxval = 12)
To_Day     = input(defval = 1, title = "To Day", minval = 1, maxval = 31)
Start  = timestamp(From_Year, From_Month, From_Day, 00, 00)  // backtest start window
Finish = timestamp(To_Year, To_Month, To_Day, 23, 59)        // backtest finish window

// == INPUTS ==
trigInput = input(title = "Execute Trades On...", defval = "Wick", options=["Wick","Close"]) // Useful for comparing standing stop orders vs. waiting for candle closes prior to action
stopTrail = input(title = "Trail Stops On...", defval = "ATR", options = ["ATR","Bottom of DC Channel","Midline of DC Channel","Tightest of ATR/Bot DC Channel"])
dcPeriod = input(title="DC period", type=input.integer, defval=20)

// === PLOT THE DONCHIAN CHANNEL ===
// Logic
dcUpper = highest(high, dcPeriod)
dcLower = lowest(low, dcPeriod)
dcMid = avg(dcUpper, dcLower)

// Plotting
dcUplot = plot(dcUpper, color=color.blue, linewidth=1, title="Upper Channel Line")
dcLplot = plot(dcLower, color=color.blue, linewidth=1, title="Lower Channel Line")
dcMidPlot = plot(dcMid, color=color.gray, linewidth=1, title="Mid-Line Average")
fill(dcUplot, dcLplot, color=color.gray, transp=90)

// == FILTERING ==
// Inputs
useMaFilter = input(title = "Use MA for Filtering?", type = input.bool, defval = true)
maType = input(defval="SMA", options=["EMA", "SMA"], title = "MA Type For Filtering")
maLength   = input(defval = 100, title = "MA Period for Filtering", minval = 1)

// Declare function to be able to swap out EMA/SMA
ma(maType, src, length) =>
    maType == "EMA" ? ema(src, length) : sma(src, length) //Ternary Operator (if maType equals EMA, then do ema calc, else do sma calc)
maFilter = ma(maType, close, maLength)
plot(maFilter, title = "Trend Filter MA", color = color.green, linewidth = 3, style = plot.style_line, transp = 50)

// Check to see if the useMaFilter check box is checked, this then inputs this conditional "maFilterCheck" variable into the strategy entry 
maFilterCheck = if useMaFilter == true
    maFilter
else
    0

// == ENTRY AND EXIT CRITERIA ==
// Trigger stop based on candle close or High/Low (i.e. Wick) - If doing daily timeframe, can do candle close.  Intraday should use wick.
trigResistance = trigInput == "Close" ? close : trigInput == "Wick" ? high : na
trigSupport = trigInput == "Close" ? close : trigInput == "Wick" ? low : na
buySignal = trigResistance >= dcUpper[1] // The [1] looks at the previous bar's value as it didn't seem to be triggering correctly without it (likely) DC moves with each bar
sellSignal = trigSupport <= dcLower[1]

buy = buySignal and dcUpper[1] > maFilterCheck // All these conditions need to be met to buy


// (STRATEGY ONLY) Comment out for Study
// This string of code enters and exits at the close
if (trigInput == "Close")
    strategy.entry("Long", strategy.long, when = buy)
    strategy.close("Long", when = sellSignal)

// This string of code enters and exits at the wick (i.e. with pre-set stops)
if (trigInput == "Wick")
    strategy.entry("Long", strategy.long, stop = dcUpper[1], when = time > Start and time < Finish and dcUpper[1] > maFilterCheck)
    strategy.exit("Exit Long", from_entry = "Long", stop = dcLower[1])

Больше