ADXフィルターを用いた適応型レンコモメンタムトレンドフォロー戦略

/*backtest
start: 2025-06-06 00:00:00
end: 2025-07-05 10:00:00
period: 1h
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BNB_USDT"}]
*/

//@version=6
strategy("Renko UT Bot Strategy v6 - ADX Filter", overlay=true, default_qty_type=strategy.percent_of_equity, default_qty_value=1)

// === Inputs ===
atrPeriod       = input.int(5,    "ATR Period",               minval=1)
atrMult         = input.float(3.5, "ATR Multiplier",           step=0.1)
useAtrSmooth    = input.bool(false,"Use Wilder ATR Smooth")
adaptiveAtr     = input.bool(false,"Adaptive ATR Multiplier")
adaptiveFactor  = input.float(1.0, "Adaptive Mult Factor",    step=0.1)
emaPeriod       = input.int(1,    "EMA Period for Crossover", minval=1)
showStopLine    = input.bool(true, "Show Trailing Stop")
showStopLabel   = input.bool(true, "Show Stop Label")
labelOffset     = input.int(2,    "Label Horizontal Offset",  minval=-10, maxval=10)
labelSizeOpt    = input.string("small","Label Text Size",     options=["tiny","small","normal","large"])
arrowOffset     = input.int(0,    "Arrow Offset",             minval=-10, maxval=10)

// === ADX Filter Inputs ===
adxLen      = input.int(14, "ADX Length", minval=1)
adxThresh   = input.float(20, "ADX Threshold", step=0.1)
diplusThresh= input.float(20, "DI+ Threshold", step=0.1)
diminusThresh=input.float(20, "DI- Threshold", step=0.1)

// === Price & ATR ===
src      = close
atrRaw   = useAtrSmooth ? ta.rma(ta.tr, atrPeriod) : ta.atr(atrPeriod)
mult     = adaptiveAtr    ? atrMult * (atrRaw / ta.atr(atrPeriod)) * adaptiveFactor : atrMult
loss     = atrRaw * mult

// === UT Bot Trailing Stop ===
var float stopLine = na
prevStop        = nz(stopLine[1], src)
stp1            = src > prevStop ? src - loss : src + loss
stp2            = (src < prevStop and src[1] < prevStop) ? math.min(prevStop, src + loss) : stp1
stopLine        := (src > prevStop and src[1] > prevStop) ? math.max(prevStop, src - loss) : stp2

plot(showStopLine ? stopLine : na, title="Trailing Stop", color=color.orange)

// === Signals ===
ema1    = ta.ema(src, emaPeriod)
buyX    = ta.crossover(ema1, stopLine)
sellX   = ta.crossover(stopLine, ema1)

// === Manual ADX and DI Calculation ===
upMove   = high - high[1]
downMove = low[1] - low
plusDM   = (upMove > downMove and upMove > 0) ? upMove : 0
minusDM  = (downMove > upMove and downMove > 0) ? downMove : 0
trur     = ta.rma(ta.tr, adxLen)
plusDI   = 100 * ta.rma(plusDM, adxLen) / trur
minusDI  = 100 * ta.rma(minusDM, adxLen) / trur
dx       = 100 * math.abs(plusDI - minusDI) / (plusDI + minusDI)
adx      = ta.rma(dx, adxLen)

// === ADX Filter ===
adxFilterLong  = adx > adxThresh and plusDI > diplusThresh
adxFilterShort = adx > adxThresh and minusDI > diminusThresh

// === Filtered Entry Signals ===
signalLongEntry  = buyX and src > stopLine and adxFilterLong
signalShortEntry = sellX and src < stopLine and adxFilterShort

// === Entries & Labels ===
if signalLongEntry
    strategy.entry("Long", strategy.long)
    if showStopLabel
        label.new(bar_index + labelOffset, stopLine,
           text="Stop: " + str.tostring(stopLine, "#.#####"), xloc=xloc.bar_index,
           style=label.style_label_left, color=color.orange, textcolor=color.white,
           size = labelSizeOpt == "tiny"  ? size.tiny  :
                  labelSizeOpt == "small" ? size.small :
                  labelSizeOpt == "normal"? size.normal : size.large)

if signalShortEntry
    strategy.entry("Short", strategy.short)
    if showStopLabel
        label.new(bar_index + labelOffset, stopLine,
           text="Stop: " + str.tostring(stopLine, "#.#####"), xloc=xloc.bar_index,
           style=label.style_label_left, color=color.orange, textcolor=color.white,
           size = labelSizeOpt == "tiny"  ? size.tiny  :
                  labelSizeOpt == "small" ? size.small :
                  labelSizeOpt == "normal"? size.normal : size.large)

plotshape(signalLongEntry,  title="Buy",  style=shape.triangleup,   location=location.belowbar, color=color.green,  offset=arrowOffset)
plotshape(signalShortEntry, title="Sell", style=shape.triangledown, location=location.abovebar, color=color.red,    offset=arrowOffset)

// === Alerts ===
alertcondition(signalLongEntry,  title="UT Bot Long",  message="UT Bot Long Signal")
alertcondition(signalShortEntry, title="UT Bot Short", message="UT Bot Short Signal")
if signalLongEntry
    alert("Long @" + str.tostring(close), alert.freq_once_per_bar_close)
if signalShortEntry
    alert("Short @" + str.tostring(close), alert.freq_once_per_bar_close)