Адаптивная стратегия торговли интеллектуальными сетями

Автор:Чао Чжан, Дата: 2024-01-16 14:51:48
Тэги:

Обзор

Эта стратегия является адаптивной интеллектуальной сетевой торговой стратегией, основанной на платформе TradingView, написанной в Pine Script v4.

Логика стратегии

Ключевые особенности

Пирамида и управление деньгами:
- Разрешает до 14 дополнений в одном направлении (пирамидальные),
- Использует стратегию, основанную на денежных средствах, для управления размером позиций;
- Начальный капитал установлен в размере 100 долларов США для целей моделирования,
- За каждую сделку взимается небольшая комиссия в размере 0,1%.
Границы сетки:
- Пользователи могут использовать автоматически рассчитанные границы или вручную устанавливать верхнюю и нижнюю границы сетки,
- Автоматические ограничения могут быть получены либо из недавнего высокого и низкого уровня цены, либо из простой скользящей средней (SMA),
- Пользователи могут определить период обратного обзора для расчета границ и регулировать отклонение для расширения или сужения границ.
Линии сетки:
- Стратегия позволяет настраивать количество линий сети в пределах, с рекомендуемым диапазоном от 3 до 15,
- Линии сетки равномерно распределены между верхней и нижней границами.

Логика стратегии

Запись:
- Скрипт размещает ордера на покупку, когда цена опускается ниже сетевой линии, и никакой существующий ордер не связан с этой сетевой линией.
- Каждый объем ордера на покупку рассчитывается на основе начального капитала, деленного на количество линий сети, скорректированных на текущую цену.
Выход:
- Заказы продажи запускаются, когда цена поднимается выше линии сетки, при условии, что есть открытый заказ, соответствующий следующей нижней линии сетки.
Адаптивная решетка:
- Если установлена автоматическая граница, то сеть адаптируется к изменяющимся рыночным условиям путем перерасчета верхней и нижней границ и соответствующей корректировки сети.

Анализ преимуществ

Стратегия объединяет систематический характер и эффективное выполнение сетевой торговли. Разрешая пирамидирование и использование управления деньгами, можно эффективно контролировать риски. Автоадаптивная сетка подходит для различных рыночных условий.

Анализ рисков

Прорыв цен за пределы сети может привести к серьезным потерям. Параметры должны быть корректированы должным образом или объединены со стоп-лосом для контроля рисков. Кроме того, чрезмерная торговля увеличивает затраты на транзакции.

Руководство по оптимизации

Стоп-лосс также может помочь предотвратить риски от экстремальных рыночных движений.

Заключение

Эта стратегия систематически генерирует входы и выходы при управлении позициями. Благодаря настройке параметров она адаптируется к различным предпочтениям. Она сочетает в себе основанный на правилах характер сетевой торговли с гибкостью трендовой торговли, облегчая сложность операции при сохранении надежности.

/*backtest
start: 2024-01-08 00:00:00
end: 2024-01-15 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy("(IK) Grid Script", overlay=true, pyramiding=14, close_entries_rule="ANY", default_qty_type=strategy.cash, initial_capital=100.0, currency="USD", commission_type=strategy.commission.percent, commission_value=0.1)
i_autoBounds    = input(group="Grid Bounds", title="Use Auto Bounds?", defval=true, type=input.bool)                             // calculate upper and lower bound of the grid automatically? This will theorhetically be less profitable, but will certainly require less attention
i_boundSrc      = input(group="Grid Bounds", title="(Auto) Bound Source", defval="Hi & Low", options=["Hi & Low", "Average"])     // should bounds of the auto grid be calculated from recent High & Low, or from a Simple Moving Average
i_boundLookback = input(group="Grid Bounds", title="(Auto) Bound Lookback", defval=250, type=input.integer, maxval=500, minval=0) // when calculating auto grid bounds, how far back should we look for a High & Low, or what should the length be of our sma
i_boundDev      = input(group="Grid Bounds", title="(Auto) Bound Deviation", defval=0.10, type=input.float, maxval=1, minval=-1)  // if sourcing auto bounds from High & Low, this percentage will (positive) widen or (negative) narrow the bound limits. If sourcing from Average, this is the deviation (up and down) from the sma, and CANNOT be negative.
i_upperBound    = input(group="Grid Bounds", title="(Manual) Upper Boundry", defval=0.285, type=input.float)                      // for manual grid bounds only. The upperbound price of your grid
i_lowerBound    = input(group="Grid Bounds", title="(Manual) Lower Boundry", defval=0.225, type=input.float)                      // for manual grid bounds only. The lowerbound price of your grid.
i_gridQty       = input(group="Grid Lines",  title="Grid Line Quantity", defval=8, maxval=15, minval=3, type=input.integer)       // how many grid lines are in your grid

f_getGridBounds(_bs, _bl, _bd, _up) =>
    if _bs == "Hi & Low"
        _up ? highest(close, _bl) * (1 + _bd) : lowest(close, _bl)  * (1 - _bd)
    else
        avg = sma(close, _bl)
        _up ? avg * (1 + _bd) : avg * (1 - _bd)

f_buildGrid(_lb, _gw, _gq) =>
    gridArr = array.new_float(0)
    for i=0 to _gq-1
        array.push(gridArr, _lb+(_gw*i))
    gridArr

f_getNearGridLines(_gridArr, _price) =>
    arr = array.new_int(3)
    for i = 0 to array.size(_gridArr)-1
        if array.get(_gridArr, i) > _price
            array.set(arr, 0, i == array.size(_gridArr)-1 ? i : i+1)
            array.set(arr, 1, i == 0 ? i : i-1)
            break
    arr

var upperBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true) : i_upperBound  // upperbound of our grid
var lowerBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false) : i_lowerBound // lowerbound of our grid
var gridWidth       = (upperBound - lowerBound)/(i_gridQty-1)                                                       // space between lines in our grid
var gridLineArr     = f_buildGrid(lowerBound, gridWidth, i_gridQty)                                                 // an array of prices that correspond to our grid lines
var orderArr        = array.new_bool(i_gridQty, false)                                                              // a boolean array that indicates if there is an open order corresponding to each grid line

var closeLineArr    = f_getNearGridLines(gridLineArr, close)                                                        // for plotting purposes - an array of 2 indices that correspond to grid lines near price
var nearTopGridLine = array.get(closeLineArr, 0)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line above current price
var nearBotGridLine = array.get(closeLineArr, 1)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line below current price
strategy.initial_capital = 50000
for i = 0 to (array.size(gridLineArr) - 1)
    if close < array.get(gridLineArr, i) and not array.get(orderArr, i) and i < (array.size(gridLineArr) - 1)
        buyId = i
        array.set(orderArr, buyId, true)
        strategy.entry(id=tostring(buyId), long=true, qty=(strategy.initial_capital/(i_gridQty-1))/close, comment="#"+tostring(buyId))
    if close > array.get(gridLineArr, i) and i != 0
        if array.get(orderArr, i-1)
            sellId = i-1
            array.set(orderArr, sellId, false)
            strategy.close(id=tostring(sellId), comment="#"+tostring(sellId))

if i_autoBounds
    upperBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true)
    lowerBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false)
    gridWidth   := (upperBound - lowerBound)/(i_gridQty-1)
    gridLineArr := f_buildGrid(lowerBound, gridWidth, i_gridQty)

closeLineArr    := f_getNearGridLines(gridLineArr, close)
nearTopGridLine := array.get(closeLineArr, 0)
nearBotGridLine := array.get(closeLineArr, 1)

Больше