Mengapa ia dipanggil termostat? Kami menamakan sistem ini berdasarkan kebolehsuaiannya untuk menukar dan berdagang dalam kedua-dua mod pasaran, swing dan trend. Sistem ini diperoleh daripada pemerhatian kami terhadap kejayaan sistem tertentu dalam segmen pasaran tertentu. Sistem ini membolehkan penciptaan strategi dengan sifat dwi untuk memanfaatkan kedua-dua mod pasaran.

Pertama, kami mencipta fungsi untuk membantu menentukan corak pasaran. Berdasarkan output fungsi ini, termostat bertukar daripada mod berikut kepada mod ayunan jangka pendek.

Mod mengikut arah aliran menggunakan mekanisme mengikut aliran yang serupa dengan yang terdapat dalam Bollinger Bands. Sistem ayunan jangka pendek ialah pelarian terbuka yang menggabungkan pengecaman corak. Fungsi ini membandingkan jarak yang telah dilalui oleh pasaran dengan jarak sebenar yang telah dilalui oleh pasaran:

Abs(Harga Tutup - Harga Tutup[29])/(Harga tertinggi (30) - Harga terendah (harga rendah, 30 hari) * 100

Fungsi ini menjana nilai antara 0 dan 100. Semakin besar nilai, semakin kurang sesak pasaran semasa. Jika nilai yang dikembalikan oleh fungsi kurang daripada 20, sistem memasuki mod ayunan jangka pendek.

Pada asasnya, pasaran kebanyakannya menunjukkan tindakan berayun dan sistem cuba menangkap hayunan dan mengambil keuntungan kecil daripadanya. Termostat cuba mencapai kejayaan ini dengan membeli/menjual impuls pasaran kecil. Jika turun naik cukup besar, sistem menukar mod.

Melalui analisis mendalam tentang turun naik jangka pendek, kami mendapati kadangkala adalah lebih baik untuk membeli daripada menjual, dan begitu juga sebaliknya. Masa-masa ini boleh dikenal pasti melalui corak visual yang mudah. Jika penutupan hari ini melebihi tinggi, rendah dan penutup semalam (juga dikenali sebagai titik pangsi hari ini), maka kami percaya tindakan pasaran esok berkemungkinan menurun. Walau bagaimanapun, jika penutupan hari ini adalah di bawah purata paras tinggi, rendah dan penutup semalam, maka pasaran hari ini berkemungkinan meningkat. Kami mengklasifikasikan masa ini sebagai lebih mudah untuk membeli dan menjual.

Strategi termostat ialah strategi yang sangat popular pada Platform Kuantitatif Pencipta Pengguna boleh menambah beberapa logik perdagangan tambahan mengikut keperluan mereka untuk menjadikan strategi berprestasi lebih baik Berikut ialah rangka kerja tipikal strategi termostat pada Platform Kuantitatif Pencipta.

• Imej utama: Formula rel atas: TOP^^MAC+N_TMPTMP; // Rel atas saluran Bollinger Formula trek bawah: BOTTOM^^MAC-N_TMPTMP; // Bollinger saluran bawah trek

• Sub-imej: Formula CMI: CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; //0-100 Semakin besar nilai, semakin kuat aliran CMI<20 menunjukkan mod ayunan, CMI>20 menunjukkan arah aliran.

• Kod (Bahasa saya):

MAC:=MA(CLOSE,N);
TMP:=STD(CLOSE,N);
TOP^^MAC+N_TMP*TMP;      // 布林通道上轨
BOTTOM^^MAC-N_TMP*TMP;   // 布林通道下轨
BBOLL:=C>MAC;
SBOLL:=C<MAC;
N_CMI:=30;

CMI:ABS(C-REF(C,N_CMI-1))/(HHV(H,N_CMI)-LLV(L,N_CMI))*100; //0-100 取值越大，说明趋势越强，CMI<20震荡模式，CMI>20为趋势

N_KD:=9;
M1:=3;
M2:=3;
RSV:=(CLOSE-LLV(LOW,N_KD))/(HHV(HIGH,N_KD)-LLV(LOW,N_KD))*100; //收盘价与N周期最低值做差，N周期最高值与N周期最低值做差，两差之间做比值。

K:=SMA(RSV,M1,1); //RSV的移动平均值
D:=SMA(K,M2,1);   //K的移动平均值
MIND:=30;
BKD:=K>D AND D<MIND;
SKD:=K<D AND D>100-MIND;

// 震荡模式
BUYPK1:=CMI < 20 AND BKD;  //震荡多单买平开
SELLPK1:=CMI < 20 AND SKD; //震荡空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY1:=REF(CMI,BARSBK) < 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND K<D; //震荡多单止盈
BUYY1:=REF(CMI,BARSSK) < 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND K>D;  //震荡空单止盈

// 趋势模式
BUYPK2:=CMI >= 20 AND C > TOP;        // 趋势多单买平开
SELLPK2:=CMI >= 20 AND C < BOTTOM;    // 趋势空单卖平开

// 趋势模式下原有震荡持仓的处理
SELLY2:=REF(CMI,BARSBK) >= 20 AND C>BKPRICE*(1+0.01*STOPLOSS*3) AND SBOLL;//趋势多单止盈
BUYY2:=REF(CMI,BARSSK) >= 20 AND C<SKPRICE*(1-0.01*STOPLOSS*3) AND BBOLL;//趋势空单止盈
SELLS2:=REF(CMI,BARSBK) >= 20 AND C<BKPRICE*(1-0.01*STOPLOSS) AND SBOLL;//趋势多单止损
BUYS2:=REF(CMI,BARSSK) >= 20 AND C>SKPRICE*(1+0.01*STOPLOSS) AND BBOLL;//趋势空单止损

IF BARPOS>N THEN BEGIN
    BUYPK1,BPK;
    SELLPK1,SPK;
    BUYPK2,BPK;
    SELLPK2,SPK;
END
BUYY1,BP(SKVOL);
BUYY2,BP(SKVOL);
BUYS2,BP(SKVOL);
SELLY1,SP(BKVOL);
SELLY2,SP(BKVOL);
SELLS2,SP(BKVOL);

Keputusan backtest strategi ini adalah seperti berikut:

Untuk butiran lanjut, sila lihat: https://www.fmz.com/strategy/129086