اسے تھرموسٹیٹ کیوں کہا جاتا ہے؟ ہم نے اس سسٹم کا نام مارکیٹ، سوئنگ اور ٹرینڈ موڈ دونوں میں سوئچ اور ٹریڈ کرنے کے لیے اس کی موافقت کی بنیاد پر رکھا ہے۔ یہ نظام مارکیٹ کے مخصوص حصوں میں مخصوص نظاموں کی کامیابی کے ہمارے مشاہدے سے اخذ کیا گیا تھا۔ یہ نظام مارکیٹ کے دونوں طریقوں سے فائدہ اٹھانے کے لیے دوہری نوعیت کے ساتھ حکمت عملی بنانے کی اجازت دیتا ہے۔

سب سے پہلے، ہم مارکیٹ کے پیٹرن کا تعین کرنے میں مدد کے لیے ایک فنکشن بناتے ہیں۔ اس فنکشن کے آؤٹ پٹ کی بنیاد پر، تھرموسٹیٹ مندرجہ ذیل موڈ سے شارٹ ٹرم سوئنگ موڈ میں سوئچ کرتا ہے۔

ٹرینڈ فالونگ موڈ ایک ٹرینڈ فالونگ میکانزم کا استعمال کرتا ہے جیسا کہ بولنگر بینڈز میں پایا جاتا ہے۔ قلیل مدتی سوئنگ سسٹم ایک کھلا بریک آؤٹ ہے جو پیٹرن کی شناخت کو شامل کرتا ہے۔ یہ فنکشن اس فاصلے کا موازنہ کرتا ہے جو مارکیٹ گھومتی ہے اس فاصلے سے جو مارکیٹ نے طے کی ہے:

Abs(بند ہونے والی قیمت - اختتامی قیمت[29])/(سب سے زیادہ قیمت (30) - سب سے کم قیمت (کم قیمت، 30 دن) * 100

یہ فنکشن 0 اور 100 کے درمیان ایک قدر پیدا کرتا ہے۔ قیمت جتنی بڑی ہوگی، موجودہ مارکیٹ میں بھیڑ اتنی ہی کم ہوگی۔ اگر فنکشن کے ذریعے واپس کی گئی قدر 20 سے کم ہے، تو نظام مختصر مدت کے سوئنگ موڈ میں داخل ہوتا ہے۔

بنیادی طور پر، مارکیٹ زیادہ تر جھول کی کارروائی دکھا رہی ہے اور نظام اس جھول کو پکڑنے اور اس سے تھوڑا سا منافع لینے کی کوشش کرتا ہے۔ ترموسٹیٹ چھوٹے بازار کے اثرات کو خرید/فروخت کرکے اس کارنامے کو پورا کرنے کی کوشش کرتے ہیں۔ اگر اتار چڑھاو کافی بڑا ہے، تو سسٹم موڈز کو سوئچ کرتا ہے۔

مختصر مدت کے اتار چڑھاو کے گہرائی سے تجزیہ کے ذریعے، ہم نے پایا کہ بعض اوقات بیچنے سے خریدنا بہتر ہوتا ہے، اور اس کے برعکس۔ ان اوقات کی شناخت سادہ بصری نمونوں کے ذریعے کی جا سکتی ہے۔ اگر آج کا بند کل کی بلندی، کم اور قریب سے اوپر ہے (جسے دن کا محور نقطہ بھی کہا جاتا ہے)، تو ہمیں یقین ہے کہ کل کی مارکیٹ ایکشن مندی کا امکان ہے۔ تاہم، اگر آج کا بند کل کی بلندی، کم اور بند کی اوسط سے کم ہے، تو آج کی مارکیٹ میں تیزی کا امکان ہے۔ ہم ان اوقات کو خرید و فروخت میں آسان کے طور پر درجہ بندی کرتے ہیں۔

موجد مقداری پلیٹ فارم پر ترموسٹیٹ حکمت عملی ایک بہت ہی مقبول حکمت عملی ہے تاکہ صارف حکمت عملی کو بہتر کارکردگی کا مظاہرہ کرنے کے لیے کچھ اضافی تجارتی منطق شامل کر سکیں۔

• اہم تصویر: اپر ریل فارمولا: TOP^^MAC+N_TMPTMP؛ // بولنگر چینل اپر ریل لوئر ٹریک فارمولا: BOTTOM^^MAC-N_TMPTMP؛ // بولنگر چینل لوئر ٹریک

• ذیلی تصویر: CMI فارمولا: CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100؛ //0-100 قدر جتنی بڑی ہوگی، CMI <20 دوغلی موڈ کی نشاندہی کرتا ہے، CMI>20 رجحان کی نشاندہی کرتا ہے۔

• کوڈ (میری زبان):

MAC:=MA(CLOSE,N);
TMP:=STD(CLOSE,N);
TOP^^MAC+N_TMP*TMP;      // 布林通道上轨
BOTTOM^^MAC-N_TMP*TMP;   // 布林通道下轨
BBOLL:=C>MAC;
SBOLL:=C<MAC;
N_CMI:=30;

CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; //0-100 取值越大，说明趋势越强，CMI<20震荡模式，CMI>20为趋势

N_KD:=9;
M1:=3;
M2:=3;
RSV:=(CLOSE-LLV(LOW,N_KD))/(HHV(HIGH,N_KD)-LLV(LOW,N_KD))*100; //收盘价与N周期最低值做差，N周期最高值与N周期最低值做差，两差之间做比值。

K:=SMA(RSV,M1,1); //RSV的移动平均值
D:=SMA(K,M2,1);   //K的移动平均值
MIND:=30;
BKD:=K>D AND D<MIND;
SKD:=K<D AND D>100-MIND;

// 震荡模式
BUYPK1:=CMI < 20 AND BKD;  //震荡多单买平开
SELLPK1:=CMI < 20 AND SKD; //震荡空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY1:=REF(CMI,BARSBK) < 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND K<D; //震荡多单止盈
BUYY1:=REF(CMI,BARSSK) < 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND K>D;  //震荡空单止盈

// 趋势模式
BUYPK2:=CMI >= 20 AND C > TOP;        // 趋势多单买平开
SELLPK2:=CMI >= 20 AND C < BOTTOM;    // 趋势空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY2:=REF(CMI,BARSBK) >= 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND SBOLL;//趋势多单止盈
BUYY2:=REF(CMI,BARSSK) >= 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND BBOLL;//趋势空单止盈
SELLS2:=REF(CMI,BARSBK) >= 20 AND C<BKPRICE*(1-0.01*STOPLOSS) AND SBOLL;//趋势多单止损
BUYS2:=REF(CMI,BARSSK) >= 20 AND C>SKPRICE*(1+0.01*STOPLOSS) AND BBOLL;//趋势空单止损

IF BARPOS>N THEN BEGIN
    BUYPK1,BPK;
    SELLPK1,SPK;
    BUYPK2,BPK;
    SELLPK2,SPK;
END
BUYY1,BP(SKVOL);
BUYY2,BP(SKVOL);
BUYS2,BP(SKVOL);
SELLY1,SP(BKVOL);
SELLY2,SP(BKVOL);
SELLS2,SP(BKVOL);

اس حکمت عملی کے پس پردہ نتائج درج ذیل ہیں:

مزید تفصیلات کے لیے، براہ کرم دیکھیں: https://www.fmz.com/strategy/129086