1. مربع
  2. EMA-MACD-SuperTrend-ADX-ATR کثیر اشارے ٹریڈنگ سگنل کی حکمت عملی

EMA-MACD-SuperTrend-ADX-ATR کثیر اشارے ٹریڈنگ سگنل کی حکمت عملی

مصنف:چاؤ ژانگ، تاریخ: 2024-03-29 15:41:29
ٹیگز:

img

جائزہ

یہ حکمت عملی متعدد تکنیکی اشارے کو جوڑتی ہے ، بشمول ایکسپونینشل موونگ ایوریج (ای ایم اے) ، موونگ ایوریج کنورجنس ڈائیورجنس (ایم اے سی ڈی) ، سپر ٹرینڈ ، اوسط سمت کا انڈیکس (اے ڈی ایکس) ، اور اوسط حقیقی رینج (اے ٹی آر) ، تاکہ مارکیٹ کے رجحانات ، اتار چڑھاؤ اور تجارتی سگنل کا تعین کیا جاسکے ، جس کا مقصد کریپٹوکرنسی ٹریڈنگ میں مضبوط منافع حاصل کرنا ہے۔ یہ حکمت عملی مختلف اشارے کی طاقتوں کا فائدہ اٹھاتی ہے تاکہ رجحان کی نشاندہی ، اتار چڑھاؤ کا تعین ، اور رسک کنٹرول کو متوازن بنایا جاسکے ، جس سے تاجروں کے لئے قابل اعتماد تجارتی سگنل فراہم کیے جائیں۔

حکمت عملی کا اصول

  1. 12 روزہ اور 26 روزہ ای ایم اے کے کراس اوور کو رجحان کے تعین کی بنیاد کے طور پر استعمال کیا جاتا ہے۔ جب 12 روزہ ای ایم اے 26 روزہ ای ایم اے سے اوپر جاتا ہے تو ، یہ ایک اپ ٹرینڈ کی نشاندہی کرتا ہے؛ اس کے برعکس ، یہ ایک ڈاؤن ٹرینڈ کی نشاندہی کرتا ہے۔
  2. ایم اے سی ڈی اشارے کو معاون فیصلے کے طور پر استعمال کیا جاتا ہے۔ جب ایم اے سی ڈی ہسٹوگرام 0 سے اوپر ہوتا ہے تو ، ای ایم اے بولش سگنل کے ساتھ مل کر ، ایک لمبی پوزیشن کھولی جاتی ہے۔ جب ایم اے سی ڈی ہسٹوگرام 0 سے نیچے ہوتا ہے ، ای ایم اے bearish سگنل کے ساتھ مل کر ، ایک مختصر پوزیشن کھولی جاتی ہے۔
  3. اے ڈی ایکس اشارے کا استعمال اس بات کا تعین کرنے کے لئے کیا جاتا ہے کہ آیا مارکیٹ رجحان کی حالت میں ہے۔ جب اے ڈی ایکس 15 سے اوپر ہوتا ہے تو ، مارکیٹ کو رجحان کے مرحلے میں سمجھا جاتا ہے۔
  4. اے ٹی آر اشارے کا استعمال مارکیٹ کی اتار چڑھاؤ کا اندازہ کرنے کے لئے کیا جاتا ہے۔ جب اے ٹی آر 20 دن کے اے ٹی آر سے 0.5 گنا زیادہ ہوتا ہے تو ، مارکیٹ کو اعلی اتار چڑھاؤ کی حالت میں سمجھا جاتا ہے۔
  5. سپر ٹرینڈ اشارے کو اسٹاپ نقصان کی شرط کے طور پر متعارف کرایا گیا ہے۔ جب قیمت سپر ٹرینڈ سے نیچے آجاتی ہے تو ، لمبی پوزیشنیں بند ہوجاتی ہیں ، اور جب قیمت سپر ٹرینڈ سے اوپر ٹوٹ جاتی ہے تو ، مختصر پوزیشنیں بند ہوجاتی ہیں۔
  6. جب ای ایم اے ، ایم اے سی ڈی ، اے ڈی ایکس ، اور اے ٹی آر کی شرائط پوری ہوجاتی ہیں تو ، صعودی یا bearish سگنلز کی بنیاد پر پوزیشنیں کھولی جاتی ہیں۔ جب سپر ٹرینڈ اسٹاپ نقصان کی شرط کو متحرک کیا جاتا ہے تو ، پوزیشنیں بند کردی جاتی ہیں۔

حکمت عملی کے فوائد

  1. کثیر اشارے کا امتزاج: حکمت عملی میں متعدد تکنیکی اشارے شامل ہیں تاکہ مارکیٹ کو مختلف جہتوں سے تجزیہ کیا جاسکے ، بشمول رجحان ، نوسٹالیشن ، اور رسک کنٹرول ، جس سے تجارتی سگنلز کی وشوسنییتا میں اضافہ ہوتا ہے۔
  2. رجحان کی نشاندہی: ای ایم اے اور ایم اے سی ڈی کو یکجا کرکے، حکمت عملی مؤثر طریقے سے مارکیٹ کے رجحان کی سمت کا تعین کر سکتی ہے، جس سے تجارتی فیصلوں کی بنیاد فراہم ہوتی ہے۔
  3. خطرے کا کنٹرول: ADX اور ATR اشارے متعارف کرانے سے مارکیٹ کی رجحان کی طاقت اور اتار چڑھاؤ کا اندازہ کرنے میں مدد ملتی ہے ، جس سے تجارتی خطرات کو ایک خاص حد تک کنٹرول کیا جاتا ہے۔
  4. اسٹاپ نقصان کا طریقہ کار: سپر ٹرینڈ اشارے کو اسٹاپ نقصان کی شرط کے طور پر استعمال کرنا مؤثر طریقے سے ایک ہی تجارت کے زیادہ سے زیادہ نقصان کو محدود کرتا ہے ، جس سے تجارتی سرمایہ کی حفاظت ہوتی ہے۔
  5. پیرامیٹرز کی لچک: حکمت عملی میں اشارے کے پیرامیٹرز کو مختلف مارکیٹ کے حالات اور تجارتی آلات کے مطابق لچکدار طریقے سے ایڈجسٹ کیا جاسکتا ہے تاکہ مارکیٹ کے بدلتے ہوئے ماحول کو اپنایا جاسکے۔

حکمت عملی کے خطرات

  1. پیرامیٹر کی اصلاح: حکمت عملی میں متعدد اشارے اور پیرامیٹرز شامل ہیں ، جیسے ای ایم اے ادوار ، ایم اے سی ڈی پیرامیٹرز ، اور اے ڈی ایکس کی حدیں۔ ان پیرامیٹرز کا انتخاب حکمت عملی کی کارکردگی پر نمایاں اثر ڈالتا ہے اور اس میں تکرار پیرامیٹر کی اصلاح اور ڈیبگنگ کی ضرورت ہوتی ہے۔
  2. مارکیٹ کی موافقت: حکمت عملی کچھ مارکیٹ کے حالات میں کم کارکردگی کا مظاہرہ کرسکتی ہے ، جیسے رینج سے منسلک مارکیٹ یا رجحان کے الٹ پوائنٹس ، جہاں حکمت عملی سے غلط تجارتی سگنل پیدا ہوسکتے ہیں۔
  3. سلائیپ اور تجارتی اخراجات: انتہائی اتار چڑھاؤ والے بازاروں میں ، حکمت عملی سے تجارتی سگنل کثرت سے پیدا ہوسکتے ہیں ، جس سے سلائیپ اور تجارتی اخراجات میں اضافہ ہوتا ہے ، جو حکمت عملی کی منافع کو متاثر کرتا ہے۔
  4. بیک ٹیسٹنگ کی حدود: حکمت عملی کے بیک ٹیسٹنگ کے نتائج میں کچھ حدود ہوسکتی ہیں۔ اصل مارکیٹ کے حالات تاریخی اعداد و شمار سے مختلف ہوسکتے ہیں ، اور براہ راست تجارت میں حکمت عملی کی کارکردگی بیک ٹیسٹنگ کے نتائج سے پوری طرح مطابقت نہیں رکھ سکتی ہے۔

حکمت عملی کی اصلاح کی ہدایات

  1. متحرک پیرامیٹر کی اصلاح: حکمت عملی کی موافقت اور استحکام کو بہتر بنانے کے لئے مارکیٹ کے مختلف حالات اور تجارتی آلات کے لئے حکمت عملی میں کلیدی پیرامیٹرز کو متحرک طور پر بہتر بنائیں۔
  2. مارکیٹ کے جذبات کے اشارے شامل کرنا: موجودہ اشارے کے علاوہ ، مارکیٹ کے جذبات کی عکاسی کرنے والے اشارے متعارف کروائیں ، جیسے Volatility Index (VIX) ، تاکہ مارکیٹ کے جذبات کا مقداری تجزیہ کیا جاسکے اور تجارتی فیصلوں میں مدد ملے۔
  3. اسٹاپ نقصان کا بہتر طریقہ کار: سپر ٹرینڈ اسٹاپ نقصان کے علاوہ اضافی اسٹاپ نقصان کے طریقوں ، جیسے ٹریلنگ اسٹاپ یا فیصد پر مبنی اسٹاپ متعارف کرانے کے ذریعہ اسٹاپ نقصان کی لچک اور تاثیر کو بڑھانا۔
  4. پوزیشن سائزنگ کی اصلاح: مارکیٹ کے رجحان کی طاقت اور اتار چڑھاؤ جیسے عوامل کی بنیاد پر پوزیشن کے سائز کو متحرک طور پر ایڈجسٹ کریں۔ جب رجحانات واضح ہوں تو پوزیشن کے سائز میں اضافہ کریں اور دارالحکومت کی کارکردگی کو بہتر بنانے کے لئے رینج سے منسلک مارکیٹوں میں پوزیشن کے سائز کو کم کریں۔
  5. ملٹی ٹائم فریم تجزیہ: مختلف ٹائم فریم سے سگنل کو یکجا کریں ، جیسے روزانہ اور 4 گھنٹے کے چارٹ ، تاکہ متعدد ٹائم فریم میں ٹریڈنگ سگنل کی تصدیق کی جاسکے ، جس سے سگنل کی وشوسنییتا میں اضافہ ہو۔

خلاصہ

ای ایم اے - ایم اے سی ڈی - سپر ٹرینڈ - اے ڈی ایکس - اے ٹی آر ملٹی انڈیکیٹر ٹریڈنگ سگنل حکمت عملی ایک مقداری تجارتی حکمت عملی ہے جو متعدد تکنیکی اشارے کو مربوط کرتی ہے۔ ای ایم اے ، ایم اے سی ڈی ، اے ڈی ایکس ، اور اے ٹی آر جیسے اشارے کو یکجا کرکے ، حکمت عملی مارکیٹ کو مختلف جہتوں سے تجزیہ کرتی ہے ، بشمول رجحان ، نوسازی ، اور رسک کنٹرول ، تاجروں کے لئے قابل اعتماد تجارتی سگنل مہیا کرتی ہے۔ حکمت عملی کی طاقت اس کے ملٹی انڈیکیٹر مجموعہ ، رجحان کی نشاندہی ، رسک کنٹرول ، اور اسٹاپ نقصان کے طریقہ کار میں ہے۔ تاہم ، اس کو پیرامیٹر کی اصلاح ، مارکیٹ کی موافقت ، تجارتی اخراجات ، اور بیک ٹیسٹنگ کی حدود جیسے خطرات کا بھی سامنا کرنا پڑتا ہے۔ مستقبل میں ، حکمت عملی کو متحرک پیرامیٹر کی اصلاح ، جذبات کے اشارے کو شامل کرنے ، اسٹاپ نقصان کے طریقہ کار کو بڑھانے ، پوزیشننگ کی اصلاح ، اور ملٹی ٹائم فریم تجزیہ کے ذریعہ بہتر بنایا جاسکتا ہے تاکہ اس کی استحکام ، استحکام اور منافع میں اضافہ ہو۔

/*backtest
start: 2023-03-23 00:00:00
end: 2024-03-28 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy("EMA-MACD-SuperTrend-ADX-ATR Strategy", 
     overlay = true,
     initial_capital = 1000,
     default_qty_type = strategy.percent_of_equity,
     default_qty_value = 70)

//MACD
[macdLine, signalLine, hist] = ta.macd(close, 12, 26, 9)
//Plot Candlesticks
candlestickscolor = (hist >= 0 ? (hist[1] < hist ? #26A69A : #B2DFDB) : (hist[1] < hist ? #FFCDD2 : #FF5252))
plotcandle(open, high, low, close, 
     color = candlestickscolor, 
     bordercolor = candlestickscolor)
     
//EMA
ema12 = ta.ema(close, 12)
ema26 = ta.ema(close, 26)

//Plot EMA
plot(ema26, color= #EE6969, linewidth = 2)
plot(ema12, color= #B4CBF0, linewidth = 2)

//Average Directional Index (ADX) Calculation
trueRange = ta.rma(ta.tr, 14)
plusDM = ta.rma(math.max(high - high[1], 0), 14)
minusDM = ta.rma(math.max(low[1] - low, 0), 14)
plusDI = 100 * ta.rma(plusDM / trueRange, 14)
minusDI = 100 * ta.rma(minusDM / trueRange, 14)
adxValue = 100  *ta.rma(math.abs(plusDI - minusDI) / (plusDI + minusDI), 14)

//Trend Confirmation (ADX)
trending = adxValue > 15

//Volatility Filter (ATR)
atrValue = ta.atr(14)
volatility = atrValue > 0.5 * ta.atr(20)

//SuperTrend
atrlength = input.int(10, "ATR Length", step = 1)
factor = input.float(3, "Factor", step = 0.1)
[supertrend, direction] = ta.supertrend(factor, atrlength)
supertrend := barstate.isfirst ? na : supertrend

//Plot SuperTrend
uptrend = plot(direction < 0 ? supertrend : na, 
     "Up Trend", color = color.green, style = plot.style_linebr, linewidth = 1)

downtrend = plot(direction > 0 ? supertrend : na,
     "Down Trend", color = color.red, style = plot.style_linebr, linewidth = 1)
bodymiddle = plot(barstate.isfirst ? na : (open + close)/2, "Body Middle", display = display.none)
fill(bodymiddle, uptrend,   color.new(color.green, 90), fillgaps = false)
fill(bodymiddle, downtrend, color.new(color.red,   90), fillgaps = false)

//Entry Conditions
longCondition = ta.crossover(ema12, ema26) and trending and volatility and hist > 0

shortCondition = ta.crossunder(ema12, ema26)  and trending and volatility and hist < 0

long_SL_Con = ta.crossunder(close, supertrend)

short_SL_Con = ta.crossover(close, supertrend)

//Plot Signal
plotshape(longCondition, 
     title='Buy', text='Buy', 
     location= location.belowbar, 
     style=shape.labelup, size=size.tiny, 
     color=color.green, textcolor=color.new(color.white, 0))

plotshape(shortCondition, 
     title='Sell', text='Sell', 
     location= location.abovebar, 
     style=shape.labeldown, size=size.tiny, 
     color=color.red, textcolor=color.new(color.white, 0))

//Backtest
start = timestamp(2020, 1, 1, 0, 0, 0)
end = timestamp(2024, 1, 1, 0, 0, 0)
backtestperiod = time >= start and time <= end

if longCondition and backtestperiod
    strategy.entry("Buy", strategy.long)

if long_SL_Con and backtestperiod
    strategy.close("Buy")

if shortCondition and backtestperiod
    strategy.entry("Sell", strategy.short)

if short_SL_Con and backtestperiod
    strategy.close("Sell")
مزید

2019 FMZ - تمام حقوق محفوظ ہیں