多级动态追踪趋势量化策略:基于Hull移动平均线的智能止盈止损系统

/*backtest
start: 2025-01-01 00:00:00
end: 2025-07-04 08:00:00
period: 1h
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT"}]
*/

//@version=5
strategy("Samil Dogru SmartTrailing v1.1", overlay=true, pyramiding=0,
     default_qty_type=strategy.percent_of_equity, default_qty_value=100)

// === PARAMETRELER ===
triggerPerc     = input.float(1.2,  "Tetikleme Eşiği (%)", step=0.1)
trailPerc       = input.float(0.8,  "Trailing Marj (%)", step=0.1)
hardStopPerc    = input.float(2.5,  "Maksimum Zarar (%) (Tetiklenmeden önce)", step=0.1)

// === HMA'lar (giriş için referans) ===
hma100 = ta.hma(close, 100)
hma200 = ta.hma(close, 200)
hma500 = ta.hma(close, 500)
hma600 = ta.hma(close, 600)

isBull = hma500 > hma600
longCond  = ta.crossover(hma100, hma200) and isBull and hma100 > hma500 and hma200 > hma500
shortCond = ta.crossunder(hma100, hma200) and not isBull and hma100 < hma500 and hma200 < hma500

// === GİRİŞLER ===
if (longCond)
    strategy.entry("Long", strategy.long)
if (shortCond)
    strategy.entry("Short", strategy.short)

// === DURUM DEĞİŞKENLERİ ===
var float entryPrice    = na
var float maxSinceEntry = na
var bool  triggered     = false

// === POZİSYON AÇILDIĞINDA BAŞLAT ===
if strategy.opentrades > 0
    if na(entryPrice)
        entryPrice := strategy.position_avg_price
        maxSinceEntry := close
        triggered := false
    else
        // Güncel zirve/dip güncellemesi
        if strategy.position_size > 0
            maxSinceEntry := math.max(maxSinceEntry, close)
        if strategy.position_size < 0
            maxSinceEntry := math.min(maxSinceEntry, close)

        // Tetikleme kontrolü
        longTriggerPrice  = entryPrice * (1 + triggerPerc / 100)
        shortTriggerPrice = entryPrice * (1 - triggerPerc / 100)

        if strategy.position_size > 0 and close >= longTriggerPrice
            triggered := true
        if strategy.position_size < 0 and close <= shortTriggerPrice
            triggered := true

        // Çıkış kontrolü (trailing)
        if triggered
            if strategy.position_size > 0
                trailStop = maxSinceEntry * (1 - trailPerc / 100)
                if close <= trailStop
                    strategy.close("Long", comment="TRAIL EXIT LONG")
            if strategy.position_size < 0
                trailStop = maxSinceEntry * (1 + trailPerc / 100)
                if close >= trailStop
                    strategy.close("Short", comment="TRAIL EXIT SHORT")
        else
            // Tetiklenmeden önce sert zarar çıkışı (hard stop)
            if strategy.position_size > 0 and close <= entryPrice * (1 - hardStopPerc / 100)
                strategy.close("Long", comment="HARD STOP LONG")
            if strategy.position_size < 0 and close >= entryPrice * (1 + hardStopPerc / 100)
                strategy.close("Short", comment="HARD STOP SHORT")

// === POZİSYON KAPANDIĞINDA RESET ===
if strategy.opentrades == 0
    entryPrice := na
    maxSinceEntry := na
    triggered := false

// === GÖRSEL ===
plot(hma100,  title="HMA 100",  color=color.white,  linewidth=2)
plot(hma200,  title="HMA 200",  color=color.yellow, linewidth=3)
p1 = plot(hma500,  title="HMA 500",  color=color.green, linewidth=2)
p2 = plot(hma600, title="HMA 600", color=color.red,   linewidth=2)
fill(p1, p2, color=isBull ? color.new(color.green, 70) : color.new(color.red, 70), title="HMA Cloud")

• 双重赫尔移动平均交叉动量量化策略
• 动态ATR止损止盈的指数移动平均线交叉趋势量化策略
• 双均线隧道趋势突破交易策略
• 双周期赫尔移动平均线趋势跟踪与动态止盈量化交易策略
• 零延迟移动平均趋势交叉策略
• 多重时序动量融合趋势跟踪策略
• 高效趋势捕捉型指数移动平均线交叉与动态追踪止损策略
• 双均线交叉动量验证交易策略
• 多因子EMA-RSI-VWAP日内动量交易策略与会话风险管理
• 指数移动平均线交叉动态跟踪止损策略