多指标动态波动管理突破策略

/*backtest
start: 2024-07-29 00:00:00
end: 2025-07-27 08:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT"}]
*/

//@version=5
strategy("MVO - MA Signal Strategy", overlay=true, default_qty_type=strategy.percent_of_equity, default_qty_value=100)
inDateRange = true 
source = close

// === HEIKIN ASHI ===
haOpen  = request.security(syminfo.tickerid, timeframe.period, (nz(open[1]) + nz(close[1]) ) / 2)
haClose = request.security(syminfo.tickerid, timeframe.period, (low + high + open + close )/4)
haHigh  = request.security(syminfo.tickerid, timeframe.period, math.max(high, math.max((haOpen[1] + haClose[1]) / 2, (open + high + low + close) / 4)))
haLow   = request.security(syminfo.tickerid, timeframe.period, math.min(low, math.min((haOpen[1] + haClose[1]) / 2, (open + high + low + close) / 4)))
isGreen = haClose > haLow[1]
isRed = haClose < haLow[1]

// === INPUTS === //
maLength   = input.int(55, "MA Period")
atrLength  = input.int(5, "ATR Period")
mfiLength  = input.int(5, "MFI Period")
riskMult   = input.float(1.0, "SL Multiplier (xATR)")
rewardMult = input.float(5.0, "TP Multiplier (xATR)")
breakevenTicks = input.float(2, "Move to Breakeven After (xATR)")
trailATRmult = input.float(1.5, "Trailing Stop After BE (xATR)")
enableTrailingStop = input.bool(true, "Enable Trailing Stop")
enableBreakeven = input.bool(true, "Enable Break Even")
showBreakEvenLine = input.bool(true, "Show Break Even Line")
enableLong  = input.bool(true, "Allow Long Trades")
enableShort = input.bool(true, "Allow Short Trades")

// === MA + ATR === //
ma  = ta.sma(close, maLength)
atr = ta.atr(atrLength)
//────────────────────────────────────────────────────────────────────────────
// 1. Dashboard Table Setup
//────────────────────────────────────────────────────────────────────────────
dashboardLocation = input.string("Bottom Right", "Dashboard Location", group="Dashboard", options=["Top Right", "Bottom Right", "Bottom Left"])
textSizeOption     = input.string("Tiny", "Text Size", group="Dashboard", options=["Tiny", "Small", "Normal"])
tablePos           = str.replace(str.lower(dashboardLocation), " ", "_")
dashTextSize       = str.lower(textSizeOption)
var tbl = table.new(tablePos, 3, 4, bgcolor=#1e222d, border_color=#373a46, border_width=1, frame_color=#373a46, frame_width=1)


// === Trade state === //
var float entryPrice = na
var float stopPrice = na
var float takePrice = na
var float breakevenLevel = na
var bool inTrade = false
var bool isLong = false
var bool movedToBE = false

// === Signals === //
longSignal  = enableLong and ( ta.cross(haClose, ma) or (ta.mfi(haLow,mfiLength) < 20 and haClose > ma)) 
shortSignal = enableShort and (ta.crossunder(haClose, ma) or (ta.mfi(haClose,mfiLength) > 90 and haClose < ma)) 

// === Trade Logic === //
if not inTrade and inDateRange
    if longSignal
        entryPrice := close
        stopPrice := close - riskMult * atr
        takePrice := close + rewardMult * atr
        breakevenLevel := close + breakevenTicks * atr
        isLong := true
        inTrade := true
        movedToBE := false
        strategy.entry("Long", strategy.long)
    else if shortSignal
        entryPrice := close
        stopPrice := close + riskMult * atr
        takePrice := close - rewardMult * atr
        breakevenLevel := close - breakevenTicks * atr
        isLong := false
        inTrade := true
        movedToBE := false
        strategy.entry("Short", strategy.short)

// === Dynamic Exit Logic === //
var float trailStop = na

// Trigger break-even move
if inTrade and not movedToBE and enableBreakeven
    if isLong and high >= breakevenLevel
        stopPrice := entryPrice
        movedToBE := true
    else if not isLong and low <= breakevenLevel
        stopPrice := entryPrice
        movedToBE := true

// Trailing stop logic
if inTrade and movedToBE and enableTrailingStop
    if isLong
        trailStop := math.max(stopPrice, close - trailATRmult * atr)
        stopPrice := trailStop
    else
        trailStop := math.min(stopPrice, close + trailATRmult * atr)
        stopPrice := trailStop

// Set strategy exit dynamically
if inTrade and inDateRange
    strategy.exit("Exit", from_entry = isLong ? "Long" : "Short", stop = stopPrice, limit = takePrice)

// Exit Detection for visuals
stopHit = isLong ? low <= stopPrice : high >= stopPrice
tpHit   = isLong ? high >= takePrice : low <= takePrice
exitTrade = inTrade and (stopHit or tpHit)

if exitTrade
    inTrade := false
    entryPrice := na
    stopPrice := na
    takePrice := na
    breakevenLevel := na
    movedToBE := false
    trailStop := na

• 多指标趋势突破动态止损交易系统
• 多周期均线回调与ATR动态止盈止损策略
• 双均线动量趋势追踪与反转交易系统
• 趋势过滤多均线交叉ATR风控量化策略
• 多均线趋势突破回踩交易系统与ATR动态止损
• RSI动量震荡波段雷达交易策略:基于ATR风险管理的RSI/MA交叉系统
• 波动压缩动量突破跟踪策略：TTM挤压指标的量化实现
• 均线，简单移动平均线，均线斜率，追踪止损，重新进场
• Z分数动量ATR止损策略结合风险收益比优化交易系统
• 增强趋势多重信号动态交易策略