اسٹوکاسٹک آر ایس آئی حکمت عملی کے ساتھ 3EMA

مصنف:چاؤ ژانگ، تاریخ: 2023-11-15 10:47:20
ٹیگز:

جائزہ

یہ ایک رجحان کی پیروی کرنے والی حکمت عملی ہے جس میں متعدد اشارے ملتے ہیں۔ یہ رجحان کی سمت کی نشاندہی کرنے اور پوزیشنوں کو قائم کرنے کے لئے مختلف ادوار ، اسٹوکاسٹک آر ایس آئی اور اے ٹی آر کے ساتھ تین ای ایم اے کا استعمال کرتا ہے۔ جب تیز ای ایم اے سست ای ایم اے سے تجاوز کرتا ہے تو یہ طویل ہوجاتا ہے ، اسٹاپ نقصان حالیہ اے ٹی آر ویلیو کے 3 گنا مقرر ہوتا ہے اور حالیہ اے ٹی آر کے 2 گنا منافع لیتا ہے۔

اصول

اس حکمت عملی میں تین ای ایم اے لائنیں استعمال کی جاتی ہیں - 8 ، 14 اور 50 پیریڈ ای ایم اے ، جو مختلف ٹائم فریموں میں قیمت کے رجحانات کی نمائندگی کرتی ہیں۔ جب 8 پیریڈ ای ایم اے 14 پیریڈ ای ایم اے سے اوپر کی حد کو عبور کرتا ہے ، اور 14 پیریڈ ای ایم اے 50 پیریڈ ای ایم اے سے اوپر کی حد کو عبور کرتا ہے ، تو یہ ایک اپ ٹرینڈ کے آغاز کی نشاندہی کرتا ہے اور ایک لمبی پوزیشن شروع کی جاسکتی ہے۔

اسٹوکاسٹک آر ایس آئی اشارے میں اوور بک / اوور سیلڈ حالات کی نشاندہی کرنے کے لئے آر ایس آئی اور اسٹوکاسٹک حساب کتاب شامل ہیں۔ جب اسٹوکاسٹک آر ایس آئی کی لائن نیچے سے ڈی لائن سے اوپر سے عبور کرتی ہے تو ، اس سے یہ ظاہر ہوتا ہے کہ مارکیٹ اوور سیلڈ سے تیزی کی پیش گوئی میں منتقل ہو رہی ہے ، جس سے طویل پوزیشن کی اجازت ملتی ہے۔

اے ٹی آر حالیہ اتار چڑھاؤ کی حد کی نمائندگی کرتا ہے۔ حکمت عملی منافع میں مقفل کرنے اور خطرے کو کنٹرول کرنے کے لئے 3 بار اے ٹی آر کو اسٹاپ نقصان کی دوری اور 2 بار اے ٹی آر کو منافع کی دوری کے طور پر استعمال کرتی ہے۔

فوائد

ای ایم اے قیمت کے اعداد و شمار میں شور کو فلٹر کرتی ہے اور رجحان کی سمت کی نشاندہی کرتی ہے
اسٹوکاسٹک آر ایس آئی الٹ جانے کے مواقع کی نشاندہی کرتا ہے
اے ٹی آر متحرک طور پر مارکیٹ کی اتار چڑھاؤ کی بنیاد پر نقصان کو روکنے / منافع حاصل کرنے کی پیروی کرتا ہے

خطرات

متعدد اشارے متضاد سگنل پیدا کرسکتے ہیں
فکسڈ سٹاپ نقصان / منافع حاصل کرنے کے تناسب کو تبدیل مارکیٹ کے حالات کے مطابق نہیں کیا جا سکتا
مختصر مدت کے طویل عرصے تک واپسی کے لئے حساس

حساسیت کو بہتر بنانے کے لئے ای ایم اے کے ادوار کو ایڈجسٹ کرکے اصلاح کی جاسکتی ہے۔ اے ٹی آر تناسب کو ایڈجسٹ کرنے سے مارکیٹ کے حالات کی بنیاد پر تخصیص کی اجازت ملتی ہے۔ دوسرے اشارے شامل کرنے سے سگنل کی توثیق اور غلطیوں سے بچنے میں مدد ملتی ہے۔

بہتری

حساسیت کو بہتر بنانے کے لئے EMA ادوار کو ایڈجسٹ کریں
اے ٹی آر تناسب کو سایڈست بنائیں
غلط سگنل سے بچنے کے لئے دیگر اشارے شامل کریں

نتیجہ

حکمت عملی میں رجحان ، زیادہ خرید / زیادہ فروخت کی سطح ، اور اتار چڑھاؤ کی حد پر غور کیا جاتا ہے تاکہ انٹری ٹائمنگ کی نشاندہی کی جاسکے۔ ای ایم اے اور اسٹوکاسٹک آر ایس آئی مل کر مؤثر طریقے سے رجحانات کی نشاندہی کرتے ہیں ، جبکہ اے ٹی آر کی متحرک اسٹاپ نقصان / منافع لینے سے رسک کنٹرول میں مدد ملتی ہے۔ پیرامیٹر ٹیوننگ اور اصلاحات کے ساتھ ، حکمت عملی ایک قابل اعتماد رجحان مندرجہ ذیل نظام بن سکتی ہے۔ لیکن غلط سگنل اور فکسڈ اسٹاپ نقصان / منافع لینے کے انتباہات پر محتاط رہنے کی ضرورت ہے۔

/*backtest
start: 2023-10-15 00:00:00
end: 2023-11-14 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © FreddieChopin
 
//@version=4
strategy("3 x EMA + Stochastic RSI + ATR", overlay = true, default_qty_type = strategy.percent_of_equity, default_qty_value = 100)
 
// 3x EMA
ema1Length = input(8, "EMA1 Length", minval = 1)
ema2Length = input(14, "EMA2 Length", minval = 1)
ema3Length = input(50, "EMA3 Length", minval = 1)
ema1 = ema(close, ema1Length)
ema2 = ema(close, ema2Length)
ema3 = ema(close, ema3Length)
 
plot(ema1, color = color.green)
plot(ema2, color = color.orange)
plot(ema3, color = color.red)
 
// Stochastic RSI
smoothK = input(3, "K", minval=1)
smoothD = input(3, "D", minval=1)
lengthRSI = input(14, "RSI Length", minval=1)
lengthStoch = input(14, "Stochastic Length", minval=1)
src = input(close, title="RSI Source")
rsi1 = rsi(src, lengthRSI)
k = sma(stoch(rsi1, rsi1, rsi1, lengthStoch), smoothK)
d = sma(k, smoothD)
 
// ATR
atrPeriod = input(14, "ATR Period")
takeProfitMultiplier= input(2.0, "Take-profit Multiplier")
stopLossMultiplier= input(3.0, "Stop-loss Multiplier")
atrSeries = atr(atrPeriod)[1]
 
longCondition = ema1 > ema2 and ema2 > ema3 and crossover(k, d)
strategy.entry("long", strategy.long, when = longCondition)
 
float stopLoss = na
float takeProfit = na
 
if (strategy.position_size > 0)
    if (na(stopLoss[1]))
        stopLoss := strategy.position_avg_price - atrSeries * stopLossMultiplier
    else
        stopLoss := stopLoss[1]
    if (na(takeProfit[1]))
        takeProfit := strategy.position_avg_price + atrSeries * takeProfitMultiplier
    else
        takeProfit := takeProfit[1]
 
    strategy.exit("take profit / stop loss", limit = takeProfit, stop = stopLoss)
 
plot(stopLoss, color = color.red, linewidth = 2, style = plot.style_linebr)
plot(takeProfit, color = color.green, linewidth = 2, style = plot.style_linebr)

مزید

2019 FMZ - تمام حقوق محفوظ ہیں