Menulis model trans-siklus bahasa My

Mengapa kita perlu menulis model trans-siklus?

Dalam perdagangan, tren siklus besar adalah naik dan tren siklus kecil adalah turun, di mana arahnya?

Jika ide perdagangan yang dilakukan menurut urutan mengikuti arah tren besar, maka akan ada dua masalah: pertama, ketika tren kecil berlawanan dengan perubahan tren besar, chip yang ada di tangan dapat menghasilkan kerugian besar, bahkan membuat orang tidak tahan untuk berdagang. Kedua, jika terjadi pergeseran kecil, pergeseran besar juga akan menyebabkan pergeseran tren besar, sehingga terlambat untuk berdagang lagi ketika tren besar berbalik.

Sebagai contoh di atas: muncul sinyal pembalikan di kepala M pada siklus 30 menit, dan kemungkinan besar melompat lebih dari 40 poin untuk memulai posisi kosong, sedangkan siklus kecil 1 menit pada awalnya menurun dan tidak lama kemudian mulai pulih, hingga mencapai 43,8 poin, kerugian besar ini mudah memicu pemasangan pesanan stop loss yang baik lebih awal.

Oleh karena itu, memahami hubungan antara ukuran dan ukuran siklus, memahami waktu operasional yang optimal adalah masalah yang harus dipelajari dalam analisis lintas siklus. Analisis lintas siklus pada dasarnya adalah untuk memecahkan masalah bagaimana fluktuasi kecil mempengaruhi tren besar, atau bagaimana tren besar membatasi tren kecil.

Aplikasi lain dari trans-siklus adalah dalam teori resonansi.

Pertama-tama, ada sebuah cerita kecil: Pada Perang Dunia I, sekelompok tentara Jerman berjalan dengan langkah yang teratur dan melewati sebuah jembatan, sehingga akhirnya menjatuhkan jembatan tersebut. Jembatan itu sendiri memiliki berat yang jauh lebih besar dari beban pasukan Jerman, tetapi karena langkah para tentara disesuaikan dengan ritme dan kesatuan, jembatan itu runtuh karena kekuatan yang sama.

Teori resonansi di pasar perdagangan: frekuensi fluktuasi pasar atau faktor-faktor siklik internal, yang berasal dari perkalian hubungan antara waktu pasar dan harga. Ketika frekuensi fluktuasi internal pasar dan frekuensi kekuatan pendorong pasar eksternal memiliki hubungan multipel, maka pasar akan memiliki hubungan resonansi, sehingga pasar memiliki pengaruh besar ke atas atau ke bawah.

Penggunaan fungsi dalam model lintas siklus

// 本代码演示如何引用不同周期的公式在同一代码里
// #EXPORT扩展语法, 以#END结束标记为一个公式,可以声明多个
#EXPORT TEST 
均值1:EMA(C, 20);
均值2:EMA(C, 10);
#END // 结束

#IMPORT [MIN,15,TEST] AS VAR15 // 引用公式, K线周期用15分钟
#IMPORT [MIN,30,TEST] AS VAR30 // 引用公式, K线周期用30分钟
CROSSUP(VAR15.均值1, VAR30.均值1),BPK;
CROSSDOWN(VAR15.均值2, VAR30.均值2),SPK;
十五分最高价:VAR15.HIGH;
三十分最高价:VAR30.HIGH;
AUTOFILTER;

Untuk informasi lebih lanjut, silakan kunjungi:https://www.fmz.com/digest-topic/2569

Struktur dan pemrograman model lintas siklus

Struktur dasar dari model trans-siklus:

• Langkah 1: Membuat FORMULA model yang dirujuk

• Langkah 2: Membuat model trans-siklus yang dapat digunakan sebagai berikut:

#IMPORT [PERIOD,N,FORMULA] AS VAR
A1:VAR.A;

A1>REF(A1,1),BPK;
A1<REF(A1,1),SPK;

…

AUTOFILTER;

Contoh 1: Mengutip harga penutupan garis K hari kemarin dalam siklus lima menit

• Langkah 1: Membuat Indikator 1

CC:REF(C,1);

• Langkah 2: Membuat Indikator Trans Siklus 2

#IMPORT[DAY,1,A] AS A1
C1:A1.CC;

• Langkah 3: Terapkan Indikator 2 pada K-String 5 menit

Di atas ini adalah contoh sederhana dan kerangka kerja kode, kemudian kita menulis struktur yang lebih kompleks.

Contoh 2: Berdasarkan grafik siklus 30 menit, ketika indikator MACD pada siklus 30 menit menunjukkan kolom merah, dan volume yang diperdagangkan lebih besar dari yang sebelumnya; garis rata-rata pada siklus besar (hari dan 1 jam) memiliki kombinasi berjumlah banyak kepala; maka indikator KD pada siklus kecil (menit 15 atau 5 menit) adalah titik beli.

DIFF : EMA(CLOSE,12) - EMA(CLOSE,26);
DEA  : EMA(DIFF,9);
#IMPORT[DAY,1,MM] AS MM1
MD1:MM1.M1;
MD2:MM1.M2;
MD3:MM1.M3;
#IMPORT[HOUR,1,MM] AS MM2
MH1:MM2.M1;
MH2:MM2.M2;
MH3:MM2.M3;
#IMPORT[MIN,15,KD] AS KD1
K1:=KD1.K;
D1:=KD1.D;
#IMPORT[MIN,5,KD] AS KD2
K2:=KD2.K;
D2:=KD2.D;
TMP1:= DIFF>DEA&&VOL>REF(VOL,1);
TMP2:=(MD1>MD2&&MD2>MD3)&&(MH1>MH2&&MH2>MH3);
TMP3:=(CROSSUP(K1,D1)||CROSSUP(K2,D2);
TMP1&&TMP2&&TMP3,BK(10);

Untuk penjelasan dan penggunaan fungsi yang tidak dipahami dalam contoh ini, silakan lihat dokumen API resmi dari Inventor Quantification Platform dan dokumen bahasa My:https://www.fmz.com/digest-topic/2569

Mari kita coba lagi contoh trans siklus garis lurus.

Contoh 3: Sistem perdagangan tiga layar; melakukan lebih banyak ketika grafik bulan sedang naik dan indikator osilasi grafik minggu sedang turun; kosong ketika grafik bulan sedang turun dan indikator osilasi grafik minggu sedang naik.

• Langkah 1: Menulis SPJY yang dikutip

EMA1:EMA(C,13);
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100
K:SMA(RSV,3,1);
D:SMA(K,3,1);
J:3*K-2*D;

• Langkah 2: Membangun sistem perdagangan tiga layar

#IMPORT [ MONTH,1,SPJY] AS VAR1
YMA:=VAR1.EMA1;
#IMPORT [ WEEK,1,SPJY] AS VAR2
ZJ:=VAR2.J;
LL:=VALUEWHEN(YMA>REF(YMA,1)&&ZJ<30,L);
HH:=VALUEWHEN(YMA<REF(YMA,1)&&ZJ>70,H);
YMA>REF(YMA,1)&&ZJ<30,BK;//月线的趋势向上，周线的振荡指标向下
YMA<REF(YMA,1)&&ZJ>70,SK;//月线的趋势向下，周线的振荡指标向上
C<LL,SP;//多头止损出场
C>HH,BP;//空头止损出场
C<LLV(L,20),SP;//多头出场条件
C>HHV(H,20),BP;//空头出场条件
AUTOFILTER;

Catatan: Indikator lintas siklus, model mendukung siklus kecil untuk merujuk pada siklus besar, atau siklus besar dapat merujuk pada siklus kecil, perhatikan referensi data.

Indikator DAYBAR

N:=BARSLAST(DATE<>REF(DATE,1))+1;

#IMPORT[HOUR,1,DAYBAR] AS VAR1
N1:VAR1.N;
盘中3分钟引用1小时周期的当日K线根数，20个3分钟周期N1才变动。

#IMPORT[MIN,3,DAYBAR] AS VAR2
N2:VAR2.N;
盘中1小时引用3分钟周期的当日K线的根数N，1小时中存在20个N2值变动。

Di atas adalah beberapa aplikasi sederhana dari My Language dalam menulis strategi lintas-siklus, pembaca dapat memainkan berbagai kombinasi siklus dan indikator secara fleksibel untuk mencapai efek yang mereka inginkan, terutama dalam mata uang digital, karena munculnya kontrak permanen, penggunaan My Language yang efisien dapat menghindari masalah penggantian kontrak utama dalam produk berjangka seperti komoditas.

Perhatian

• Indikator yang dikutip dalam model trans-siklus, trans-kontrak tidak dapat dikutip dalam model.

• Sebuah cross-cycle, cross-contract model mendukung maksimal 6 kalimat referensi.

• Penggunaan sumber data lintas siklus, lintas kontrak tidak dapat melebihi 50 di seluruh bahasa My.