発明者による定量化プラットフォームにおける熱器戦略の実践と応用

なぜ恒温器と呼ばれるのか.我々はこのシステムを,市場,波動,トレンドの両方のモードで変換し取引する適応性の観点から命名した.このシステムは,特定のシステムの特定の市場領域での成功の観察から生まれました.このシステムは,市場の両方のモードを最大限に活用するための二重性のある戦略を作成することができます.

まず,市場パターンを決定するのに役立つ関数を作成します. この関数の出力に基づいて,熱器はフォローモードから短期振動モードに切り替えます.

トレンドトラッキングパターンは,ブリンズ帯のようなトレンドトラッキングメカニズムを使用する. 短期振動システムは,パターンの認識を含むオープンブレークスルーである. この関数は,市場が傾いている距離と,実際に市場が走っている距離を比較する.

Abs (閉店価格 - 閉店価格[29])/ (最高価格) (30) - 最低価格 (低価格,30日) * 100

この関数は0から100までの値を生成する. 値が大きいほど,現在の市場が混雑する程度は小さい. 関数の返した値が20未満である場合,システムは短期振動モードに入る.

基本的には,市場の大半は波動の動きを示しており,システムは波動を掴み,わずかな利益を得ようとしています. 恒温器は,小さな市場衝動で買い/売ることでこの壮大なことを達成しようとしています. 波動が十分に大きい場合,システムはモードを切り替えます.

短期波動の深入分析により,時として買い方が売よりも好ましい時と逆のことも発見した.これらの時を単純な視覚的パターンによって判断できる.今日の閉じる価格が昨日の高値,低値,閉じる価格 (また,今日の重要なポイントとも呼ばれる) より高い場合,明日の市場の動きが下落する可能性が高いと考えられる.しかし,今日の閉じる価格が昨日の高値,低値,開く価格の平均値よりも低い場合,今日の市場は見張る可能性が高い.我々はこれらの時をより簡単に買取と売却する価格に分類する.

発明者定量化プラットフォームでは,サーモネータ戦略は非常に人気のある戦略であり,ユーザーは自分のニーズに応じて,戦略のパフォーマンスをより良くするために,いくつかの追加の取引ロジックを追加します.

• フォトグラフ: 上軌式:TOP^^MAC+N_TMPTMP;//ブリン通道上軌 下軌公式:BOTTOM^^MAC-N_TMPTMP;//ブリン通道下軌

• 副図: CMI公式:CMI:ABS ((C-REF ((C,N_CMI-1))/(HHV ((H,N_CMI) -LLV ((L,N_CMI)) *100;//0-100 値を取れば大きいほど,傾向が強いことを示し,CMI<20の波動パターン,CMI>20は傾向である.

• コード ((My language): メールの送信番号

MAC:=MA(CLOSE,N);
TMP:=STD(CLOSE,N);
TOP^^MAC+N_TMP*TMP;      // 布林通道上轨
BOTTOM^^MAC-N_TMP*TMP;   // 布林通道下轨
BBOLL:=C>MAC;
SBOLL:=C<MAC;
N_CMI:=30;

CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; //0-100 取值越大，说明趋势越强，CMI<20震荡模式，CMI>20为趋势

N_KD:=9;
M1:=3;
M2:=3;
RSV:=(CLOSE-LLV(LOW,N_KD))/(HHV(HIGH,N_KD)-LLV(LOW,N_KD))*100; //收盘价与N周期最低值做差，N周期最高值与N周期最低值做差，两差之间做比值。

K:=SMA(RSV,M1,1); //RSV的移动平均值
D:=SMA(K,M2,1);   //K的移动平均值
MIND:=30;
BKD:=K>D AND D<MIND;
SKD:=K<D AND D>100-MIND;

// 震荡模式
BUYPK1:=CMI < 20 AND BKD;  //震荡多单买平开
SELLPK1:=CMI < 20 AND SKD; //震荡空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY1:=REF(CMI,BARSBK) < 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND K<D; //震荡多单止盈
BUYY1:=REF(CMI,BARSSK) < 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND K>D;  //震荡空单止盈

// 趋势模式
BUYPK2:=CMI >= 20 AND C > TOP;        // 趋势多单买平开
SELLPK2:=CMI >= 20 AND C < BOTTOM;    // 趋势空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY2:=REF(CMI,BARSBK) >= 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND SBOLL;//趋势多单止盈
BUYY2:=REF(CMI,BARSSK) >= 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND BBOLL;//趋势空单止盈
SELLS2:=REF(CMI,BARSBK) >= 20 AND C<BKPRICE*(1-0.01*STOPLOSS) AND SBOLL;//趋势多单止损
BUYS2:=REF(CMI,BARSSK) >= 20 AND C>SKPRICE*(1+0.01*STOPLOSS) AND BBOLL;//趋势空单止损

IF BARPOS>N THEN BEGIN
    BUYPK1,BPK;
    SELLPK1,SPK;
    BUYPK2,BPK;
    SELLPK2,SPK;
END
BUYY1,BP(SKVOL);
BUYY2,BP(SKVOL);
BUYS2,BP(SKVOL);
SELLY1,SP(BKVOL);
SELLY2,SP(BKVOL);
SELLS2,SP(BKVOL);

この戦略は,以下の結果を示しています.

詳細については,以下を参照してください:https://www.fmz.com/strategy/129086