यह लघु रणनीति प्रवेश समय के लिए NR7 और अंदर के दिनों को जोड़ती है।
तर्क यह हैः
NR7 की पहचान करें, जहां 7 दिनों में सीमा सबसे संकीर्ण है
दिन के भीतर की पहचान करें, उच्च पिछले उच्च से कम और निम्न पिछले निम्न से अधिक के साथ
उन दिनों में जब NR7 और अंदर का दिन मेल खाता है, और बंद खुला से कम है
और सरल चलती औसत ढलान नीचे है, शॉर्ट जाओ
अगले दिन बंद होने पर खुले से कम कवर करें
यह रणनीति NR7 और अंदर के दिनों पर ध्यान केंद्रित करती है जो भीड़भाड़ को इंगित करती है। एमए ढलान और समापन मूल्य फिल्टर के साथ संयुक्त, यह कम दक्षता में सुधार करती है।
NR7 और दिन के भीतर समय की उलट
झूठे संकेतों से बचने के लिए स्थितियों का संयोजन
वैकल्पिक दीर्घ/लघु संचालन
एनआर7 प्लस दिन के अंदर कम आम
एमए पैरामीटर अनुकूलन की आवश्यकता है
केवल शॉर्ट्स लंबे अवसरों को याद करते हैं
यह रणनीति प्रभावी ढंग से रिवर्स की पहचान और पुष्टि करके शॉर्ट्स करती है। लेकिन कम आवृत्ति मूल्यांकन की आवश्यकता है। पैरामीटर ट्यूनिंग और लंबी / छोटी ट्रेडिंग रणनीति का विस्तार कर सकती है।
/*backtest
start: 2023-08-14 00:00:00
end: 2023-09-13 00:00:00
period: 4h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=2
strategy("NR7ID: Narrow Range + Inside Day, Short Only Strategy (by ChartArt)", shorttitle="CA_-_NR7ID_Short_Strat", overlay=true) // max_bars_back=5000
// ChartArt's Narrow Range + Inside Day Strategy (Short Only)
//
// Version 1.1
// Idea by ChartArt on Oktober 22, 2016.
//
// This short only strategy determines when there is both
// a NR7 (narrow range 7, a trading day in which the range
// is narrower than any of the previous six days), plus a
// inside day (high of the current day is lower than the high
// of the previous day and the low of the current day is higher
// than the low of the previous day) both on the same trading day
// and enters a short trade when the close is lower than the
// open and the slope of the simple moving average is downwards, too.
//
// The strategy exits the short trade next time the close is
// lower than the open in any of the next trading days.
//
// In addition the NR7ID can be colored (if close lower open
// colored in red, else in green) and the SMA can be drawn
// with a color based on the direction of the SMA slope.
//
// List of my work:
// https://www.tradingview.com/u/ChartArt/
//
// __ __ ___ __ ___
// / ` |__| /\ |__) | /\ |__) |
// \__, | | /~~\ | \ | /~~\ | \ |
//
//
// NR7 Identifier
show_NR7=input(true, type=bool,title="Show Narrow Range 7 (NR7) ?")
range=(high-low)
nr7=(range < range[1]) and (range < range[2]) and (range < range[3]) and (range < range[4]) and (range < range[5]) and (range < range[6])
plotchar(show_NR7?nr7:na, char="7", location=location.abovebar, color=blue)
// Inside Day Identifier
show_insidebar = input(true, type=bool,title="Show Inside Day (I) ?")
insidebar = (high < high[1] and low > low[1])
plotchar(show_insidebar?insidebar:na, char="i", location=location.abovebar, color=blue)
// NR7 + Inside Day Identifier
show_NR7ID_bear = input(true, type=bool,title="Show NR7ID (NR7 + Inside Day) bear color ?")
NR7ID = nr7 and insidebar
NR7ID_bear_color = NR7ID and open > close ? red : na
barcolor(show_NR7ID_bear?NR7ID_bear_color:na)
show_NR7ID_bull = input(false, type=bool,title="Show NR7ID (NR7 + Inside Day) bull color ?")
NR7ID_bull_color = NR7ID and open < close ? green : na
barcolor(show_NR7ID_bull?NR7ID_bull_color:na)
// Simple Moving Average
show_ma = input(true, type=bool,title="Show SMA ?")
ma_length = input(14,title="SMA Length")
ma = sma(close,ma_length)
ma_change = change(ma) > 0
ma_change_color = change(ma) > 0 ? green : change(ma) < 0 ? red : blue
plot(show_ma?ma:na,color=ma_change_color,linewidth=3)
// Short Strategy: NR7 + Inside Day + close is smaller than open + change of SMA is downwards
strategy.entry("sell", strategy.short, when = NR7ID and open > close and ma_change == false, comment="Short")
strategy.close("sell", when = open > close )
// (not enabled) Long Strategy: NR7 + Inside Day + close is larger than open + change of SMA is upwards
//strategy.entry("long", strategy.long, when = NR7ID and open < close and ma_change == true, comment="Long")
//strategy.close("long", when = open < close )