Динамическая сетевая стратегия торговли

Автор:Чао Чжан, Дата: 2024-01-23 10:53:05
Тэги:

Обзор

Эта стратегия реализует сетевую торговлю путем размещения нескольких параллельных ордеров на покупку и продажу в пределах ценового диапазона.

Логика стратегии

Установите верхние и нижние границы сети, которые могут быть настроены вручную или автоматически рассчитаны на основе последних высоких и низких цен.
Вычислить ширину интервала сетки в соответствии с указанным количеством линий сетки.
Создать массив цен на сетевые линии с соответствующим количеством.
Когда цена опускается ниже линии сетки, открыть длинный заказ ниже нее; когда цена повышается выше линии сетки, закрыть короткий заказ выше нее.
Динамически корректировать границы, ширину интервалов и цены на линии сети для адаптации стратегии к изменениям рынка.

Анализ преимуществ

Могут стабильно получать прибыль на рынке с ограниченным диапазоном и волатильностью, независимо от направления тренда.
Поддерживает как ручные, так и автоматические настройки параметров для сильной адаптивности.
Оптимизируемые параметры, такие как количество сетки, ширина интервала и размер заказа для лучшей награды.
Встроенное управление положением для снижения риска.
Динамическая регулировка диапазона сетки повышает адаптивность.

Анализ рисков

В условиях сильного тренда на рынке могут возникнуть серьезные потери.
Неправильные настройки количества и положения сетки могут увеличить риск.
Автоматически рассчитанный диапазон сетки может потерпеть неудачу при экстремальных колебаниях цен.

Управление рисками:

Оптимизируйте параметры сетки и строго контролируйте общую позицию.
Закройте стратегию до значительного движения цены.
Судите о состоянии рынка с помощью индикаторов тренда, при необходимости используйте стратегию.

Руководство по оптимизации

Выберите оптимальное количество сети на основе характера рынка и масштаба капитала.
Проверьте разные периоды для оптимизации параметров авто.
Оптимизировать расчет размеров заказов для более стабильной награды.
Добавить индикаторы для определения тенденции и стратегических условий закрытия.

Резюме

Динамическая стратегия торговли сеткой адаптируется к рынку путем корректировки параметров сети. Она приносит прибыль на рынке с ограниченным диапазоном и волатильностью. При правильном контроле позиций риск смягчается. Оптимизация настроек сети и включение индикаторов оценки тренда могут еще больше улучшить стабильность стратегии.

/*backtest
start: 2023-12-23 00:00:00
end: 2024-01-22 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
strategy("sarasa srinivasa kumar", overlay=true, pyramiding=14, close_entries_rule="ANY", default_qty_type=strategy.cash, initial_capital=100.0, currency="USD", commission_type=strategy.commission.percent, commission_value=0.1)
i_autoBounds    = input(group="Grid Bounds", title="Use Auto Bounds?", defval=true, type=input.bool)                             // calculate upper and lower bound of the grid automatically? This will theorhetically be less profitable, but will certainly require less attention
i_boundSrc      = input(group="Grid Bounds", title="(Auto) Bound Source", defval="Hi & Low", options=["Hi & Low", "Average"])     // should bounds of the auto grid be calculated from recent High & Low, or from a Simple Moving Average
i_boundLookback = input(group="Grid Bounds", title="(Auto) Bound Lookback", defval=250, type=input.integer, maxval=500, minval=0) // when calculating auto grid bounds, how far back should we look for a High & Low, or what should the length be of our sma
i_boundDev      = input(group="Grid Bounds", title="(Auto) Bound Deviation", defval=0.10, type=input.float, maxval=1, minval=-1)  // if sourcing auto bounds from High & Low, this percentage will (positive) widen or (negative) narrow the bound limits. If sourcing from Average, this is the deviation (up and down) from the sma, and CANNOT be negative.
i_upperBound    = input(group="Grid Bounds", title="(Auto) Upper Boundry", defval=0.285, type=input.float)                      // for manual grid bounds only. The upperbound price of your grid
i_lowerBound    = input(group="Grid Bounds", title="(Auto) Lower Boundry", defval=0.225, type=input.float)                      // for manual grid bounds only. The lowerbound price of your grid.
i_gridQty       = input(group="Grid Lines",  title="Grid Line Quantity", defval=8, maxval=15, minval=3, type=input.integer)       // how many grid lines are in your grid

f_getGridBounds(_bs, _bl, _bd, _up) =>
    if _bs == "Hi & Low"
        _up ? highest(close, _bl) * (1 + _bd) : lowest(close, _bl)  * (1 - _bd)
    else
        avg = sma(close, _bl)
        _up ? avg * (1 + _bd) : avg * (1 - _bd)

f_buildGrid(_lb, _gw, _gq) =>
    gridArr = array.new_float(0)
    for i=0 to _gq-1
        array.push(gridArr, _lb+(_gw*i))
    gridArr

f_getNearGridLines(_gridArr, _price) =>
    arr = array.new_int(3)
    for i = 0 to array.size(_gridArr)-1
        if array.get(_gridArr, i) > _price
            array.set(arr, 0, i == array.size(_gridArr)-1 ? i : i+1)
            array.set(arr, 1, i == 0 ? i : i-1)
            break
    arr

var upperBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true) : i_upperBound  // upperbound of our grid
var lowerBound      = i_autoBounds ? f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false) : i_lowerBound // lowerbound of our grid
var gridWidth       = (upperBound - lowerBound)/(i_gridQty-1)                                                       // space between lines in our grid
var gridLineArr     = f_buildGrid(lowerBound, gridWidth, i_gridQty)                                                 // an array of prices that correspond to our grid lines
var orderArr        = array.new_bool(i_gridQty, false)                                                              // a boolean array that indicates if there is an open order corresponding to each grid line

var closeLineArr    = f_getNearGridLines(gridLineArr, close)                                                        // for plotting purposes - an array of 2 indices that correspond to grid lines near price
var nearTopGridLine = array.get(closeLineArr, 0)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line above current price
var nearBotGridLine = array.get(closeLineArr, 1)                                                                    // for plotting purposes - the index (in our grid line array) of the closest grid line below current price
strategy.initial_capital = 50000
for i = 0 to (array.size(gridLineArr) - 1)
    if close < array.get(gridLineArr, i) and not array.get(orderArr, i) and i < (array.size(gridLineArr) - 1)
        buyId = i
        array.set(orderArr, buyId, true)
        strategy.entry(id=tostring(buyId), long=true, qty=(strategy.initial_capital/(i_gridQty-1))/close, comment="#"+tostring(buyId))
    if close > array.get(gridLineArr, i) and i != 0
        if array.get(orderArr, i-1)
            sellId = i-1
            array.set(orderArr, sellId, false)
            strategy.close(id=tostring(sellId), comment="#"+tostring(sellId))

if i_autoBounds
    upperBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, true)
    lowerBound  := f_getGridBounds(i_boundSrc, i_boundLookback, i_boundDev, false)
    gridWidth   := (upperBound - lowerBound)/(i_gridQty-1)
    gridLineArr := f_buildGrid(lowerBound, gridWidth, i_gridQty)

closeLineArr    := f_getNearGridLines(gridLineArr, close)
nearTopGridLine := array.get(closeLineArr, 0)
nearBotGridLine := array.get(closeLineArr, 1)

Больше