কেন গ্রুপিং নির্দেশাবলী

কৌশল বিকাশকারীদের চাহিদা

বিভিন্ন পরিস্থিতির জন্য বিভিন্ন সূচক ব্যবহার করা প্রয়োজন। আমি কি বিভিন্ন স্টপ লস পার্থক্য সেট করতে পারি?

উদাহরণস্বরূপ, ঐতিহ্যগত মডেলটি পজিশন শর্তাবলী লিখতে বিভিন্ন পজিশন শর্তাবলীর মধ্যে পার্থক্য করে না।

নিম্নলিখিত কোডটি হল একটি সহজ, ঐতিহ্যবাহী, অ-বিভক্ত পজিশনিং কৌশলঃ

MA5^^MA(C,5);
MA10^^MA(C,10);
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K..SMA(RSV,3,1);
D..SMA(K,3,1);
CROSS(MA5,MA10)||CROSS(K,D),BK;
C>HV(H,10)||C<BKPRICE-5*MINPRICE,SP;
AUTOFILTER;

কিন্তু গ্রুপিং কমান্ড ব্যবহার করাটা অন্যরকম।

গ্রুপিং নির্দেশনাটি খোলার শর্তের জন্য n টি গোষ্ঠীতে বিভক্ত করা যেতে পারে, একটি গোষ্ঠীর শর্তাধীন খোলার অবস্থানটি কেবলমাত্র একটি গোষ্ঠীর সমান্তরাল অবস্থানের শর্তাধীন শর্তাদির সমান্তরাল হতে পারে, অন্য গোষ্ঠীর সমান্তরাল শর্তাদি পূরণ করা হয় না, বা এটি অর্পণ করা হয় না।

যেমন:

প্রথম গ্রুপঃ বহু শর্ত

MA5^^MA(C,5);
MA10^^MA(C,10);
CROSS(MA5,MA10),BK;
CROSS(MA10,MA5),SP;

দ্বিতীয় দলঃ একাধিক শর্তাদি

RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K..SMA(RSV,3,1);
D..SMA(K,3,1); 
CROSS(K,D),BK; 
C>HV(H,10)||C<BKPRICE-5*MINPRICE,SP;

কিন্তু আমরা কিভাবে একই মডেলের মধ্যে বিভিন্ন ধরণের শর্তকে আলাদা করতে পারি? আসুন আমরা তাদের বাস্তবায়ন করি।

গ্রুপিং কমান্ড লিখুন

প্রথমত, মডেলগুলি ফিল্টার করা এবং ফিল্টার না করা মডেলগুলিতে বিভক্তঃ

• ফিল্টারিং মডেলঃ বিভিন্ন খোলা অবস্থার জন্য বিভিন্ন সমতল অবস্থার জন্য সমতল অবস্থার জন্য, নির্দেশক গ্রুপিং ব্যবহার করে এটি বাস্তবায়ন করা যেতে পারে।

• অ-ফিল্টারিং মডেলঃ প্রথমবারের মতো প্রবেশের কৌশলটি পজিশনিংয়ের কৌশল থেকে আলাদা, আপনি যদি একটি পৃথক স্টপ-লস পজিশনিং কৌশল ব্যবহার করে পজিশনিং করতে চান তবে নির্দেশিকা গ্রুপিং ব্যবহার করে এটি বাস্তবায়ন করা যেতে পারে।

ফিল্টার মডেল

//A组指令
A组的开多条件,BK('A');
A组的开空条件,SK('A');
A组的平多条件,SP('A');
A组的平空条件,BP('A');

//B组指令
B组的开多条件,BPK('B');
B组的开空条件,SPK('B');
B组的平多条件,SP('B');
B组的平空条件,BP('B');
AUTOFILTER;//过滤函数

দ্রষ্টব্যঃ ফিল্টার মডেলের গ্রুপিং ট্রেডিং নির্দেশের পরে গ্রুপে যোগ করা এবং একক উদ্ধৃতি দিয়ে বন্ধ করা প্রয়োজন যেমন BK ((‘A’)

ফিল্টারহীন মডেল

//A组指令
A组的开多条件1,BK('A',2);
A组的开空条件1,SK('A',2);
A组的加多条件2,BK('A',1);
A组的加空条件2,SK('A',1);
A组的平多条件,SP('A',GROUPBKVOL('A'));
A组的平空条件,BP('A',GROUPSKVOL('A'));

//B组指令
B组的加多条件,BK('B',1);
B组的加空条件,SK('B',1);
B组的平多条件1,SP('B',GROUPBKVOL('B'));
B组的平空条件1,BP('B',GROUPSKVOL('B'));

দ্রষ্টব্যঃ অ-ফিল্টার মডেলের গ্রুপিংয়ের জন্য ট্রেডিং নির্দেশের পরে গ্রুপ এবং হাতের সংখ্যা যুক্ত করা প্রয়োজন। গ্রুপগুলিকে একক উদ্ধৃতি দিয়ে বন্ধ করা দরকার। যেমন BK ((‘A’,2)

গ্রুপিং নির্দেশাবলীর কার্যকারিতা

ফিল্টারিং মডেলঃ গ্রুপ ফিল্টার এবং সিগন্যাল ফিল্টার

• গ্রুপ ফিল্টারিং বলতে বোঝায়ঃ যদি পূর্ববর্তী কে লাইন সংকেতটি গ্রুপ এ থেকে প্রাপ্ত খোলার সংকেত হয় ((বিকে এসকে বিপিকে এসপিকে) বর্তমান কে লাইনটি কেবল গ্রুপ এ এর খালি সংকেত হতে পারে। যদি পূর্ববর্তী কে লাইন সংকেতটি গ্রুপ এ থেকে প্রাপ্ত খালি সংকেত হয় ((বিপি এসপি) বর্তমান কে লাইনটি যে কোনও গ্রুপের খোলার সংকেত হতে পারে। (প্রথম খোলার সংকেতটি সিগন্যালের ক্রমে নেওয়া)

• একত্রিত পজিশনের শর্তাবলী কেবলমাত্র একত্রিত পজিশনের শর্তাবলী পূরণ করতে পারে

সিগন্যাল ফিল্টারিং এর অর্থ হলঃ সিগন্যাল ফিল্টারিং

এখানে অগ্রাধিকার দেওয়া হলঃ

• উপরের K লাইনটি BK এবং বর্তমান K লাইনটি অবশ্যই SPK বা SP হতে হবে (SPK SP এর চেয়ে অগ্রাধিকার পায়, নিম্নলিখিত সমার্থক)
• উপরের K লাইনটি SK, বর্তমান K লাইনটি BPK বা BP হতে হবে
• উপরের K লাইনটি BP, বর্তমান K লাইনটি BK বা SK হতে হবে
• উপরের K লাইনটি SP, বর্তমান K লাইনটি BK বা SK হতে হবে।
• উপরের K লাইনটি BPK, বর্তমান K লাইনটি SPK বা SP হতে হবে
• উপরের K লাইনটি SPK এবং বর্তমান K লাইনটি BPK বা BP হতে হবে

ফিল্টারহীন মডেলঃ

• যদি পূর্ববর্তী সংকেতটি গ্রুপ এ থেকে প্রেরিত একটি খোলার সংকেত হয়, তবে পরবর্তী সংকেতটি গ্রুপ এ এর একটি বাড়ানো বা খালি সংকেত হওয়া উচিত।
• যদি পূর্ববর্তী সংকেতটি গ্রুপ এ-র পজিশন সিগন্যাল হয় এবং গ্রুপ এ-র পজিশন 0 হয়, তবে পরবর্তী সংকেতটি যে কোনও গ্রুপের পজিশন খোলার সংকেত হতে পারে।
• যদি গ্রুপ A এর অবস্থান 0 এর চেয়ে বড় হয়, তাহলে গ্রুপ A এর জন্য একটি খোলা বা প্যাসিভ সংকেত দিতে হবে।

দ্রষ্টব্যঃ অ-বিভাজিত সমতল অবস্থানের শর্তগুলি কেবলমাত্র অ-বিভাজিত সমতল অবস্থানের শর্তগুলি খুলতে পারে

গ্রুপিং নির্দেশের ক্ষেত্রে বিশ্লেষণ

এখন, আমরা কিছু কৌশল ব্যবহার করে দেখব কিভাবে কোডিংয়ের সময় এই নির্দেশাবলীকে একত্রিত করা হয়।

ফিল্টার মডেল

ট্রেডিং পদ্ধতিঃ প্রবণতা নির্ণয় করার জন্য 20 চক্র এবং 60 চক্রের গড় লিনিয়ার ফর্কের স্ট্যান্ডার্ড।

• 20 টি চক্রের গড় লাইন 60 টি চক্রের গড় লাইনের চেয়ে বড়। বিপরীতভাবে খালি।
• একটি মাল্টি ট্রেন্ডের মধ্যে, যদি সর্বোচ্চ মূল্য 10 টি k-লাইন নতুন উচ্চতা অতিক্রম করে এবং সূর্যের রেখা হয়, তবে ট্রেন্ডটি আরও বেশি। যখন পজিশন বন্ধ হয়, তখন পজিশনটি বন্ধ করার জন্য একটি বৃহত্তর স্টপ পয়েন্ট দিয়ে পজিশনটি বন্ধ করে দেওয়া হয় বা গড় লাইন ডাই ফর্ক পজিশন ঘটে। বিপরীতভাবে।
• যদি KDJ সূচকটি গোল্ডফোর্ক এবং সূর্যের রেখা হয়, তাহলে পজিশনটি আরও বেশি করা উচিত। যখন পজিশনটি বন্ধ হয়, তখন পজিশনটি বন্ধ করার জন্য একটি ছোট স্টপ পয়েন্ট বা পজিশনটি খোলার জন্য পজিশনটি খোলার জন্য সর্বনিম্ন পয়েন্টটি বন্ধ করুন।

কোড:

MA20^^MA(C,20);
MA60^^MA(C,60);
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
HH:=HV(H,10);
LL:=LV(L,10);
MA20>MA60&&H>HH&&C>O,BK('A');
MA20<MA60&&L<LL&&C<O,SK('A');
L<LV(L,5)||CROSSDOWN(MA20,MA60)||C<BKPRICE-5*MINPRICE,SP('A');
H>HV(H,5)||CROSSUP(MA20,MA60)||C>SKPRICE+5*MINPRICE,BP('A');//只平A组开仓
MA20>MA60&&CROSSUP(K,D)&&C>O,BK('B');
MA20<MA60&&CROSSDOWN(K,D)&&C<O,SK('B');
C>BKPRICE+5*MINPRICE||C<BKPRICE-2*MINPRICE||C<REF(L,BARSBK),SP('B');
C<SKPRICE-5*MINPRICE||C>SKPRICE+2*MINPRICE||C>REF(H,BARSSK),BP('B');//只平B组开仓
//不同的开仓条件开仓，用不同的平仓条件，有针对性的平仓。达到不同行情试用不同策略的目的。
AUTOFILTER;

ফিল্টারহীন মডেল

ট্রেডিং পদ্ধতিঃ প্রথমবারের মতো পজিশন খোলার শর্ত হিসাবে 5 টি এবং 10 টি চক্রের সমতুল্য লিনিয়ার ফর্কের ডাইফোর্ক।

• প্রথমবারের মতো পজিশন খোলার আগে 5 টি চক্র এবং 60 টি চক্রের গড় লাইন গোল্ড ফর্ক অতিরিক্ত পজিশন। প্রথমবারের মতো পজিশন খালি করার আগে 5 টি চক্র এবং 60 টি চক্রের গড় লাইন মৃত ফর্ক অতিরিক্ত পজিশন।
• 5 চক্রের চেয়ে বড় 60 চক্রের প্রবণতার অধীনে, সর্বোচ্চ মূল্য 10k লাইন নতুন উচ্চ, তারপর দ্বিতীয়বারের মত আরো পজিশন। 5 চক্রের চেয়ে ছোট 60 চক্রের প্রবণতার অধীনে, সর্বনিম্ন মূল্য 10k লাইন নতুন নিম্ন, তারপর দ্বিতীয়বার খালি পজিশন।
• প্রথমবারের জন্য অতিরিক্ত পজিশনের পরে, 5 টি k-লাইন তৈরি করে একটি নতুন নিম্ন বা ছোট স্টপ লস পজিশনের সমতল করুন। খালি খালি বিপরীত।
• দ্বিতীয়বারের জন্য অতিরিক্ত পজিশনের পরে, 5 টি চক্র এবং 60 টি চক্রের গড়রেখার সাথে মরা এবং খালি পজিশনের জন্য। খালি এবং বিপরীত।

কোড:

MA5^^MA(C,5);
MA10^^MA(C,10);
MA20:=MA(C,20);
MA60^^MA(C,60);
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
HH:=HV(H,10);
LL:=LV(L,10);
CROSSUP(MA5,MA10)&&BKVOL=0&&C>=O,BK('A',2);
CROSSDOWN(MA5,MA10)&&SKVOL=0&&C<=O,SK('A',2);
CROSSUP(MA5,MA60)&&ISLASTBK&&BKVOL=2,BK('A',1);
CROSSDOWN(MA5,MA60)&&ISLASTSK&&SKVOL=2,SK('A',1);
MA5>MA60&&H>HH&&ISLASTSP&&REF(GROUPBKVOL('A'),BARSSP+1)>0,BK('B',1);
MA5<MA60&&L<LL&&ISLASTBP&&REF(GROUPSKVOL('A'),BARSBP+1)>0,SK('B',1);
L<LV(L,5)||C<REF(L,BARSBK)&&(C<BKPRICE-2*MINPRICE),SP('A',GROUPBKVOL('A'));
H>HV(H,5)||C>REF(H,BARSSK)&&(C>SKPRICE+2*MINPRICE),BP('A',GROUPSKVOL('A'));
C>BKPRICE+10*MINPRICE||CROSSDOWN(MA5,MA60),SP('B',BKVOL);
C<SKPRICE-10*MINPRICE||CROSS(MA5,MA60),BP('B',SKVOL);

এই দুই ধরনের মডেলের উপর ভিত্তি করে, পাঠককে দেখানো হয়েছে যে মাই ভাষা কীভাবে গ্রুপিং নির্দেশাবলী পরিচালনা করে। আপনি আপনার নিজস্ব কৌশলগত যুক্তি অনুসারে বিভিন্ন গ্রুপিংয়ের প্রয়োজনীয়তা তৈরি করতে পারেন, যাতে আপনি যে কৌশলগত যুক্তিটি প্রকাশ করতে চান তা কোডের মধ্যে যথাসম্ভব পরিষ্কার এবং কম ত্রুটিযুক্ত উপায়ে প্রকাশ করতে পারেন।