इस रणनीति को
पारंपरिक पैराबोलिक एसएआर का त्वरण कारक स्थिर रहता है और बढ़ी हुई अस्थिरता के अनुकूल नहीं हो सकता है। यह रणनीति एटीआर मूल्य के विस्तार के साथ एसएआर वक्र अनुबंध को तेज बनाती है, इसलिए अस्थिरता बढ़ने पर स्टॉप जोखिमों को प्रभावी ढंग से नियंत्रित करने के लिए कीमतों के आसपास तेजी से कस सकता है।
विशेष रूप से, मूल्य प्रवृत्ति निर्धारित करने के बाद, पैराबोलिक एसएआर ट्रेलिंग स्टॉप वक्र को प्लॉट करने के लिए एटीआर मूल्य के आधार पर एक अनुकूलन त्वरण कारक की गणना की जाती है। जब कीमतें स्टॉप स्तर को तोड़ती हैं, तो स्टॉप लॉस ट्रिगर किया जाता है।
इस रणनीति का लाभ बाजार की अस्थिरता के आधार पर पारंपरिक पैराबोलिक SAR स्टॉप को गतिशील बनाना है। लेकिन एटीआर मापदंडों को अनुकूलन की आवश्यकता है, और स्टॉप लाइन समय से पहले उल्लंघन के लिए प्रवण हो सकती है।
आम तौर पर, लाभ की रक्षा और जोखिमों को सीमित करने के लिए अनुकूलन स्टॉप महत्वपूर्ण हैं। व्यापारियों को बाजार की स्थितियों के आधार पर उपयुक्त स्टॉप संकेतक चुनने चाहिए, और स्टॉप लॉस रणनीतियों की उपयोगिता को अधिकतम करने के लिए मापदंडों का परीक्षण और अनुकूलन करना चाहिए।
/*backtest
start: 2023-08-13 00:00:00
end: 2023-09-12 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
//@version=4
strategy(title="ATR Parabolic SAR Strategy [QuantNomad]", shorttitle="ATR PSAR Strategy [QN]", overlay=true, default_qty_type = strategy.percent_of_equity, default_qty_value = 100)
atr_length = input(14)
start = input(0.02)
increment = input(0.02)
maximum = input(0.2)
entry_bars = input(1, title = "Entry on Nth trend bar")
atr = atr(atr_length)
atr := na(atr) ? tr : atr
psar = 0.0 // PSAR
af = 0.0 // Acceleration Factor
trend_dir = 0 // Current direction of PSAR
ep = 0.0 // Extreme point
trend_bars = 0
sar_long_to_short = trend_dir[1] == 1 and close <= psar[1] // PSAR switches from long to short
sar_short_to_long = trend_dir[1] == -1 and close >= psar[1] // PSAR switches from short to long
trend_change = barstate.isfirst[1] or sar_long_to_short or sar_short_to_long
// Calculate trend direction
trend_dir := barstate.isfirst[1] and close[1] > open[1] ? 1 :
barstate.isfirst[1] and close[1] <= open[1] ? -1 :
sar_long_to_short ? -1 :
sar_short_to_long ? 1 : nz(trend_dir[1])
trend_bars := sar_long_to_short ? -1 :
sar_short_to_long ? 1 :
trend_dir == 1 ? nz(trend_bars[1]) + 1 :
trend_dir == -1 ? nz(trend_bars[1]) - 1 :
nz(trend_bars[1])
// Calculate Acceleration Factor
af := trend_change ? start :
(trend_dir == 1 and high > ep[1]) or
(trend_dir == -1 and low < ep[1]) ?
min(maximum, af[1] + increment) :
af[1]
// Calculate extreme point
ep := trend_change and trend_dir == 1 ? high :
trend_change and trend_dir == -1 ? low :
trend_dir == 1 ? max(ep[1], high) :
min(ep[1], low)
// Calculate PSAR
psar := barstate.isfirst[1] and close[1] > open[1] ? low[1] :
barstate.isfirst[1] and close[1] <= open[1] ? high[1] :
trend_change ? ep[1] :
trend_dir == 1 ? psar[1] + af * atr :
psar[1] - af * atr
plot(psar, style=plot.style_cross, color=trend_dir == 1 ? color.green : color.red, linewidth = 2)
// Strategy
strategy.entry("Long", true, when = trend_bars == entry_bars)
strategy.entry("Short", false, when = trend_bars == -entry_bars)