다차원적 시장 분석 및 양적 거래 전략

/*backtest
start: 2024-07-22 00:00:00
end: 2025-07-20 08:00:00
period: 2d
basePeriod: 2d
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT","balance":2000000}]
*/

//@version=6
strategy("Panel Pro+ Quantum SmartPrompt", overlay=true, default_qty_value = 10)

// --- BASE INDICATORS
ema_suprem   = ta.ema(close, 55)
sma_vol20    = ta.sma(volume, 20)
[macdLine, signalLine, _] = ta.macd(close, 12, 26, 9)
rsi_val      = ta.rsi(close, 14)
atr14        = ta.atr(14)
range20      = ta.stdev(close, 20)
sniper_thresh = ta.percentile_nearest_rank(volume, 40, 80)
rvol         = volume / sma_vol20

// --- WARNING PRECALCULATIONS
smaATR20 = ta.sma(atr14, 20)
smaATR20x12 = smaATR20 * 1.2
smaATR20x08 = smaATR20 * 0.8
smaRange20 = ta.sma(range20, 20)
smaRange20x08 = smaRange20 * 0.8

// --- CORE LOGIC VARIABLES (removed display colors/prompts)
vol_abs_thresh = sma_vol20 * 1.2
trend = close > ema_suprem ? 1 : close < ema_suprem ? -1 : 0
delta = close - open

// --- SIMPLIFIED CANDLE PATTERNS
is_hammer = (high - low) > 3 * math.abs(open - close) and
             (close - low) / (0.001 + high - low) > 0.6 and
             (open - low) / (0.001 + high - low) > 0.6
is_engulfing = close > open[1] and open < close[1] and
               close > open and open < close

pattern = is_hammer ? 1 : is_engulfing ? 2 : 0

// --- MARKET TYPE DETECTION
isBull = close > ema_suprem and macdLine > signalLine and rsi_val > 50 and rvol > 1
isBear = close < ema_suprem and macdLine < signalLine and rsi_val < 50 and volume > sma_vol20
isSideways = math.abs(close - ema_suprem) < atr14 * 0.5 and atr14 < smaATR20
isVolatile = atr14 > smaATR20x12
isMomentum = ta.change(close, 1) > atr14 * 1.5 and volume > sma_vol20 * 1.5
isMeanRev = rsi_val > 70 or rsi_val < 30
isBox = isSideways and range20 < smaRange20x08
isMacro = math.abs(ta.change(close, 1)) > atr14 * 2
isWolf = ta.change(close, 1) < -atr14 and close < ema_suprem
isEagle = isBull and atr14 < smaATR20x08

var string marketType = ""

if isEagle
    marketType := "Eagle"
else if isBull
    marketType := "Bull"
else if isWolf
    marketType := "Wolf"
else if isBear
    marketType := "Bear"
else if isBox
    marketType := "Box"
else if isSideways
    marketType := "Sideways"
else if isVolatile
    marketType := "Volatile"
else if isMomentum
    marketType := "Momentum"
else if isMeanRev
    marketType := "MeanRev"
else if isMacro
    marketType := "Macro"
else
    marketType := "Unknown"

// --- DYNAMIC WEIGHT MATRIX
weights = array.new_float(10)
if marketType == "Bull"
    array.set(weights, 0, 2.0) // trend
    array.set(weights, 1, 1.5) // rsi
    array.set(weights, 2, 2.0) // macd
    array.set(weights, 3, 1.3) // volume
    array.set(weights, 4, 1.2) // rvol
    array.set(weights, 5, 1.0) // delta
    array.set(weights, 6, 1.2) // sniper
    array.set(weights, 7, 1.0) // blocks
    array.set(weights, 8, 1.0) // tick
    array.set(weights, 9, 1.0) // pattern
else if marketType == "Bear"
    array.set(weights, 0, 2.0)
    array.set(weights, 1, 1.5)
    array.set(weights, 2, 2.0)
    array.set(weights, 3, 1.5)
    array.set(weights, 4, 1.3)
    array.set(weights, 5, 1.1)
    array.set(weights, 6, 1.2)
    array.set(weights, 7, 1.1)
    array.set(weights, 8, 1.0)
    array.set(weights, 9, 1.0)
else
    // Default weights for other market types
    array.set(weights, 0, 1.0)
    array.set(weights, 1, 1.0)
    array.set(weights, 2, 1.0)
    array.set(weights, 3, 1.0)
    array.set(weights, 4, 1.0)
    array.set(weights, 5, 1.0)
    array.set(weights, 6, 1.0)
    array.set(weights, 7, 1.0)
    array.set(weights, 8, 1.0)
    array.set(weights, 9, 1.0)

// --- SCORING SYSTEM
base_score = 0.0
base_score := base_score + ((trend == 1 ? 20 : trend == -1 ? -20 : 0) * array.get(weights, 0))
base_score := base_score + ((rsi_val > 70 ? -10 : rsi_val < 30 ? 10 : 0) * array.get(weights, 1))
base_score := base_score + ((macdLine > signalLine ? 10 : -10) * array.get(weights, 2))
base_score := base_score + ((volume > vol_abs_thresh ? 8 : volume < sma_vol20 ? -8 : 0) * array.get(weights, 3))
base_score := base_score + ((rvol > 1.5 ? 7 : rvol < 0.8 ? -7 : 0) * array.get(weights, 4))
base_score := base_score + ((delta > 0 ? 6 : -6) * array.get(weights, 5))
base_score := base_score + ((volume > sniper_thresh ? 8 : volume < sma_vol20 ? -8 : 0) * array.get(weights, 6))
base_score := base_score + ((volume > ta.highest(volume, 10) * 0.8 ? 5 : volume < sma_vol20 ? -5 : 0) * array.get(weights, 7))
base_score := base_score + ((volume > sma_vol20 ? 5 : -5) * array.get(weights, 8))
base_score := base_score + ((pattern == 1 ? 7 : pattern == 2 ? 5 : 0) * array.get(weights, 9))

score_pct = math.max(0, math.min(100, 50 + base_score))

// === STRATEGY LOGIC ===
longCond = (marketType == "Bull" or marketType == "Eagle" or marketType == "Momentum") and score_pct > 65
shortCond = (marketType == "Bear" or marketType == "Wolf") and score_pct < 35

if longCond and strategy.position_size <= 0
    strategy.entry("LONG", strategy.long)
    alert("LONG entry: Market " + marketType, alert.freq_once_per_bar)
if shortCond and strategy.position_size >= 0
    strategy.entry("SHORT", strategy.short)
    alert("SHORT entry: Market " + marketType, alert.freq_once_per_bar)
if not longCond and strategy.position_size > 0
    strategy.close("LONG", comment="Exit LONG")
if not shortCond and strategy.position_size < 0
    strategy.close("SHORT", comment="Exit SHORT")