Estratégia de negociação do indicador Balance Line PSAR
ChaoZhang
Esta estratégia combina o uso de gráficos de linhas de equilíbrio e indicadores de PSAR para julgar tendências e gerar sinais de negociação. A estratégia usa a característica de redução de ruído da linha de equilíbrio, em conjunto com os indicadores de PSAR para determinar os pontos de reversão de tendências, para capturar a tendência da linha média e longa.
Princípios da estratégia:
Calcule o preço de abertura, o preço de fechamento, o preço máximo e o preço mínimo da linha de equilíbrio.
A tendência para a multiplicação de cabeças e cabeças vazias é julgada de acordo com a cor das entidades da linha de equilíbrio.
Calcular o indicador de PSAR para determinar a reversão de tendência quando ele é quebrado de cima para baixo ou de baixo para cima
Quando a linha de equilíbrio é dupla, o PSAR faz mais para baixo; quando a linha de equilíbrio está vazia, o PSAR faz mais para cima.
O PSAR se adapta de acordo com os novos altos, baixos e fatores de aceleração.
Os benefícios da estratégia:
Linha de equilíbrio filtra o ruído, captura de inversão PSAR. A combinação aumenta a precisão.
Os parâmetros do PSAR se adaptam e respondem às mudanças do mercado.
As regras são claras e fáceis de usar, o que facilita a otimização dos parâmetros.
Os riscos desta estratégia:
A linha de equilíbrio e o PSAR estão atrasados, podendo perder os melhores pontos de entrada.
O PSAR é vulnerável a sinais errados sob uma tendência de tremor.
A gestão rigorosa dos fundos é necessária para proteger contra o risco de inversão.
Em resumo, a estratégia julga a tendência geral através da linha de equilíbrio, o PSAR identifica pontos de entrada específicos e realiza operações de rastreamento de tendências. Os problemas de atraso e o risco de falsas reversões precisam ser alertas, mas podem obter retornos estáveis a longo prazo com a otimização.
/*backtest
start: 2023-08-12 00:00:00
end: 2023-09-11 00:00:00
period: 2h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=4
strategy("QuantNomad - Heikin-Ashi PSAR Strategy", shorttitle = "HA-PSAR[QN]", overlay = false)
////////////
// INPUTS //
start = input(0.02, title = "PSAR Start")
increment = input(0.02, title = "PSAR Increment")
maximum = input(0.2, title = "PSAR Max")
start_year = input(2018, 'Start Year', input.integer)
start_month = input(1, 'Start Month', input.integer)
start_day = input(1, 'Start Day', input.integer)
end_year = input(2100, 'End Year', input.integer)
end_month = input(1, 'End Month', input.integer)
end_day = input(1, 'End Day', input.integer)
date_start = timestamp(start_year, start_month, start_day, 00, 00)
date_end = timestamp(end_year, end_month, end_day, 00, 00)
// if time is in correct period
time_cond = time >= date_start and time <= date_end
// Calculation HA Values
haopen = 0.0
haclose = (open + high + low + close) / 4
haopen := na(haopen[1]) ? (open + close) / 2 : (haopen[1] + haclose[1]) / 2
hahigh = max(high, max(haopen, haclose))
halow = min(low, min(haopen, haclose))
// HA colors
hacolor = haclose > haopen ? color.green : color.red
psar = 0.0 // PSAR
af = 0.0 // Acceleration Factor
trend_dir = 0 // Current direction of PSAR
ep = 0.0 // Extreme point
trend_bars = 0
sar_long_to_short = trend_dir[1] == 1 and haclose <= psar[1] // PSAR switches from long to short
sar_short_to_long = trend_dir[1] == -1 and haclose >= psar[1] // PSAR switches from short to long
trend_change = barstate.isfirst[1] or sar_long_to_short or sar_short_to_long
// Calculate trend direction
trend_dir := barstate.isfirst[1] and haclose[1] > haopen[1] ? 1 :
barstate.isfirst[1] and haclose[1] <= haopen[1] ? -1 :
sar_long_to_short ? -1 :
sar_short_to_long ? 1 : nz(trend_dir[1])
trend_bars := sar_long_to_short ? -1 :
sar_short_to_long ? 1 :
trend_dir == 1 ? nz(trend_bars[1]) + 1 :
trend_dir == -1 ? nz(trend_bars[1]) - 1 :
nz(trend_bars[1])
// Calculate Acceleration Factor
af := trend_change ? start :
(trend_dir == 1 and hahigh > ep[1]) or
(trend_dir == -1 and low < ep[1]) ?
min(maximum, af[1] + increment) :
af[1]
// Calculate extreme point
ep := trend_change and trend_dir == 1 ? hahigh :
trend_change and trend_dir == -1 ? halow :
trend_dir == 1 ? max(ep[1], hahigh) :
min(ep[1], halow)
// Calculate PSAR
psar := barstate.isfirst[1] and haclose[1] > haopen[1] ? halow[1] :
barstate.isfirst[1] and haclose[1] <= haopen[1] ? hahigh[1] :
trend_change ? ep[1] :
trend_dir == 1 ? psar[1] + af * (ep - psar[1]) : psar[1] - af * (psar[1] - ep)
plotcandle(haopen, hahigh, halow, haclose, title = "HA", color = hacolor)
plot(psar, style=plot.style_cross, color=trend_dir == 1 ? color.green : color.red, linewidth = 2)
// Strategy
strategy.entry("long", true, when = sar_short_to_long and time_cond)
strategy.entry("short", false, when = sar_long_to_short and time_cond)