Двойные полосы Боллинджера

Автор:Чао Чжан, Дата: 2023-12-13 17:33:24
Тэги:

Обзор

Эта стратегия использует двойные полосы Боллинджера для выявления зон консолидации и сигналов прорыва для реализации стратегии торговли низкого покупания-высокой продажи. Когда цена прорывается через нейтральную зону, это сигнализирует о начале нового тренда и времени для входа в длинную позицию. Когда цена прорывается ниже нейтральной зоны, это сигнализирует о конце тренда и времени для закрытия позиции.

Логика стратегии

Стратегия использует две полосы Боллинджера. Внутренний BB имеет верхние / нижние полосы 20SMA ± 1 стандартного отклонения. Внешний BB имеет верхние / нижние полосы 20SMA ± 2 стандартных отклонений. Область между двумя BB определяется как нейтральная зона.

Когда цена остается в нейтральной зоне в течение двух последовательных свечей, это считается консолидацией.

После входа в длинную позицию стоп-лосс устанавливается на самой низкой цене - 2xATR для блокировки прибыли и контроля риска.

Анализ преимуществ

Эта стратегия сочетает в себе индикаторы и тенденции для выявления зон консолидации и определения начала тренда, что позволяет вести торговлю с низким уровнем покупки и высоким уровнем продажи с большим потенциалом прибыли.

Анализ рисков

Стратегия основана на сигналах прорыва, которые могут оказаться ложными прорывами, что приводит к потере сделок.

Решения включают оптимизацию параметров BB, добавление фильтров для уменьшения ложных сигналов и предоставление более широких остановок.

Руководство по оптимизации

Оптимизируйте параметры BB для уменьшения ложных прорывов
Добавьте другие фильтры, например, объем, чтобы избежать ложных перерывов с низким объемом
Корректировать стратегию остановки потери для предотвращения срывов и ранних остановок
Масштаб позиций для снижения рисков единой торговли

Заключение

Эта стратегия объединяет двойные BB и трендовые стратегии для торговли с низкой покупкой-высокой продажей с большим потенциалом прибыли.

/*backtest
start: 2022-12-06 00:00:00
end: 2023-12-12 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © DojiEmoji

//@version=4
strategy("[KL] Double BB Strategy",overlay=true,pyramiding=1)
ENUM_LONG = "LONG"

// Timeframe {
backtest_timeframe_start = input(defval = timestamp("01 Apr 2020 13:30 +0000"), title = "Backtest Start Time", type = input.time)
USE_ENDTIME = input(false,title="Define backtest end-time (If false, will test up to most recent candle)")
backtest_timeframe_end = input(defval = timestamp("19 Apr 2021 19:30 +0000"), title = "Backtest End Time (if checked above)", type = input.time)
within_timeframe = true
// }

// Bollinger bands
BOLL_length = 20, BOLL_src = close, SMA20 = sma(BOLL_src, BOLL_length)
BOLL_sDEV = stdev(BOLL_src, BOLL_length)
BOLL_upper1 = SMA20 + BOLL_sDEV, BOLL_lower1 = SMA20 - BOLL_sDEV
BOLL_upper2 = SMA20 + BOLL_sDEV*2, BOLL_lower2 = SMA20 - BOLL_sDEV*2
SMA_20_plot = plot(SMA20, "Basis", color=#872323, offset = 0)
BOLL_upper1_plot = plot(BOLL_upper1, "BOLL Upper1", color=color.navy, offset = 0, transp=50)
BOLL_lower1_plot = plot(BOLL_lower1, "BOLL Lower1", color=color.navy, offset = 0, transp=50)
BOLL_upper2_plot = plot(BOLL_upper2, "BOLL Upper2", color=color.navy, offset = 0, transp=50)
BOLL_lower2_plot = plot(BOLL_lower2, "BOLL Lower2", color=color.navy, offset = 0, transp=50)
fill(BOLL_upper2_plot, BOLL_upper1_plot, title = "Background", color=#198787, transp=85)
fill(BOLL_upper1_plot, SMA_20_plot, title = "Background", color=#198787, transp=75)
fill(SMA_20_plot, BOLL_lower1_plot, title = "Background", color=#198787, transp=75)
fill(BOLL_lower1_plot, BOLL_lower2_plot, title = "Background", color=#198787, transp=85)


// Trailing stop loss {
ATR_X2_TSL = atr(input(14,title="Length of ATR for trailing stop loss")) * input(2.0,title="ATR Multiplier for trailing stop loss",type=input.float)
TSL_source = low
var stop_loss_price = float(0)
TSL_line_color = color.green, TSL_transp = 100
if strategy.position_size == 0 or not within_timeframe
    TSL_line_color := color.black
    stop_loss_price := TSL_source - ATR_X2_TSL 
else if strategy.position_size > 0
    stop_loss_price := max(stop_loss_price, TSL_source - ATR_X2_TSL)
    TSL_transp := 0
plot(stop_loss_price, color=color.new(TSL_line_color, TSL_transp))
// }

// Signals for entry
is_neutral = close < BOLL_upper1 and close > BOLL_lower2
is_consol = is_neutral and is_neutral[2]
entry_signal = is_consol[1] and close > BOLL_upper1


// MAIN:
if within_timeframe
    // EXIT ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
	exit_msg = close <= strategy.position_avg_price ? "stop loss" : "take profit"
	end_of_rally = close < BOLL_upper1 and strategy.position_avg_price > stop_loss_price	// also detects false breakouts
	if strategy.position_size > 0 and (TSL_source <= stop_loss_price or end_of_rally)
        strategy.close(ENUM_LONG, comment=exit_msg)

    // ENTRY :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    if (strategy.position_size == 0 or (strategy.position_size > 0 and close > stop_loss_price)) and entry_signal
		entry_msg = strategy.position_size > 0 ? "adding" : "initial"
		strategy.entry(ENUM_LONG, strategy.long, comment=entry_msg)

// CLEAN UP:
if strategy.position_size == 0
	stop_loss_price := float(0)

Больше