Mengapa disebut termostat? Kami menamai sistem ini berdasarkan kemampuan adaptasinya untuk beralih dan berdagang dalam mode pasar, ayunan, dan tren. Sistem ini berasal dari pengamatan kami terhadap keberhasilan sistem tertentu di segmen pasar tertentu. Sistem ini memungkinkan terciptanya strategi dengan sifat ganda untuk memanfaatkan kedua mode pasar.

Pertama, kami membuat fungsi untuk membantu menentukan pola pasar. Berdasarkan keluaran fungsi ini, termostat beralih dari mode berikut ke mode ayunan jangka pendek.

Mode mengikuti tren menggunakan mekanisme mengikuti tren yang serupa dengan yang ditemukan di Bollinger Bands. Sistem ayunan jangka pendek adalah terobosan terbuka yang menggabungkan pengenalan pola. Fungsi ini membandingkan jarak yang telah ditempuh pasar dengan jarak sebenarnya yang telah ditempuh pasar:

Abs(Harga Penutupan - Harga Penutupan[29])/(Harga tertinggi (30) - Harga terendah (harga terendah, 30 hari) * 100

Fungsi ini menghasilkan nilai antara 0 dan 100. Makin besar nilainya, makin sepi pasar saat itu. Jika nilai yang dikembalikan oleh fungsi kurang dari 20, sistem memasuki mode ayunan jangka pendek.

Pada dasarnya, pasar sebagian besar menunjukkan aksi yang berayun dan sistem mencoba menangkap ayunan tersebut dan mengambil sedikit keuntungan darinya. Termostat mencoba mencapai prestasi ini dengan membeli/menjual impuls pasar kecil. Jika fluktuasi cukup besar, sistem akan berganti mode.

Melalui analisis mendalam terhadap fluktuasi jangka pendek, kami menemukan bahwa terkadang lebih baik membeli daripada menjual, dan sebaliknya. Waktu-waktu ini dapat diidentifikasi melalui pola visual yang sederhana. Jika harga penutupan hari ini berada di atas harga tertinggi, terendah, dan penutupan kemarin (juga dikenal sebagai titik tumpu hari), maka kami yakin pergerakan pasar besok kemungkinan besar akan menurun. Namun, jika harga penutupan hari ini lebih rendah dari harga rata-rata tertinggi, terendah, dan penutupan kemarin, maka pasar hari ini kemungkinan besar sedang bullish. Kami mengklasifikasikan waktu-waktu ini sebagai waktu yang lebih mudah untuk membeli dan menjual.

Strategi termostat merupakan strategi yang sangat populer di Inventor Quantitative Platform. Pengguna dapat menambahkan beberapa logika perdagangan tambahan sesuai dengan kebutuhan mereka untuk membuat strategi tersebut berkinerja lebih baik. Berikut ini adalah kerangka kerja umum strategi termostat di Inventor Quantitative Platform:

• Gambar utama: Rumus rel atas: TOP^^MAC+N_TMPTMP; // Rel atas saluran Bollinger Rumus jalur bawah: BOTTOM^^MAC-N_TMPTMP; // jalur bawah saluran Bollinger

• Sub-gambar: Rumus CMI: CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; //0-100 Semakin besar nilainya, semakin kuat trennya. CMI<20 menunjukkan mode osilasi, CMI>20 menunjukkan tren.

• Kode (Bahasa saya):

MAC:=MA(CLOSE,N);
TMP:=STD(CLOSE,N);
TOP^^MAC+N_TMP*TMP;      // 布林通道上轨
BOTTOM^^MAC-N_TMP*TMP;   // 布林通道下轨
BBOLL:=C>MAC;
SBOLL:=C<MAC;
N_CMI:=30;

CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; //0-100 取值越大，说明趋势越强，CMI<20震荡模式，CMI>20为趋势

N_KD:=9;
M1:=3;
M2:=3;
RSV:=(CLOSE-LLV(LOW,N_KD))/(HHV(HIGH,N_KD)-LLV(LOW,N_KD))*100; //收盘价与N周期最低值做差，N周期最高值与N周期最低值做差，两差之间做比值。

K:=SMA(RSV,M1,1); //RSV的移动平均值
D:=SMA(K,M2,1);   //K的移动平均值
MIND:=30;
BKD:=K>D AND D<MIND;
SKD:=K<D AND D>100-MIND;

// 震荡模式
BUYPK1:=CMI < 20 AND BKD;  //震荡多单买平开
SELLPK1:=CMI < 20 AND SKD; //震荡空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY1:=REF(CMI,BARSBK) < 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND K<D; //震荡多单止盈
BUYY1:=REF(CMI,BARSSK) < 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND K>D;  //震荡空单止盈

// 趋势模式
BUYPK2:=CMI >= 20 AND C > TOP;        // 趋势多单买平开
SELLPK2:=CMI >= 20 AND C < BOTTOM;    // 趋势空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY2:=REF(CMI,BARSBK) >= 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND SBOLL;//趋势多单止盈
BUYY2:=REF(CMI,BARSSK) >= 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND BBOLL;//趋势空单止盈
SELLS2:=REF(CMI,BARSBK) >= 20 AND C<BKPRICE*(1-0.01*STOPLOSS) AND SBOLL;//趋势多单止损
BUYS2:=REF(CMI,BARSSK) >= 20 AND C>SKPRICE*(1+0.01*STOPLOSS) AND BBOLL;//趋势空单止损

IF BARPOS>N THEN BEGIN
    BUYPK1,BPK;
    SELLPK1,SPK;
    BUYPK2,BPK;
    SELLPK2,SPK;
END
BUYY1,BP(SKVOL);
BUYY2,BP(SKVOL);
BUYS2,BP(SKVOL);
SELLY1,SP(BKVOL);
SELLY2,SP(BKVOL);
SELLS2,SP(BKVOL);

Hasil backtest dari strategi ini adalah sebagai berikut:

Untuk keterangan lebih lanjut, silakan lihat: https://www.fmz.com/strategy/129086