विन्यास योग्य BB+RSI+Aroon रणनीति बैकटेस्ट

लेखक:चाओझांग, दिनांक: 2023-09-21 15:05:38
टैगः

अवलोकन

यह रणनीति बोलिंगर बैंड (बीबी), रिलेटिव स्ट्रेंथ इंडेक्स (आरएसआई) और एरोन इंडिकेटरों को कुशल प्रवेश और निकास संकेतों के व्यापार के लिए प्रत्येक की ताकतों पर लाभ उठाने के लिए जोड़ती है।

यह कैसे काम करता है

  1. मूल्य ब्रेक बीबी निचले बैंड लंबे संकेत दिखाता है।

  2. आरएसआई ओवरसोल्ड लाइन को पार करने से लंबी पुष्टि होती है।

  3. एरॉन क्रॉसओवर में लंबी पुष्टि दिखाई देती है।

  4. लंबी प्रविष्टि जब सभी 3 शर्तों को पूरा किया जाता है।

  5. मूल्य ब्रेक BB ऊपरी बैंड कम संकेत दिखाता है।

  6. आरएसआई ओवरबोल्ड लाइन को पार करने से संक्षिप्त पुष्टि होती है।

  7. एरॉन क्रॉसओवर में संक्षिप्त पुष्टि दिखाई देती है।

  8. जब सभी 3 शर्तें पूरी हो जाएं तो लघु प्रवेश।

लाभ

  • अनुकूलन के लिए विन्यास योग्य पैरामीटर
  • कई पुष्टिकरण सटीकता में सुधार
  • विभिन्न बाजार स्थितियों के अनुकूल
  • सरल तर्क लागू करने में आसान

जोखिम

  • खराब पैरामीटर ट्यूनिंग गलत संकेत का कारण बन सकता है
  • कई संकेतक विलंब जोड़ते हैं, तेजी से उलटफेर को याद कर सकते हैं
  • प्रतिवर्तन व्यापार की आवृत्ति और लागत को बढ़ाता है

अनुकूलन दिशाएँ

  • इष्टतम मापदंडों के लिए बाजारों और समय सीमाओं के बीच बैकटेस्ट
  • प्रत्येक संकेतक के योगदान का मूल्यांकन करें, रिकार्ड्स को हटाएं
  • पैरामीटर अनुकूलन के लिए मशीन सीखने का अन्वेषण करें
  • गणनाओं को कम करने के लिए कोड का अनुकूलन करें
  • विभिन्न रखरखाव अवधि मापदंडों का परीक्षण करें

निष्कर्ष

यह रणनीति कई संकेतकों की ताकत को मजबूत प्रवेश संकेतों में जोड़ती है। पैरामीटर अनुकूलन, अतिरेक संकेतकों को कम करने और कोड का अनुकूलन करके आगे के सुधार प्रदर्शन को बढ़ा सकते हैं। कुल मिलाकर एक प्रभावी अनुकूलन योग्य समाधान व्यापार।


/*backtest
start: 2023-09-13 00:00:00
end: 2023-09-20 00:00:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// Developed by Marco Jarquin as part of Arkansas 22 Project for Binary Options
// CBRA for binary options (Configurable Bollinger Bands, RSI and Aroon)

//@version=4
// ====================================================================================

//strategy("A22.CBRA.Strat", overlay=true, initial_capital=10000, currency="USD", calc_on_every_tick=true, default_qty_type=strategy.cash, default_qty_value=4000, commission_type=strategy.commission.cash_per_order, commission_value=0)

// Aroonish Parameters
// ====================================================================================

Aroonish_length = input(4, minval=1, title="Aroonish Lenght")
Aroonish_ConfVal = input(50, minval=0, maxval=100, step=25, title="Aroonish Confirmation Value")
Aroonish_upper = 100 * (-highestbars(high, Aroonish_length+1) + Aroonish_length)/Aroonish_length
Aroonish_lower = 100 * (-lowestbars(low, Aroonish_length+1) + Aroonish_length)/Aroonish_length

// Aroonish confirmations
// ====================================================================================
Aroonish_ConfLong = (Aroonish_lower >= Aroonish_ConfVal) and (Aroonish_upper < Aroonish_lower)
Aroonish_ConfShrt = (Aroonish_upper >= Aroonish_ConfVal) and (Aroonish_upper > Aroonish_lower)

plotshape(crossover(Aroonish_lower, Aroonish_upper), color = color.red, style = shape.triangledown, location = location.abovebar, size = size.auto, title = "Ar-B")
plotshape(crossover(Aroonish_upper, Aroonish_lower), color = color.green, style = shape.triangleup, location = location.belowbar, size = size.auto, transp = 0, title = "Ar-S")

// RSI Parameters
// ====================================================================================
RSI_length = input(4, title="RSI Lenght")
RSI_overSold = input(20, title="RSI Oversold Limit")
RSI_overBought = input(80, title="RSI Overbought Limit" )

RSI = rsi(close, RSI_length)

plotshape(crossover(RSI, RSI_overSold), color = color.orange, style = shape.square, location = location.belowbar, size = size.auto, title = "RSI-B")
plotshape(crossunder(RSI, RSI_overBought), color = color.orange, style = shape.square, location = location.abovebar, size = size.auto, transp = 0, title = "RSI-S")

// Bollinger Parameters
// ====================================================================================
BB_length = input(20, minval=1, title="Bollinger Lenght")
BB_mult = input(2.5, minval=0.1, maxval=50, step=0.1, title="Bollinger Std Dev")
// BB_bars = input(3, minval=1, maxval=5, title="Check bars after crossing")

BB_basis = sma(close, BB_length)
BB_dev = BB_mult * stdev(close, BB_length)

BB_upper = BB_basis + BB_dev
BB_lower = BB_basis - BB_dev

p1 = plot(BB_upper, color=color.blue)
p2 = plot(BB_lower, color=color.blue)

// Bars to have the operation open
// ====================================================================================
nBars = input(3, minval=1, maxval=30, title="Bars to keep the operation open")

// Strategy condition short or long
// ====================================================================================
ConditionShrt = ((crossunder(close, BB_upper) or crossunder(close[1], BB_upper[1])) and Aroonish_ConfShrt) and (crossunder(RSI, RSI_overBought) or crossunder(RSI[1], RSI_overBought[1]))
ConditionLong = ((crossover(close, BB_lower) or crossover(close[1], BB_lower[1])) and Aroonish_ConfLong) and (crossover(RSI, RSI_overSold) or crossover(RSI[1], RSI_overSold[1]))

plotshape(crossover(close, BB_lower), color = color.blue, style = shape.circle, location = location.belowbar, size = size.auto, title = "BB-B")
plotshape(crossunder(close, BB_upper), color = color.blue, style = shape.circle, location = location.abovebar, size = size.auto, transp = 0, title = "BB-S")


// Make input options that configure backtest date range
// ====================================================================================
iMo = input(title="Start Month", type=input.integer, defval=1, minval=1, maxval=12)
iDy = input(title="Start Date", type=input.integer, defval=1, minval=1, maxval=31)
iYr = input(title="Start Year", type=input.integer, defval=(2020), minval=1800, maxval=2100)

eMo = input(title="End Month", type=input.integer, defval=1, minval=1, maxval=12)
eDy = input(title="End Date", type=input.integer, defval=1, minval=1, maxval=31)
eYr = input(title="End Year", type=input.integer, defval=(2021), minval=1800, maxval=2100)

// Look if the close time of the current bar falls inside the date range
// ====================================================================================
inDateRange = true


// Evaluates conditions to enter short or long
// ====================================================================================
if (inDateRange and ConditionLong)
    strategy.entry("A22.L", strategy.long)

if (inDateRange and ConditionLong[nBars])
    strategy.close("A22.L", comment="A22.L Exit")
    
if (inDateRange and ConditionShrt)
    strategy.entry("A22.S", strategy.short)

if (inDateRange and ConditionShrt[nBars])
    strategy.close("A22.S", comment="A22.S Exit")

if (not inDateRange)
    strategy.close_all()

अधिक