পাইন ভাষা ব্যবহার করে একটি আধা-স্বয়ংক্রিয় ট্রেডিং টুল লিখুন

যদিও সম্পূর্ণ স্বয়ংক্রিয় ট্রেডিং করার জন্য আরও বেশি সংখ্যক ট্রেডার প্রোগ্রাম লিখছেন, বৃহত্তর গোষ্ঠী এখনও ম্যানুয়াল ট্রেডার। আসলে, ম্যানুয়াল সাবজেক্টিভ ট্রেডাররা তাদের বিষয়ভিত্তিক ট্রেডিংকে সহায়তা করার জন্য কিছু ছোট টুলও লিখতে পারে। উদাহরণস্বরূপ, কখনও কখনও আপনি একটি ভাল এন্ট্রি অবস্থান খুঁজে পান এবং প্রাথমিক অবস্থানের জন্য একটি নির্দিষ্ট স্টপ লস এবং ট্রেলিং টেক প্রফিট সেট করার পরিকল্পনা করেন। তারপরে বাজারের পরবর্তী ট্র্যাকিংয়ের মতো আরও শক্তি-সাশ্রয়ী জিনিসগুলি করার দরকার নেই এবং আপনি সম্পূর্ণরূপে আপনার নিজস্ব স্টপ-লস এবং লাভ-লাভ পরিকল্পনা অনুসরণ করতে পারেন এবং প্রোগ্রামটিকে আপনাকে বাজার ট্র্যাক করতে সহায়তা করতে দিন। আপনি বাজি হারলে ক্ষতি বন্ধ করুন, এবং আপনি বাজি জিতলে ম্যানুয়াল ট্রেডিং সহায়তা করতে স্টপ প্রফিট অনুসরণ করুন।

প্যারামেট্রিক ডিজাইন

এই ধরনের প্রয়োজনীয়তাগুলি ডিজাইন করার জন্য পাইন ভাষা ব্যবহার করার কৌশলটি প্রয়োজনীয়তা অনুযায়ী ফাংশনগুলি বাস্তবায়ন করতে, আপনাকে নিম্নলিখিত পরামিতিগুলি ডিজাইন করতে হবে:

1. অফসেট: ট্রেলিং টেক প্রফিট ট্রিগার করার সময়, টেক প্রফিট লাইনের অফসেট দূরত্ব বর্ণনা করতে সর্বোচ্চ মূল্য এবং সর্বনিম্ন মূল্য অফসেট করুন।
2. সীমা: নিয়ন্ত্রণ করতে প্যারামিটার ব্যবহার করা হয় - A. প্রাথমিক অবস্থানে সরাসরি কিনুন, B. নির্দিষ্ট মূল্যে কেনার জন্য অপেক্ষা করুন, C. কিছুই করবেন না৷
3. পরিমাণ: নীচের অবস্থানটি খোলার সময় অর্ডারের পরিমাণ।
4. ক্ষতি: স্টপ লস পয়েন্ট।
5. টার্গেটঅফসেট: ট্র্যালিং টেক প্রফিট ট্রিগার হওয়ার সময় প্রারম্ভিক মূল্য থেকে দামের পার্থক্য অফসেট হয়।
6. minTick: দাম লাফিয়ে উঠছে।
7. দিকনির্দেশ: নীচের অবস্থানটি খোলার দিক।

নকশা কৌশল

/*backtest
start: 2022-09-24 00:00:00
end: 2022-09-27 00:00:00
period: 1m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT"}]
args: [["v_input_1",20],["v_input_2",0],["v_input_4",50],["v_input_5",20],["RunMode",1,358374],["ZPrecision",0,358374],["XPrecision",3,358374]]
*/

strategy("跟踪止损止盈委托", overlay = true)

varip targetPrice = na
varip high_lowPrice = na
varip isTrade = false 
varip isAlert = false
varip isAlertMinTick = false
varip isAlertFinished = false 

varip offset = input(30, "offset", "跟踪止损止盈偏移")
varip limit = input(-1, "limit", "初始开仓价格，-1为不开仓，0为立即开仓，其它具体数值为限价价格")
varip amount = input(1, "amount", "开仓量")
varip loss = input(30, "loss", "止损")
varip targetOffset = input(30, "targetOffset", "触发跟踪止盈止损偏移量")
varip minTick = input(1, "minTick", "价格一跳")
tradeType = input.string("long", "direction", tooltip="下单方向，long做多，short做空", options=["long", "short"])

if not barstate.ishistory and not isAlertMinTick
    runtime.log("检查syminfo.mintick是否正确！syminfo.mintick：", syminfo.mintick, "#FF0000")
    if syminfo.mintick < minTick 
        runtime.error("系统syminfo.mintick < minTick参数", "#FF0000")
    isAlertMinTick := true 

if not barstate.ishistory and limit == -1 and not isAlert
    runtime.log("没有设置开仓价格，当前limit为-1（防止误开仓，初始默认limit为-1），禁止开仓", "#FF0000")
    isAlert := true 

if isTrade and strategy.position_size == 0 and not isAlertFinished
    runtime.log("所有委托流程执行完毕，仓位为0", "#FF0000")
    isAlertFinished := true 

if not barstate.ishistory and not isTrade and limit != -1
    if limit == 0 
        strategy.entry("open", tradeType == "long" ? strategy.long : strategy.short, amount)
    else if limit > 0 
        strategy.entry("open", tradeType == "long" ? strategy.long : strategy.short, amount, limit=limit)
    
    if tradeType == "long"
        targetPrice := (limit == 0 ? close : limit) + targetOffset
    else 
        targetPrice := (limit == 0 ? close : limit) - targetOffset
    strategy.exit("exit", "open", amount, loss=loss, trail_price=targetPrice, trail_offset=offset)
    runtime.log("每点价格为：", syminfo.mintick, "，当前close:", close)
    isTrade := true 

if ((close > targetPrice and strategy.position_size > 0) or (close < targetPrice and strategy.position_size < 0)) and not barstate.ishistory
    high_lowPrice := na(high_lowPrice) ? close : high_lowPrice
    if strategy.position_size > 0 
        high_lowPrice := close > high_lowPrice ? close : high_lowPrice
    else 
        high_lowPrice := close < high_lowPrice ? close : high_lowPrice

plot(targetPrice, "trail_price 触发线")    
plot(strategy.position_size!=0 ? high_lowPrice : na, "当前最高价/最低价")
plot(strategy.position_size!=0 ? (strategy.position_size > 0 ? high_lowPrice-syminfo.mintick*offset : high_lowPrice+syminfo.mintick*offset) : na, "移动止损触发线")

কৌশল ডিজাইন জটিল নয় এটি ব্যবহার করার সময়, এটি সাধারণত একটি “রিয়েল-টাইম প্রাইস মডেল” এ সেট করা প্রয়োজন কারণ মূল্য প্রতি মুহূর্তে নিরীক্ষণ করা প্রয়োজন৷

মনে রাখবেন যে প্যারামিটারগুলিতে স্টপ লস পয়েন্টে প্রকাশ করা হয় (একটি মূল্য লাফ), এবং অফসেট ট্র্যাকিং টেক প্রফিট অফসেটও পয়েন্টে প্রকাশ করা হয় (একটি মূল্য লাফ)। targetOffset টেক-প্রফিট ট্রিগার লাইনের অফসেট ট্র্যাক করে এবং মূল্য দূরত্বে প্রকাশ করা হয় (উদাহরণস্বরূপ, যদি আপনি এটি 30 তে সেট করেন, তাহলে এর অর্থ 30 ইউয়ানের দূরত্ব)। যখন দাম ১ হয়, ৩০টি লাফ মানে ৩০ ইউয়ানের দূরত্ব।

এই অর্পণ কৌশলটি কেবল প্রাথমিক অবস্থানে দীর্ঘ হওয়ার জন্য ডিজাইন করা হয়নি, তবে প্রাথমিক অবস্থানে ছোটও। তারপর স্টপ লস এবং ট্রেইলিং টেক প্রফিট সংক্ষিপ্ত দিকে পরিচালনা করা হবে।

আসুন এখন ডিজাইনের কাজগুলো দেখাই:

১. যখন এই কৌশলটি চলমান থাকে, তখন অবিলম্বে একটি বেস পজিশন খুলুন এবং তারপর প্যারামিটার অনুসারে স্টপ লস এবং ট্রেইলিং টেক প্রফিট সেট করুন।

দিকটি লম্বাতে সেট করা হয়েছে, সীমা প্যারামিটারটি 0 এ সেট করা হয়েছে, যার অর্থ কৌশলটি যখন কৌশলটি চলছে তখনই লং পজিশনে প্রবেশ করা হবে এবং কৌশলটি 1টি চুক্তি খুলবে।

2. সীমা প্যারামিটার নির্দিষ্ট করুন এবং একটি নির্দিষ্ট মূল্যে লিখুন।

অন্যান্য প্যারামিটার সেটিংস অপরিবর্তিত থাকে, সীমা প্যারামিটারের মূল্য এইভাবে নির্দিষ্ট করা ছাড়া: 1276

3. ডিফল্ট সীমা পরামিতি হল -1, এবং ঘটনাক্রমে একটি অবস্থান খোলার প্রতিরোধ করার জন্য কোন অপারেশন করা হয় না।

THE END

পাইন ভাষার কৌশল ব্যবহার করার সময়, মূল্য লাফানোর ডেটাতে বিশেষ মনোযোগ দিন। সিস্টেমের নির্দিষ্ট মূল্য লাফ প্যারামিটারে “মূল্যের মুদ্রার নির্ভুলতা” এর সাথে সম্পর্কিত।

“মূল্য নির্ধারণ মুদ্রার যথার্থতা” প্যারামিটারটি 0 তে সেট করা আছে, যার অর্থ হল মূল্য ডেটা মান একক অঙ্কের সাথে সঠিক (অর্থাৎ, দশমিক স্থানের সংখ্যা 0)। তাহলে মূল্য পরিবর্তনের সর্বনিম্ন একক হল ১। যেহেতু কিছু পরামিতি নির্দিষ্ট মূল্যবৃদ্ধির সাথে সম্পর্কিত, তাই এই বিষয়টিতে বিশেষ মনোযোগ দেওয়া উচিত।

ঠিক আছে, উপরেরটি এই আধা-স্বয়ংক্রিয় প্রতিনিধি কৌশলের সম্পূর্ণ ডিজাইনের বিষয়বস্তু, যদিও আমি এটি বাস্তব ব্যবসায়ের জন্যও ব্যবহার করি। যাইহোক, এই ধরনের টুলগুলিকে অবশ্যই বুঝতে হবে এবং আপনার নিজের ট্রেডিং অভ্যাস অনুযায়ী ব্যবহার করতে হবে এবং আপনি নিজেই সেগুলিকে সংশোধন ও অপ্টিমাইজ করতে পারেন। শেখার নকশা পদ্ধতি এবং যুক্তির সাথে যোগাযোগ করার জন্য এখানে কৌশল কোডটি শুধুমাত্র সর্বজনীনভাবে শেয়ার করা হয়েছে।

এটি দেখা যায় যে পাইন ভাষা ব্যবহার করা খুব সহজ, সুবিধাজনক এবং শিখতে সহজ। আমরা পাইন ভাষা ব্যবহার করতে পারি আমাদের পছন্দের সরঞ্জামগুলিকে দ্রুত ডিজাইন করতে, এবং আমাদের আর জটিল প্রোগ্রামিং নিয়ে চিন্তা করতে হবে না FMZ কোয়ান্টিটেটিভ-এ পাইন ভাষা ব্যবহার করা পরিমাণগত ট্রেডিংকে সহজ এবং সহজ করে তোলে।