पाइन भाषा का उपयोग करके एक अर्ध-स्वचालित ट्रेडिंग टूल लिखें

यद्यपि अधिकाधिक व्यापारी पूर्णतः स्वचालित व्यापार करने के लिए प्रोग्राम लिख रहे हैं, फिर भी बड़ा समूह अभी भी मैनुअल व्यापारियों का है। वास्तव में, मैनुअल सब्जेक्टिव ट्रेडर्स भी अपने सब्जेक्टिव ट्रेडिंग में सहायता के लिए कुछ छोटे टूल लिख सकते हैं। उदाहरण के लिए, कभी-कभी आपको एक अच्छी प्रवेश स्थिति मिल जाती है और आप प्रारंभिक स्थिति के लिए एक निश्चित स्टॉप लॉस और ट्रेलिंग टेक प्रॉफिट निर्धारित करने की योजना बनाते हैं। फिर आप बाजार की बाद की निगरानी जैसे ऊर्जा-खपत कार्यों से बच सकते हैं। बस अपने स्थापित स्टॉप-लॉस और टेक-प्रॉफिट योजनाओं का पालन करें और प्रोग्राम को आपके लिए बाजार की निगरानी करने दें। यदि आप दांव हार जाते हैं, तो हानि रोकें; यदि आप जीत जाते हैं, तो मैनुअल ट्रेडिंग में सहायता के लिए लाभ लक्ष्य पर नज़र रखें।

पैरामीटर डिजाइन

पाइन भाषा का उपयोग करके ऐसी आवश्यकताओं को डिज़ाइन करने की रणनीति बहुत सरल है। आवश्यकताओं के अनुसार फ़ंक्शन को लागू करने के लिए निम्नलिखित मापदंडों को डिज़ाइन करने की आवश्यकता है:

1. ऑफसेट: जब ट्रेलिंग टेक प्रॉफिट ट्रिगर होता है, तो टेक प्रॉफिट लाइन की ऑफसेट दूरी निर्धारित करने के लिए उच्चतम मूल्य और निम्नतम मूल्य को ऑफसेट किया जाता है।
2. सीमा: पैरामीटर का उपयोग नियंत्रित करने के लिए किया जाता है - ए. प्रारंभिक आधार स्थिति पर सीधे खरीदें, बी. निर्दिष्ट मूल्य पर खरीदने की प्रतीक्षा करें, सी. कुछ भी न करें।
3. मात्रा: आधार गोदाम खोले जाने पर ऑर्डर की मात्रा।
4. हानि: स्टॉप लॉस पॉइंट.
5. लक्ष्य ऑफसेट: मूल्य अंतर जो ट्रेलिंग लाभ को ट्रिगर करते समय प्रारंभिक मूल्य को ऑफसेट करता है।
6. मिन्टिक: एक मूल्य वृद्धि.
7. दिशा: आधार स्थिति खोलने की दिशा।

डिजाइन रणनीति

            pine
            
            
/*backtest
start: 2022-09-24 00:00:00
end: 2022-09-27 00:00:00
period: 1m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT"}]
args: [["v_input_1",20],["v_input_2",0],["v_input_4",50],["v_input_5",20],["RunMode",1,358374],["ZPrecision",0,358374],["XPrecision",3,358374]]
*/

strategy("跟踪止损止盈委托", overlay = true)

varip targetPrice = na
varip high_lowPrice = na
varip isTrade = false 
varip isAlert = false
varip isAlertMinTick = false
varip isAlertFinished = false 

varip offset = input(30, "offset", "跟踪止损止盈偏移")
varip limit = input(-1, "limit", "初始开仓价格，-1为不开仓，0为立即开仓，其它具体数值为限价价格")
varip amount = input(1, "amount", "开仓量")
varip loss = input(30, "loss", "止损")
varip targetOffset = input(30, "targetOffset", "触发跟踪止盈止损偏移量")
varip minTick = input(1, "minTick", "价格一跳")
tradeType = input.string("long", "direction", tooltip="下单方向，long做多，short做空", options=["long", "short"])

if not barstate.ishistory and not isAlertMinTick
    runtime.log("检查syminfo.mintick是否正确！syminfo.mintick：", syminfo.mintick, "#FF0000")
    if syminfo.mintick < minTick 
        runtime.error("系统syminfo.mintick < minTick参数", "#FF0000")
    isAlertMinTick := true 

if not barstate.ishistory and limit == -1 and not isAlert
    runtime.log("没有设置开仓价格，当前limit为-1（防止误开仓，初始默认limit为-1），禁止开仓", "#FF0000")
    isAlert := true 

if isTrade and strategy.position_size == 0 and not isAlertFinished
    runtime.log("所有委托流程执行完毕，仓位为0", "#FF0000")
    isAlertFinished := true 

if not barstate.ishistory and not isTrade and limit != -1
    if limit == 0 
        strategy.entry("open", tradeType == "long" ? strategy.long : strategy.short, amount)
    else if limit > 0 
        strategy.entry("open", tradeType == "long" ? strategy.long : strategy.short, amount, limit=limit)
    
    if tradeType == "long"
        targetPrice := (limit == 0 ? close : limit) + targetOffset
    else 
        targetPrice := (limit == 0 ? close : limit) - targetOffset
    strategy.exit("exit", "open", amount, loss=loss, trail_price=targetPrice, trail_offset=offset)
    runtime.log("每点价格为：", syminfo.mintick, "，当前close:", close)
    isTrade := true 

if ((close > targetPrice and strategy.position_size > 0) or (close < targetPrice and strategy.position_size < 0)) and not barstate.ishistory
    high_lowPrice := na(high_lowPrice) ? close : high_lowPrice
    if strategy.position_size > 0 
        high_lowPrice := close > high_lowPrice ? close : high_lowPrice
    else 
        high_lowPrice := close < high_lowPrice ? close : high_lowPrice

plot(targetPrice, "trail_price 触发线")    
plot(strategy.position_size!=0 ? high_lowPrice : na, "当前最高价/最低价")
plot(strategy.position_size!=0 ? (strategy.position_size > 0 ? high_lowPrice-syminfo.mintick*offset : high_lowPrice+syminfo.mintick*offset) : na, "移动止损触发线")

रणनीति का डिज़ाइन जटिल नहीं है। इसका उपयोग करते समय, इसे आमतौर पर "वास्तविक समय मूल्य मॉडल" पर सेट करने की आवश्यकता होती है क्योंकि मूल्य को हर पल जांचना पड़ता है।

ध्यान दें कि पैरामीटर्स में स्टॉप लॉस को पॉइंट्स (एक मूल्य उछाल) में व्यक्त किया जाता है, और ऑफसेट ट्रैकिंग टेक प्रॉफिट ऑफसेट को भी पॉइंट्स (एक मूल्य उछाल) में व्यक्त किया जाता है। targetOffset लाभ-प्राप्ति ट्रिगर लाइन के ऑफसेट को ट्रैक करता है और मूल्य दूरी में व्यक्त किया जाता है (उदाहरण के लिए, यदि आप इसे 30 पर सेट करते हैं, तो इसका मतलब 30 युआन की दूरी है)। जब मूल्य में उछाल 1 है, तो 30 उछाल का मतलब 30 युआन की दूरी है।

यह सौंपने की रणनीति न केवल आरंभिक लंबी स्थिति के लिए बल्कि आरंभिक छोटी स्थिति के लिए भी अनुमति देने के लिए तैयार की गई है। फिर स्टॉप लॉस और ट्रेलिंग प्रॉफिट को शॉर्ट सेलिंग दिशा के अनुसार नियंत्रित किया जाएगा।

आइये डिज़ाइन द्वारा क्रियान्वित कार्यों का प्रदर्शन करें:

1. जब यह रणनीति चल रही हो, तो तुरंत एक बेस पोजीशन खोलें और फिर पैरामीटर के अनुसार स्टॉप लॉस और ट्रेलिंग टेक प्रॉफिट सेट करें।

दिशा को लंबे पर सेट किया गया है, सीमा पैरामीटर 0 पर सेट किया गया है, जिसका अर्थ है कि रणनीति बाजार में प्रवेश करेगी और चलने पर तुरंत लंबी हो जाएगी, और राशि 1 पर सेट की गई है, और रणनीति 1 की स्थिति खोलेगी अनुबंध।

2. सीमा पैरामीटर और प्रवेश मूल्य निर्दिष्ट करें

अन्य पैरामीटर सेटिंग अपरिवर्तित रहेंगी, बस सीमा पैरामीटर मूल्य को इस प्रकार निर्दिष्ट करें: 1276

3. डिफ़ॉल्ट सीमा पैरामीटर -1 है, जिसका अर्थ है कि पोजीशन के आकस्मिक खुलने को रोकने के लिए कोई ऑपरेशन नहीं किया जाता है।

THE END

पाइन भाषा रणनीति का उपयोग करते समय, मूल्य उछाल डेटा पर विशेष ध्यान दें। प्रणाली की विशिष्ट मूल्य वृद्धि मापदंडों में "मूल्य निर्धारण मुद्रा परिशुद्धता" से संबंधित है।

"मूल्य निर्धारण मुद्रा परिशुद्धता" पैरामीटर 0 पर सेट है, जिसका अर्थ है कि मूल्य डेटा मान इकाई अंक तक सटीक है (अर्थात, दशमलव स्थानों की संख्या 0 है)। तब मूल्य परिवर्तन की न्यूनतम इकाई 1 है। क्योंकि कुछ पैरामीटर विशिष्ट मूल्य उछाल से संबंधित हैं, इस बिंदु पर विशेष ध्यान दिया जाना चाहिए।

ठीक है, उपरोक्त इस अर्ध-स्वचालित सौंपने की रणनीति की पूरी डिज़ाइन सामग्री है, हालांकि मैं इसका उपयोग वास्तविक ट्रेडिंग में भी करता हूं। हालाँकि, ऐसे उपकरणों को आपकी अपनी ट्रेडिंग आदतों के अनुसार समझा और उपयोग किया जाना चाहिए, और आप उन्हें स्वयं संशोधित और अनुकूलित कर सकते हैं। यहां रणनीति कोड केवल सार्वजनिक साझाकरण, संचार और डिजाइन विधियों और तर्क सीखने के लिए है।

यह देखा जा सकता है कि पाइन भाषा का उपयोग करना बहुत आसान है, सुविधाजनक है, और सीखना आसान है। हम जटिल प्रोग्राम डिज़ाइन के बारे में चिंता किए बिना अपने इच्छित टूल को तेज़ी से डिज़ाइन करने के लिए पाइन भाषा का उपयोग कर सकते हैं। FMZ क्वांटिटेटिव में पाइन भाषा का उपयोग करने से क्वांटिटेटिव ट्रेडिंग आसान और सरल हो जाती है।