Количественная стратегия прорыва торговой цены

Автор:Чао Чжан, Дата: 2023-12-22 12:42:15
Тэги:

Обзор

Это краткосрочная количественная торговая стратегия, основанная на простой скользящей средней (SMA), экспоненциальной скользящей средней (EMA), каналах Келтнера, индикаторе MACD и стохастическом осцилляторе.

Принцип стратегии

Стратегия использует 25-периодическую SMA, 200-периодическую EMA для построения двойных линий скользящих средних. Когда цена проходит через двойные скользящие средние вверх, генерируется сигнал покупки. Когда цена проходит через двойные скользящие средние вниз, генерируется сигнал продажи.

В то же время эта стратегия использует 10-периодные каналы Келтнера. Прорыв верхней и нижней полос канала также служит вспомогательными сигналами. Индикатор MACD генерирует торговые сигналы с его быстрой линией, медленной линией и гистограммой. Стохастический осциллятор также формирует длинные и короткие сигналы с золотым крестом и мертвым крестом своей линии %K и линии %D.

В частности, когда цена закрытия выше как SMA, так и EMA, и в пределах каналов Келтнера, гистограмма MACD является отрицательной, а стохастический %K ниже 50, запускается сигнал длинного входа.

Преимущества стратегии

Использование двойной скользящей средней в сочетании с индикатором канала может эффективно фильтровать ложные прорывы.
Интеграция сигналов из нескольких технических показателей может повысить надежность.
Ясные длинные/короткие правила облегчают эффективность выполнения программ.
Подходит для высокочастотных количественных торговых стратегий.

Стратегические риски и оптимизация

Как краткосрочная стратегия торговли, она имеет высокие риски частоты торговли.
Не существует механизма стоп-лосса, что приводит к большим рискам потерь.
Подумайте о добавлении показателей волатильности для оптимизации условий входа и остановки потерь.
Различные периоды параметров могут быть протестированы для поиска оптимальных комбинаций.

Заключение

Эта стратегия объединяет четыре широко используемых технических индикатора - скользящие средние, канал, MACD и стохастический. Она определяет длинный / короткий на основе ценового прорыва, типичной краткосрочной количественной торговой стратегии. По сравнению со стратегией с одним индикатором, ее комбинация нескольких индикаторов улучшает точность сигнала и стоит дальнейшего тестирования и оптимизации.

/*backtest
start: 2022-12-15 00:00:00
end: 2023-12-21 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © exlux99

//@version=5
strategy(title="Scalping Trading System Crypto and Stocks", overlay=true)
src = input(low, title="Source")

//sma and ema
len = input.int(25, minval=1, title="Length SMA" , group="Moving Averages")
len2 = input.int(200, minval=1, title="Length EMA", group="Moving Averages")

out = ta.sma(src, len)
out2 = ta.ema(src, len2)


//keltner
lengthk = input.int(10, minval=1, title="Length Keltner Channel",group="Keltner")
mult = input(2.0, "Multiplier",group="Keltner")
BandsStyle = input.string("Average True Range", options = ["Average True Range", "True Range", "Range"], title="Bands Style",group="Keltner")
atrlength = input(14, "ATR Length",group="Keltner")

ma = ta.sma(src, lengthk)
rangema = BandsStyle == "True Range" ? ta.tr(true) : BandsStyle == "Average True Range" ? ta.atr(atrlength) : ta.rma(high - low, lengthk)
upper = ma + rangema * mult
lower = ma - rangema * mult

//stoch
periodK = input.int(10, title="%K Length", minval=1,group="Stochastic")
smoothK = input.int(1, title="%K Smoothing", minval=1,group="Stochastic")
periodD = input.int(1, title="%D Smoothing", minval=1,group="Stochastic")
k = ta.sma(ta.stoch(close, high, low, periodK), smoothK)
d = ta.sma(k, periodD)

//macd 1
fast_length = input(title="Fast Length MACD", defval=4,group="MACD Fast")
slow_length = input(title="Slow Length MACD", defval=34,group="MACD Fast")
signal_length = input.int(title="Signal Smoothing MACD",  minval = 1, maxval = 50, defval = 5,group="MACD Fast")
sma_source = input.string(title="Oscillator MA Type MACD",  defval="EMA", options=["SMA", "EMA"],group="MACD Fast")
sma_signal = input.string(title="Signal Line MA Type MACD", defval="EMA", options=["SMA", "EMA"],group="MACD Fast")

fast_ma = sma_source == "SMA" ? ta.sma(src, fast_length) : ta.ema(src, fast_length)
slow_ma = sma_source == "SMA" ? ta.sma(src, slow_length) : ta.ema(src, slow_length)
macd = fast_ma - slow_ma
signal = sma_signal == "SMA" ? ta.sma(macd, signal_length) : ta.ema(macd, signal_length)
hist = macd - signal




long= close > out and close < upper and close > lower and hist < 0 and k < 50 and close > out2 

short= close < out and close < upper and close > lower and hist > 0 and k > 50 and close < out2 

strategy.entry("long",strategy.long,when= long)

strategy.entry("short",strategy.short,when=short)

Больше